cAFA9	;Functies ivm back-ground-jobs; cAFA9
	;
	G YZ
	;
T0	;Functies ivm back-ground-jobs;
T1	;0[] = donderdag   1[] = vrijdag   2[] = zaterdag   3[] = zondag                 4[] = maandag     5[] = dinsdag   6[] = woensdag;
T2	;nn[] = dag van de maand   99[] = laatse dag van de maand;
	;
T0F	;Functies ivm back-ground-jobs;
T1F	;0[] = donderdag   1[] = vrijdag   2[] = zaterdag   3[] = zondag                 4[] = maandag     5[] = dinsdag   6[] = woensdag;
T2F	;nn[] = dag van de maand   99[] = laatse dag van de maand;
	;
	;  Bepalen commentaar en lengte input.
	;  Bij frequentie 7 of 14 lente input 1 (dagen van de week)
	;  Bij frequentie 30 lengte input 2 (dag van de maand)
DAG	I $P(B(1),D,2)=7!($P(B(1),D,2)=14) D
	. S U2(9)=1
	. S $P(U2(10),D,QTU)=$P($T(@("T1"_QT)),U,2)
	I $P(B(1),D,2)=30 D
	. S U2(9)=2
	. S $P(U2(10),D,QTU)=$P($T(@("T2"_QT)),U,2)
	I $P(B(1),D,2)'=7&($P(B(1),D,2)'=14)&($P(B(1),D,2)'=30) D
	. S U2(19)="S K=$S(RK=31:""-"",1:"""")"
DAGZ	Q
	;
FRDAG(FR,DAG)	;  Invullen van het veld dag adhv de frequentie
	N R
	S $ZT="TRAP^cAN000"
	S R=""
	I FR=1!FR=2 S R=0
	I FR=7!(FR=14) D
	. I UFU="O" S R=""
	. I UFU'="O"&($L(DAG)) D
	.. I "0123456"[DAG S R=DAG
	.. I "0123456"'[DAG S R=0
	. I UFU'="O"&('$L(DAG)) S R=0
	I FR=30 D
	. I $L(DAG)&(DAG>0&(DAG<32)) S R=DAG
	. I $L(DAG)&(DAG<0!(DAG>31)) S R=1
	. I '$L(DAG) S R=1
FRDAGZ	Q R
	;
LASTRN(VNR,COMP)	;  Opzoeken van de last run van een back-ground-job (begin)
	N R,RL,X
	S $ZT="TRAP^cAN000"
	I '$L(COMP) S COMP=boot
	S (R,RL)=""
	I '$D(^cLOG(cs,"CTK0","AUTO",VNR,COMP)) G LASTRNZ
	S X=$O(^cLOG(cs,"CTK0","AUTO",VNR,COMP,""),-1) I X S X=$O(^cLOG(cs,"CTK0","AUTO",VNR,COMP,X,""),-1) I X S RL=^(X)
	I $L(RL) S R=$P(RL,D,2)_" "_$J($tr($P(RL,D,3),"uh ","::"),5) 
LASTRNZ	Q R
	;
LASTRNE(VNR,COMP)	;  Opzoeken van de last run van een back-ground-job (einde)
	N R,RL,X
	S $ZT="TRAP^cAN000"
	I '$L(COMP) S COMP=boot
	S (R,RL)=""
	I '$D(^cLOG(cs,"CTK0","AUTO",VNR,COMP)) G LASTRNZ
	S X=$O(^cLOG(cs,"CTK0","AUTO",VNR,COMP,""),-1) I X S X=$O(^cLOG(cs,"CTK0","AUTO",VNR,COMP,X,""),-1) I X S RL=^(X)
	I $L(RL) S R=$P(RL,D,6)_" "_$J($tr($P(RL,D,7),"uh ","::"),5)
LASTRNEZ	Q R
	;
LOGRUN(UI1O,COMP,PROG)	;  Opbouwen van de logging van een back-ground-job
	N RSORT,VNR,I1,I2,LIJN
	S $ZT="TRAP^cAN000"
	S RSORT=$$GETSORT^cAFA1
	I '$L(COMP) S COMP=boot
	S VNR=1
	S I1=""
	F  S I1=$O(^cLOG(cs,"CTK0","AUTO",UI1O,COMP,I1)) Q:I1=""  D
	. S I2=""
	. F  S I2=$O(^cLOG(cs,"CTK0","AUTO",UI1O,COMP,I1,I2)) Q:I2=""  D
	.. S LIJN=^(I2)
	.. S ^HULP("SORT",RSORT,VNR)=$P(LIJN,D)_D_$P(LIJN,D,2)_" "_$J($tr($P(LIJN,D,3),"uh ","::"),5)_D_$P(LIJN,D,6)_" "_$J($tr($P(LIJN,D,7),"uh ","::"),5)
	.. S VNR=VNR+1
	D RS^cAN210("BGJB_LOG","0","0","0","")
	D RELSORT^cAFA1(RSORT)
LOGRUNZ	Q
	;
NSPC()	;  Opzoeken alle namespaces
	N NMSPT,CS,J,SYS
	S $ZT="TRAP^cAN000"
	S CS=cs
	; Opzoeken van de namespaces op het systeem
	D NSPC^cQ21(.SYS,1)
	I $O(SYS(CS))="",$O(SYS(CS),-1)="" G NSPCZ
	S (J,NMSPT)=""
	F  S J=$O(SYS(J)) Q:J=""  D
	. I $TR(J,"0123456789")'=$TR(CS,"0123456789") K SYS(J)
	. I $TR(J,"0123456789")=$TR(CS,"0123456789") S NMSPT=NMSPT_$P(J,$TR(CS,"0123456789"),2)_" "
	S:$E(NMSPT,$L(NMSPT))=" " $E(NMSPT,$L(NMSPT))=""
NSPCZ	Q NMSPT
	;
QWRD	; Tonen van de beschikbare Q-waardes op 2e lijn
	N qq
	S $ZT="TRAP^cAN000"
	S qq=^cLOG(boot,"Q",cs)
	S qq=$TR(qq,"\"," ")
	S $P(U2(10),D,QTU)=$P(U2(10),D,QTU)_$J(" ",80-($L($P(U2(10),D,QTU))))_qq
QWDZ	Q
	;
UI1()	;  Bepalen van de nieuwe UI1 waarde bij het openen.
	N R
	S $ZT="TRAP^cAN000"
	S R=""
	S R=$O(^cLOG(cs,"CTK0","AUTO",R),-1)+1
UI1Z	Q R
	;
	;  Uur niet ingeven als frequentie om de x minuten
UUR	I $P(B(1),D,2)>30,$P(B(1),D,2)#60=0,$P(B(1),D,2)'>43200 D
	. S U2(19)="S K=$S(RK=31:""-"",1:"""")"
	. S U2(11)=""
UURZ	Q
	;
FRUUR(FR,R)	;  Invullen van het veld uur adhv de frequentie
	S $ZT="TRAP^cAN000"
	I UFU="W",'R S R="01:23"
	I FR>30,FR#60=0,FR'>43200 S R=""
FRUURZ	Q R
	;
VERWR	;  Verwijderen van de last run van de back-ground-job
	N I1,I2,VNR
	S $ZT="TRAP^cAN000"
	I '$D(^cLOG(cs,"CTK0","AUTO",UI1O,COMP)) G VERWRZ
	S I1=""
	S I1=$O(^cLOG(cs,"CTK0","AUTO",UI1O,COMP,I1),-1)
	S I2=""
	S I2=$O(^cLOG(cs,"CTK0","AUTO",UI1O,COMP,I1,I2),-1)
	S VNR=""
	S VNR=$O(^HULP("SORT",RSORT,VNR),-1)
	I I1'=""&(I2'="") K ^cLOG(cs,"CTK0","AUTO",UI1O,COMP,I1,I2),^HULP("SORT",RSORT,VNR)
VERWRZ	Q
	;
WIJZ()	;  Kijken of een back-ground-job kan worden gewijzigd
	N R
	S $ZT="TRAP^cAN000"
	S R=0
	S UI1=UI1+.1
	S R=$$PLUS^cANLOCK(UREF,2,"",1)
	S UI1=UI1-.1
WIJZZ	Q R
	;
WIJZN	;  Verwijderen van de lock van de back-ground-job, na het wijzigen
	S UI1=UI1+.1
	L -@UREF
	S UI1=UI1-.1
WIJZNZ	Q
	;
YZ	Q
	;
ZZ	; 04.11.04 - 10 u 11 * V8.02