cAFI2	;Inputcontrole ;%AFI2 ; [ 01/25/02  2:05 PM ]
	;
T0	;Inputcontrole ;
	;
T0F	;Contrôle d'entrée ;
	;
T0E	;Inputcontrol ;
	;
BANK(NR)	; controle bank-nummer met ISO-landcode
	N R,RK,RL,RLI
	S R=0,(K,RK)=$$UC^cAFA1(NR)
	S RL=$P(@("^"_Q_"BA(39)"),D,3) I "B"[RL S RL="BE"
	S RLI=$P(K,"-") S:RLI?1U.U K=$P(K,"-",2,99) S:RLI'?1U.U RLI=RL
	I $$UI1^cAFA1("ISO.LAND",101,RLI) S R=1
	I R,$D(^BA(6,RLI)) D
	. S R=0 I @^(RLI,1) S R=1
	S K=RK I R,$P(K,"-")=RL S K=$P(K,"-",2,99)
	I 'R S R=$$IBAN(RK) I R S K=$$DP^cAFA1(RK)
	Q R
	;
IBAN(X)	;  Test op geldige IBAN-code
	N R,Y,I,K
	S R=0,X=$$DP^cAFA1(X)
	I X'?2U.AN G IBANZ
	S X=$E(X,5,$L(X))_$E(X,1,4)
	F I=1:1:$L(X) D
	. I $E(X,I)?.N S Y=$G(Y)_$E(X,I)
	. I $E(X,I)'?.N S Y=$G(Y)_($A(X,I)-55)
	S K=$E(Y,1,9)
	S K=K#97
	F I=10:8 Q:$L($E(Y,I,(I+7)))=0   S K=K_$E(Y,I,(I+7)),K=K#97
	I K=1 S R=1
IBANZ	Q R
	;
G(K,VM,NEG)	       ; controle Getal K met decimalen volgens VM, evt. NEGatief
	N DEC,R
	S DEC=$$DEC^cAFA1(VM)
	S R=$$W(K,DEC,$G(NEG))
	Q R
	;
W(K,DEC,NEG)	      ; controle Waarde K met DECimalen, evt. NEGatief
	N R
	S R=0 X "I K?.N!((K?.N1"".""."_DEC_"N)&DEC) S R=1"
	I 'R,$G(NEG) X "I K?.N1""-""!((K?.N1"".""."_DEC_"N1""-"")&DEC) S R=1"
	Q R
	;
VMAR(K)	; geldige muntcode in AR
	N BA39,R
	S BA39=@("^"_Q_"BA(39)"),R=$L(K)
	I R,K'="-",K'=$P(BA39,D) S R=$D(@("^"_Q_"BA(11,K)")) I R,$P(BA39,D,11)'="" S R='$P(^(K),D,12)
	Q R
	;
ZZ	; 07.02.02 - 11 u 22 * V7.91