cAFO9	;Outputformaten back-ground-jobs; cAFO9
	;
	G YZ
	;
T0	;Outputformaten back-ground-jobs;
T1	;Programma niet gevonden!;
T2	;;dag;werkdag;week;14 dagen;1x/maand;
T3	;Elke ;
T4	;DO;VR;ZA;ZO;MA;DI;WO;
T5	;low;normal;high;
T6	;Master;Shadow;
	;
T0F	;Outputformaten back-ground-jobs;
T1F	;Programma niet gevonden!;
T2F	;;dag;werkdag;week;14 dagen;1x/maand;
T3F	;Elke ;
T4F	;DO;VR;ZA;ZO;MA;DI;WO;
T5F	;low;normal;high;
T6F	;Master;Shadow;
	;
	;  Opzoeken van de dag van de week
DAG(K)	N R
	S $ZT="TRAP^cAN000"
	I K="" S R="" G DAGZ
	I $L(K) S R=$P($T(@("T4"_QT)),U,K+2)
DAGZ	Q R
	;
FREQ(FR1,FR2)	;  Opzoeken omschrijving v/d frequentie 
	N R,I
	S $ZT="TRAP^cAN000"
	S FR1=+FR1
	S R=$P($T(@("T2"_QT)),U,$S(FR1=1:3,FR1=2:4,FR1=7:5,FR1=14:6,FR1=30:7,1:2))
	; Vaste datum
	I FR1>58000 S R=$$HD^cAFD1(FR1) G FREQZ
	; Om de nnnn seconden
	I FR1>30 S R=$P($T(@("T3"_QT)),U,2)_(FR1\3600)_":"_R_($TR($J(FR1#3600\60,2)," ",0)) G FREQZ
	I FR1=1!(FR1=2)!(FR1=7) S R=$P($T(@("T3"_QT)),U,2)_R
	I '$L(FR2) G FREQZ
	; Bij elke week en om de 14 dagen, opzoeken op welke dag
	I FR1=7!(FR1=14) S R=R_":"_$$DAG(FR2)
	; Bij elke maand, tonen van de dag
	I FR1=30 S R=R_":"_FR2
FREQZ	Q R
	;
	;  Master/Shadow
MS(K)	N R
	S $ZT="TRAP^cAN000"
	I K="" S R=$P($T(@("T6"_QT)),U,2)_" & "_$P($T(@("T6"_QT)),U,3)
	I K="M" S R=$P($T(@("T6"_QT)),U,2)
	I K="S" S R=$P($T(@("T6"_QT)),U,3)
MSZ	Q R
	;
OMSCHR(PROG)	; Omschrijving van de back-ground-job: wordt bepaald adhv "label^routine"
	N RT,P,R,K,C,NMSPC
	S $ZT="TRAP^cAN000"
	S R=""
	I $G(PROG)="" G OMSCHRZ
	S P=PROG
	S:P'["^" P="^"_P
	; Opzoeken van de routine in de string P
	S RT=$P($TR(P,"^|[(:","~~~~~"),"~",2)
	; Opzoeken van de namespace waarin het programma zal worden uitgevoerd
	S NMSPC=$ZU(5)
	I P[":(" S C=$P($P($P(P,":(",2),")"),":"),NMSPC=$TR(C,"""")
	; Opzoeken van de omschrijving van de routine
	I $L(RT),$D(^$|NMSPC|ROUTINE(RT)) S R=$$TL(RT,NMSPC,PROG)
OMSCHRZ	Q R
	;
PRIO(K)	;  Tonen van de prioriteit
	N R
	S $ZT="TRAP^cAN000"
	S R=$P($T(@("T5"_QT)),U,K+3)
PRIOZ	Q R
	;
TL(R,S,L)	;  Opzoeken omschrijving van het programma
	N I,K
	S $ZT="TRAP^cAN000"
	S R=$G(R),S=$G(S),QT=$G(QT),L=$G(L),K=$P($T(@("T1"_QT)),";",2)
	I $L(R) D
	. ; onthouden van de orininele namespace
	. S SO=$ZU(5)
	. ; kijken of de routine een %-routine is, indien dit zo is wordt namespace op "" gezet
	. S:$E(R)="%" S="" 
	. ; switchen naar de juist namespace
	. I $L(S) ZN S
	. ; indien de routine bestaat
	. I $D(^$|S|ROUTINE(R)) D
	.. ; opzoeken label waar men in het programma start
	.. S K="" S L=$P($TR(L,":()[]","|||||"),"|")
	.. ; Ophalen commentaar uit label L
	.. I $L(L) X "ZL @R S K=$P($T("_L_"),"";"",2)" I $L(K)>5 Q
	.. ; Ophalen commentaar uit T0 
	.. X "ZL @R S K=$P($T(@(""T0""_QT)),"";"",2) S:$L(K)<5 K=$P($T(+1),"";"",2) S:$L(K)<5 K=$P($T(+1),"";"",3)"
	.. ; Ophalen commentaar uit lijn +1
	.. S:K["[" K=$P(K,"[") F I=1:1 Q:$E(K)'=" "  S K=$E(K,2,$L(K))
	. ; Terug switchen naar de originele namespece
	. I SO'=$ZU(5) ZN SO
TLZ	Q K
	;
YZ	Q
	;
ZZ	; 12.11.02 - 15 u 51 * V7.93