cAFVBF03	;Ophalen openstaande facturen (=lay van menu 1.9) ; cAFVBF03 [ 03/23/00  4:03 PM ]
	;
T1	;Totaal;Kwartaal;
T2	;Klant;Leverancier; bestaat niet.;
T3	;Firmacode is niet ingevuld.;
	;
T1F	;Total;Trimestre;
T2F	;Client;Fournisseur; n'existe pas.;
T3F	;Code d'entreprise n'est pas rempli.;
	;
T1E	;Total;Quarter;
T2E	;Customer;Supplier; does'nt exist.;
T3E	;Company Id is required.;
	;
YZ	Q
	;
BTMPCOM	; code die in de BTEMP's gezamelijk gebruikt wordt
	D QT^cAFVBO01
	I '$L($G(Q)) S OK="0\"_$P($T(@("T3"_QT)),U,2) G BTMPCOMZ
	S Q=$$SIG^cAFA1(USC,UI1,149)  ; ophalen juiste Q-waarde
	S UI1=$P($G(^(0)),D,50)       ; ophalen oude UI1
	I '$L(UI1) S OK="0\"_$P($T(@("T2"_QT)),U,$P(USC,".")="LE"+2)_$P($T(@("T2"_QT)),U,4) G BTMPCOMZ
	S USC=$P(USC,".")
	S GRIDID=$G(GRIDID)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	S KC=$P(UI1," ",2)
BTMPCOMZ	Q
	;
BTMPHIS(GRIDID,Q,USC,UI1,QU)	  ; ophalen openstaande facturen
	; Q   = Q-waarde
	; USC = USC : bv KL.A
	; UI1 = key (intern nummer uit DKL)
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^dmTOOL("GRIDID,USC,UI1")     ; initialisatie variabelen + exclusieve new : N (%dmINIT,%Q1,D,DD,...A,B)
	D USR^cA5000($G(QU))
	D BTMPCOM I 'OK G BTMPHISZ
	S KM2=DJ_"."_$TR($J(DM,2)," ",0)
	S AM=$P(@("^"_Q_"BA(""%T"",2)"),D,11)
	S KM1=$$VAN^cT48H(AM),KM1=$E($$DC^cAFD1(KM1),1,6),KM1=$E(KM1,1,4)_"."_$E(KM1,5,6)
	S MUNT=$$BF^cAFA1()_D_QD
	I $E(USC,1,2)="KL" D VB^cT48(KC,"BTMPHIST^"_$T(+0),0,1,"",KM1,KM2,0,MUNT,1)
	I $E(USC,1,2)="LE" D VB^cT49(KC,"BTMPHIST^"_$T(+0),0,1,"",KM1,KM2,0,MUNT,1)
BTMPHISZ	Q OK
	;
BTMPHIST	; historiek : wordt opgeroepen vanuit cT483
	; Ingang : TXT(n) = af te printen info 
	;          I2 = volgnr
	N i,I2
	S $ZT="TRAP^cAN000"
	S i="" F  S i=$O(TXT(i)) Q:i=""  S TXT(i)=$P(TXT(i),D)
	S I2=$O(^mtemp99(GRIDID,"COMMON",""),-1)+1
	; JRN, F/C, document, Referte, omschrijving, mnt, ini, Boekingsmaand
	S ^mtemp99(GRIDID,"COMMON",I2,0)=TXT(4)_D_TXT(5)_D_TXT(6)_D_TXT(10)_D_TXT(11)_D_TXT(12)_D_TXT(15)_D_TXT(17-'$P($G(QU(0,2)),D,39))
	; Debet EUR, Credit EUR, Saldo EUR, Debet mnt, credit mnt
	S ^(2)=TXT(7)_D_TXT(8)_D_TXT(9)_D_TXT(13)_D_TXT(14)
	; datum, datum (ingave)
	S ^(3)=TXT(3)_D_$S($P($G(QU(0,2)),D,39):TXT(16),1:"")
	Q
	;
BTMPOF(GRIDID,Q,USC,UI1,QU)	 ; ophalen openstaande facturen
	; Q   = Q-waarde
	; USC = USC : bv KL.A
	; UI1 = key (intern nummer uit DKL)
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^dmTOOL("GRIDID,USC,UI1")     ; initialisatie variabelen + exclusieve new : N (%dmINIT,%Q1,D,DD,...A,B)
	D BTMPCOM I 'OK G BTMPOFZ
	I $E(USC,1,2)="KL" D VB^cAT10(KC,"BTMPOFT^"_$T(+0))
	I $E(USC,1,2)="LE" D VB^cT10(KC,"BTMPOFT^"_$T(+0))
BTMPOFZ	Q OK
	;
BTMPOFDT(GRIDID,Q,USC,UI1,QU,REFDT)	 ; ophalen openstaande facturen (via UI1 KL/LE) + terugkeermogelijkeid
	; Q   = Q-waarde
	; USC = USC : KL of LE
	; UI1 = key (intern nummer uit Q_KL of Q_LE)
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^dmTOOL("GRIDID,USC,UI1,REFDT")     ; initialisatie variabelen + exclusieve new : N (%dmINIT,%Q1,D,DD,...A,B)
	S USC=$P(USC,".")
	S GRIDID=$G(GRIDID)
	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	S KC=$P(UI1," ",2)
	I $E(USC,1,2)="KL" D VB^cAT10(KC,"BTMPOFT^"_$T(+0),$G(REFDT))
	I $E(USC,1,2)="LE" D VB^cT10(KC,"BTMPOFT^"_$T(+0),$G(REFDT))
BTMPOFDTZ	Q OK
	;
BTMPOFT	; Openstaand facturen : wordt opgeroepen vanuit cAT104 of cT104
	; Ingang : TXT(n) = af te printen info 
	;          I3 = volgnr uit ^HULP
	N i,sw
	S sw=0 I $p(TEXT,D,5)="LE" S sw=1  ; indien leveranciers dan verschuift txt met 1 vanaf TXT(13)
	S i="" F  S i=$O(TXT(i)) Q:i=""  S TXT(i)=$P(TXT(i),D)
	; JRN, F/C, R, Document, Referte, Munt,G, (indien leveranciers : factuurnr lev.),omschrijving
	S ^mtemp99(GRIDID,"COMMON",I3,0)=TXT(3)_D_TXT(4)_D_TXT(5)_D_TXT(6)_D_TXT(12)_D_TXT(18+sw)_D_TXT(21+sw)_D_TXT(13)
	; S ^mtemp99(GRIDID,"COMMON",I3,0)=TXT(3)_D_TXT(4)_D_TXT(5)_D_TXT(6)_D_TXT(12+(sw'=0))_D_TXT(18+sw)_D_TXT(21+sw)_D_TXT(13)
	I sw S ^(0)=^(0)_D_TXT(12)
	; dag.verv.
	S ^(1)=TXT(11)
	; Openst. EUR, Verv. EUR, Totaal Munt, Openst Munt,  K.c. Mnt, (indien leveranciers : Betaling)
	S ^(2)=TXT(8)_D_TXT(9)_D_TXT(19+sw)_D_TXT(20+sw)_D_TXT(22+sw) I sw S ^(2)=^(2)_D_TXT(15)
	; factuurdatum, vervaldatum,
	S ^(3)=TXT(7)_D_TXT(10)
BTMPOFTZ	Q
	;
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09