cAFVBO03	; Algemene functies VB-output ; cAFVBO03
	;
	;
T1	;Geen details beschikbaar.;
T2	;Product;
T3	;Manueel;
T4	;Tekst;
T5	;Langte tekst;
	;
T1F	;Il n'y a pas de détail disponible.;
T2F	;Produit;
T3F	;Manuel;
T4F	;Texte;
T5F	;Texte long;
	;
T1E	;No detail available.;
T2E	;Product;
T3E	;Manual;
T4E	;Text;
T5E	;Long Text;
	;
YZ	Q
	;
CGET(VAL,NRTEXT,ALL)	;  ophalen data van berekende property
	S $ZT="^dmERROR"
	N U,D
	S U=";",D="\"
	D QT^cAFVBO01
CGETZ	Q $$OUTPUT^cAFO7($G(VAL),$G(NRTEXT),$G(ALL))
	;
	;
RF(GRIDID,Q,FNR,US,QTD)	; Opbouwen ^mtemp99 voor Raadplegen facturen: Historiek
	;                   SW - 17.07.06
	; OUTPUT:
	;   0\foutboodschap
	;   1\GRIDID
	S $ZT="ERR^cAFVBF01"
	N @$$INITVAR^cAFVBA01("GRIDID,FNR,US,QTD")
	F i="GRIDID","FNR","US" S @i=$G(@i)
	I '$L(FNR) S OK="0\"_$P($T(@("T1"_QT)),U,2) G RFZ
RFA	I '$L(GRIDID) S GRIDID=$$GRIDID^cAFVBF01()
	K ^mtemp99(GRIDID,"COMMON") S OK=GRIDID
	; US is ingevuld : indien "^"_Q_"FA(US,FNR)" niet bestaat : stoppen
RFB	I $L(US),'$D(@("^"_Q_"FA(US,FNR)")) S OK="0\"_$P($T(@("T1"_QT)),U,2) G RFZ
	; US is niet ingevuld : "^"_Q_"FA(US)" aflopen en indien $D("^"_Q_"FA(US,FNR)") : ^mtemp99 opbouwen
RFC	I '$L(US) S US="" F  S US=$O(@("^"_Q_"FA(US)")) Q:US=""  Q:$D(@("^"_Q_"FA(US,FNR)")) 
RFD	I '$L(US) S OK="0\"_$P($T(@("T1"_QT)),U,2) G RFZ
	S UGL="UL",UPM=@("^"_Q_UGL_"(0,US,""LNT"")") ; parameters nodig voor gegevens ivm bon als tekstlijn
RFE	; HOOFDING ^mtemp99 opbouwen (node 0,1,2,8)
	K Y S I1="" F  S I1=$O(@("^"_Q_"FA(US,FNR,0,I1)")) Q:I1=""  S Y(0,I1)=^(I1)
	S $P(Y(0,8),D)=FNR
	; indien B127 niet ingevuld : KCF=B101 : eerste bon bepalen
RFF	I '$L($P(Y(0,0),D,27)) S KCF=$P(Y(0,0),D),UR=+$E($O(@("^"_Q_"FA(US,FNR,""U"")")),2,99),$P(Y(0,0),D,27)=+$G(@("^"_Q_"U1(US,UR)"),KCF)
	S $P(Y(0,0),D,27)=$$SG^cAFA1("KL",$P(Y(0,0),D,27),148) 	;  B127 : nr uit ^DKL
	S $P(Y(0,0),D)=$$SG^cAFA1("KL",$P(Y(0,0),D),148) 	;  B101 : nr uit ^DKL
	; ophalen order
RFG	S UR=$O(@("^"_Q_"FA(US,FNR,""U"")"))
	; parameters nodig voor gegevens ivm bon als tekstlijn
	S U5=@("^"_Q_"FA(US,FNR,UR,1)")
	S $P(Y(0,8),D,2)=$P(^(1),D,74) ; ordernr
	M ^mtemp99(GRIDID,"COMMON")=Y
	; DETAIL-LIJNEN ^mtemp99 opbouwen 
	S COUNT=0
	S I2="U" F  S I2=$O(@("^"_Q_"FA(US,FNR,I2)")) Q:I2=""  D
	. ; parameters nodig voor gegevens ivm bon als tekstlijn
	. D URREF(I2,^(I2,1))
	. S I3=100 F  S I3=$O(@("^"_Q_"FA(US,FNR,I2,I3)")) Q:I3=""  D
	.. S COUNT=COUNT+1,Y(0)=^(I3)
	.. S $P(Y(8),D)=COUNT	; lijnnr
	.. S $P(Y(8),D,2)=$S($P(Y(0),D,17)=".":$P($T(@("T2"_QTD)),U,2),$P(Y(0),D,17)="M":$P($T(@("T3"_QTD)),U,2),$P(Y(0),D,17)="T":$P($T(@("T4"_QTD)),U,2),$P(Y(0),D,17)="L":$P($T(@("T5"_QTD)),U,2)) ; lijntypr
	.. S $P(Y(8),D,3)=$S($P(Y(0),D,17)=".":0,$P(Y(0),D,17)="M":1,$P(Y(0),D,17)="T":2,$P(Y(0),D,17)="L":4) ; code lijntype
	.. S $P(Y(8),D,7)=$P($P(Y(0),D,61),"#") 			; datum opening
	.. S $P(Y(8),D,8)=$TR($TR($P($P(Y(0),D,61),"#",2),"uh","::")," ")	; tijd opening
	.. S $P(Y(8),D,9)=$P($P(Y(0),D,40),"#")			; datum wijziging
	.. S $P(Y(8),D,10)=$TR($TR($P($P(Y(0),D,40),"#",2),"uh","::")," ")	; tijd wijziging
	.. I "TL"[$P(Y(0),D,17) M ^mtemp99(GRIDID,"COMMON",COUNT)=Y Q
	.. S:$L($P(Y(0),D,21)) $P(Y(8),D,4)=$P(@("^"_Q_"BA(""%F"",5,"""_$P(Y(0),D,21)_" "")"),D) ; omschrijving
	.. S $P(Y(0),D)=$P($P(Y(0),D)," ")_" "
	.. S $P(Y(8),D,5)=$P(@("^"_Q_"AR($P(Y(0),D),1)"),D,$S(QTD="":5,QTD="F":7,QTD="D":9,QTD="E":11)) ; TBK omschrijving rekening in taal van gebruiker
	.. S $P(Y(0),D)=$P($P(Y(0),D)," ")
	.. S $P(Y(0),D,11)=$P($P(Y(0),D,11)," ")_" "
	.. S $P(Y(8),D,6)=$P(@("^"_Q_"AR($P(Y(0),D,11),1)"),D,$S(QTD="":5,QTD="F":7,QTD="D":9,QTD="E":11)) ; TBK omschrijving rekening in taal van gebruiker
	.. S $P(Y(0),D,11)=$P($P(Y(0),D,11)," ")
	.. S $P(Y(8),D,15)=$P(Y(0),D,29),$P(Y(0),D,29)=""     ; bedrag van B129 naar B915 (B129 is InitialsLastModified)
	.. ; S $P(Y(COUNT,8),D,20)=$P(Y(COUNT,0),D,56)					 ; Suppl%
	.. S:$E($P(Y(0),D,56))'="." $P(Y(8),D,20)=$P(Y(0),D,56) 	 ; Suppl%
	.. S:$E($P(Y(0),D,55))'="." $P(Y(8),D,21)=$P(Y(0),D,55)	 ; Perm 1A%
	.. S:$E($P(Y(0),D,55))="." $P(Y(8),D,22)=$E($P(Y(0),D,55),2,99) ; Perm 1A Amount
	.. S:$E($P(Y(0),D,66))'="." $P(Y(8),D,23)=$P(Y(0),D,66)	 ; Perm 2A%
	.. S:$E($P(Y(0),D,66))="." $P(Y(8),D,24)=$E($P(Y(0),D,66),2,99) ; Perm 2A Amount
	.. S:$E($P(Y(0),D,84))'="." $P(Y(8),D,32)=$P(Y(0),D,84)	 ; Perm 1B%
	.. S:$E($P(Y(0),D,84))="." $P(Y(8),D,33)=$E($P(Y(0),D,84),2,99) ; Perm 1B Amount
	.. S:$E($P(Y(0),D,36))'="." $P(Y(8),D,34)=$P(Y(0),D,36)	 ; Perm 2B%
	.. S:$E($P(Y(0),D,36))="." $P(Y(8),D,35)=$E($P(Y(0),D,36),2,99) ; Perm 2B Amount
	.. S:$E($P(Y(0),D,85))'="." $P(Y(8),D,36)=$P(Y(0),D,85)	 ; Perm 1C%
	.. S:$E($P(Y(0),D,85))="." $P(Y(8),D,37)=$E($P(Y(0),D,85),2,99) ; Perm 1C Amount
	.. S:$E($P(Y(0),D,37))'="." $P(Y(8),D,38)=$P(Y(0),D,37)	 ; Perm 2C%
	.. S:$E($P(Y(0),D,37))="." $P(Y(8),D,39)=$E($P(Y(0),D,37),2,99) ; Perm 2C Amount
	.. S $P(Y(8),D,25)=$P(Y(0),D,57)					 ; Retour%
	.. S:$E($P(Y(0),D,81))'="." $P(Y(8),D,26)=$P(Y(0),D,81)	 ; Promo%
	.. S:$E($P(Y(0),D,81))="." $P(Y(8),D,27)=$E($P(Y(0),D,81),2,99) ; Promotional Amount
	.. S $P(Y(8),D,28)=$P(Y(0),D,83)					 ; Invoice%
	.. S:$E($P(Y(0),D,58))'="." $P(Y(8),D,29)=$P(Y(0),D,58)	 ; Logistic%
	.. S:$E($P(Y(0),D,58))="." $P(Y(8),D,30)=$E($P(Y(0),D,58),2,99) ; Logistic Amount
	.. S:$E($P(Y(0),D,56))="." $P(Y(8),D,31)=$E($P(Y(0),D,56),2,99) ; Suppl Amount
	.. M ^mtemp99(GRIDID,"COMMON",COUNT)=Y
RFZ	Q OK
	;
URREF(UR,U60)	
	I $E(UR)="U" S UR=+$E(UR,2,99)
	D S2^cFN48 ; output K1 is tekststring en bevat leveringnr., referentie, datum
	I '$L(K1) G URREFZ
	K Y S COUNT=COUNT+1,$P(Y(0),D,5)=K1,$P(Y(8),D)=COUNT,$P(Y(8),D,2)=$P($T(@("T4"_QTD)),U,2),$P(Y(8),D,3)=2
	M ^mtemp99(GRIDID,"COMMON",COUNT)=Y
URREFZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09