cAN0091(TQ,DMS)	;Printen integriteit indexen ;%AN009 ; [ 01/05/01  2:56 PM ]
	;
T0	;Integriteit index-bestanden;
T1	;UI1`code`omschrijving\;
T2	;B-Index    Theoretische waarde                UI1 uit index ;
T3	;           Huidige waarde                     Berekend via UI1 uit index;
	;
T0F	;Intégrité fichiers index;
T1F	;UI1`code`description\;
T2F	;B-Index    Valeur théorétique                 UI1 de l'index ;
T3F	;           Valeur actuelle                    Obtenu via UI1 de l'index;
	;
T0E	;Integrity index file;
T1E	;UI1`code`description\;
T2E	;B-Index    Aspected value                     UI1 from index ;
T3E	;           Actual value                       Calculated via UI1 from index;
	;
1	N UQC,USC,UI1
	;
HD	S HD(1)=D_$P($T(@("T0"_QT)),U,2)_";C;F85",HD(2)="",HD(3)=D
TIT	S TIT(1)=$P($T(@("T1"_QT)),U,2)
	S TIT(2)=$P($T(@("T2"_QT)),U,2)
	S TIT(3)=$P($T(@("T3"_QT)),U,2)
TAB	S TAB="79"
	k TXT
	;
4	S TQ=$G(TQ),DMS=$G(DMS),LOG="^DCIND",SWT=0
	S IQ="" I $L(TQ) G YZ:'$D(@LOG@(TQ)) S IQ=$O(@LOG@(TQ),-1)
	F  S IQ=$O(@LOG@(IQ)) Q:(IQ'=TQ&$L(TQ))!'$L(IQ)  D
	. S IDMS=""
	. I $L(DMS) Q:'$D(@LOG@(TQ,DMS))  S IDMS=$O(@LOG@(TQ,DMS),-1)
	. F  S IDMS=$O(@LOG@(IQ,IDMS)) Q:(IDMS'=DMS&$L(DMS))!'$L(IDMS)  D
	.. S TOP=$G(^(IDMS,0,0)),SW=0
	.. I '$L($O(@LOG@(IQ,IDMS,0))) Q
	.. S UQC=$P(TOP,D,5),USC=$P(TOP,D,6)
	.. S TOP(1,1)=$P(^DMS(IQ,IDMS,0),D,QTU-1*10+1)_U_2
	.. S TOP(2,1)="UQC="_UQC_", USC="_USC_", UREF="_$P(TOP,D,7)_U_2
	.. S TOP(3,1)="IREF="_$P(TOP,D,8)_", IREF2="_$P(TOP,D,9)_U_2
	.. S TOP(4,1)=$TR($P(TOP,D,1,2),D," ")_" - "_$TR($P(TOP,D,10,11),D," ")_U_2
	.. S TAB=79
	.. I $G(SWT) S END=4 D ^cA334
	.. S UI1=0
	.. F  S UI1=$O(@LOG@(IQ,IDMS,UI1)) Q:UI1=""  D
	... I SW S END=3 D ^cA334 S SW=0
	... D UI1
	... S BI=""
	... F  S BI=$O(@LOG@(IQ,IDMS,UI1,BI)) Q:BI=""  D
	.... S A=^(BI)
	.... I $D(BLZ),$G(LN)+4>$G(LNMAX) S LN=999,SW=0
	.... S TAB="10\45\79"
	.... S TXT(1)=BI,TXT(2)=$P(A,D),TXT(3)=$P(A,D,2) D:LN+1>LNMAX UI1 D ^cA334 
	.... S TXT(1)="",TXT(2)=$P(A,D,3),TXT(3)=$P(A,D,4) D:LN+1>LNMAX UI1 D ^cA334
	.... S SW=1,SWT=1
	;
END	I $G(SWT),$G(BLZ) S END=$S($G(SWMORE):4,1:1) D ^cA334
	;
YZ	Q
	;
UI1	;--------------------------------------------------------------------------
	N TXT,TAB
	S TAB=79
	D  
	. N Q S Q=IQ
	. S TXT(1)=UI1_"`"_$TR($P($$SGN^cAFA1(IDMS,UI1,0),D,1,2),D,"`")_"`"
	I $D(BLZ) I LN+3>LNMAX S END=4 D ^cA334
	D ^cA334
	Q
	;
ZZ	; 29.10.02 - 11 u 38 * V7.93