cAN1014 ;Synoniemen via HG-GR-SG ;%AN101 ;do uit %AN1013 ; [ 01/04/01  8:19 AM ]
 G 1
 ;
T0 ;Selectie item ;
 ;
T0F ;Sélection sujet ;
 ;
T0E ;Selection item ;
 ;
S1(S1,S2)          ; volgende (1) of vorige (-1) index
S1A K J S J=$O(@RSD@(S1),S2) I $L(J) S J(0)=^(J)
S1B I $E(RSI(1))'="*",$E(J,1,$L(RSJ(1)))'=RSJ(1) S J=""
S1C I $E(RSI(1))="*",$L(J),$P(J," ")'[RSJ(1) S S1=J G S1A
S1D I J="",S2<0 S J=0
S1Z Q
 ;
 ; tonen van de lijn
S2 N K,S1,S2,UI1,VAN,LEN,TOT,MAX,ZZ S $ZT="TRAP^cAN000"
S2A S MAX=$P(QW(QW),D,4)-($P(QW(QW),D,5)*2),ZZ=$J("",MAX)
S2B S S1="" F  S S1=$O(RSM("LAY",S1)) Q:S1=""  S S2=RSM("LAY",S1) D
 . S UI1=RSL(I,0),K=$P($G(@RSREF@($P(S2,D)\100-1)),D,$P(S2,D)#100)
 . S VAN=$P(S2,D,2),LEN=$P(S2,D,3),TOT=VAN+LEN-1
 . I $L($P(S2,D,5)) X $P(S2,D,5) ; wat ipv K
 . I $P(S2,D,4) S K=$J(K,LEN)    ; rechts
 . E  S K=$E(K_$J("",LEN),1,LEN) ; links
 . S ZZ=$S(VAN>1:$E(ZZ,1,VAN-1),1:"")_K_$S(TOT<MAX:$E(ZZ,TOT+1,MAX),1:"")
S2Y W /CUP(I+2,1),ZZ S RSL(I,9)=ZZ
S2Z Q
 ;
 ; test op niveau & 2° input & filter
S3() N S1,S2,UI1 S S1=1
S3A S UI1=J(0),S2=+$P($G(@RSREF@(0)),D,30) I S2'=RSN S S1=0
S3B I S1,$L(RSJ(2)) D
 . S S2=$P($G(^(RSM(2,"B")\100-1)),D,RSM(2,"B")#100)
 . S S2=$$DP^cAFA1($$UC^cAFA1(S2))
 . I $E(RSI(2))'="*",$E(S2,1,$L(RSJ(2)))'=RSJ(2) S S1=0
 . I $E(RSI(2))="*",S2'[RSJ(2) S S1=0
S3C I S1,$L($G(RSFLT)) X RSFLT S S1=$T
S3Z Q S1
 ;
 ; balk aan/af
BALK(C) W /CUP(II+2,1),/SGR(C),$G(RSL(II,9),$J("",$P(QW(QW),D,4)-($P(QW(QW),D,5)*2)))
BALKZ W /CUP(II+2,1),/WDSP Q
 ;
1 W /WSCROFF,/CUP(3,1),/WCMD,/WDSP n RSL
11 S RSJ(1)=$$DP^cAFA1($$UC^cAFA1(RSI(1))),RSJ(2)=$$DP^cAFA1($$UC^cAFA1(RSI(2))) D
15 S II=1,J=$S($E(RSI(1))="*":"",1:RSJ(1))_" ",JJ=$P(QW(QW),D,3)-($P(QW(QW),D,5)*2)-2,RK=0
16 K RSL I $L($G(RSX)) D
 . N R,UI1
 . I RSDD=1 S UI1=$G(@$G(^DMC(UQC,USC,"DATA","OUD"))@(RSX))
 . I RSDD=2 S UI1=RSX_" "
 . I RSDD>2 S UI1=RSX
 . I $L(UI1) S R=$P($G(@RSREF@(RSM(1,"B")\100-1)),D,RSM(1,"B")#100)
 . S J=$$DI^cAN000($G(R),RSX),RSX=J F I=1:1:JJ D S1(J,-1) Q:J=0
17 S I=0 F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 S RSL(I)=J,RSL(I,0)=J(0) D S2 I J=$G(RSX) S II=I
19 I I=1,'RSCONF,'$L($G(RSX)) S RK=28 G 328
 ;
 ; scroll met balk
2 S RSV=RK D BALK(7)
21 D ^cAFA0(RK,0,0,0,0,"23\24\25\26\31\32"_RSKEYS,0,0,0)
 ;
3 ; speciale funkties
320 I $D(^DMC(UQC,USC,"SYN",0,0,RK,0)) G Y
323 I RK=23 D  G 2                                              ; Home
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0) S II=1 I '$D(RSL(JJ)) Q
 . K RSL W /CUP(3,1),/WCMD
 . S I=0,J=$S($E(RSI(1))="*":"",1:RSJ(1))_" " F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 D
 .. S RSL(I)=J,RSL(I,0)=J(0)
 . F I=JJ:-1:1 I $D(RSL(I)) D S2 S II=I
324 I RK=24 D  G 2                                              ; End
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0) S II=$O(RSL(""),-1) I '$D(RSL(JJ)) Q
 . K RSL W /CUP(3,1),/WCMD
 . S I=0,J=$S($E(RSI(1))="*":"",1:RSJ(1))_"~" F  Q:I=JJ  D S1(J,-1) Q:J=0  I $$S3 S I=I+1 D
 .. F II=I:-1:2 M RSL(II)=RSL(II-1) K RSL(II-1)
 .. S RSL(1)=J,RSL(1,0)=J(0)
 . F I=1:1:JJ I $D(RSL(I)) D S2 S II=I
325 I RK=25 D  G 2                                              ; PgUp
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0) I II=1 S RSV=RK
 . S II=1 I RK'=RSV Q
 . S I=1,J=RSL(1) F  Q:I=JJ  D S1(J,-1) Q:J=0  I $$S3 S I=I+1 D
 .. F II=JJ:-1:2 K RSL(II) M RSL(II)=RSL(II-1)
 .. K RSL(1) S RSL(1)=J,RSL(1,0)=J(0)
 . F I=JJ:-1:1 D S2 S II=I
326 I RK=26 D  G 2                                              ; PgDn
 . I '$D(RSL(JJ)) D BEL Q
 . D BALK(0) I II=JJ S RSV=RK
 . S II=$O(RSL(""),-1) I RK'=RSV!'$D(RSL(JJ)) Q
 . S I=1,J=RSL(JJ) F  Q:I=JJ  D S1(J,1) Q:J=""  I $$S3 S I=I+1 D
 .. F II=1:1:JJ-1 K RSL(II) M RSL(II)=RSL(II+1)
 .. K RSL(JJ) S RSL(JJ)=J,RSL(JJ,0)=J(0)
 . F I=1:1:JJ D S2 S II=I
327 I RK=27 G Y                                                 ; Esc
328 I RK=28 S K=$G(RSL(II,0)) S:K="" RK=29 G Y                  ; Enter
329 I RK=29 G Y                                                 ; Tab
331 I RK=31 D  G 2                                              ; Pijl ^
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0)
 . I II>1 S II=II-1 Q
 . S I=0,J=RSL(1) F  Q:I  D S1(J,-1) Q:J=0  I $$S3 D
 .. F II=JJ:-1:2 I $D(RSL(II-1)) M RSL(II)=RSL(II-1)
 .. S RSL(1)=J,RSL(1,0)=J(0)
 .. F I=JJ:-1:1 I $D(RSL(I)) D S2 S II=I
332 I RK=32 D  G 2                                              ; Pijl v
 . I '$D(RSL(1)) D BEL Q
 . D BALK(0)
 . I II<$O(RSL(""),-1) S II=II+1 Q
 . I $D(RSL(JJ)) S I=0,J=RSL(JJ) F  Q:I  D S1(J,1) Q:J=""  I $$S3 D
 .. F II=1:1:JJ-1 M RSL(II)=RSL(II+1)
 .. S RSL(JJ)=J,RSL(JJ,0)=J(0)
 .. F I=1:1:JJ D S2 S II=I
 ;
39 D BEL G 21
 ;
Y D BALK(0) K RSD,RSL,RSX
YZ Q
 ;
BEL W $C(7) Q     
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84