cAN210	;Horizontaal beheerprogramma ;%AN210 ; [ 01/04/01  8:48 AM ]
	G YZ
	;
T0	;Horizontaal beheerprogramma ;
T1	;Openen;Beheer;Raadplegen;Verwijderen;
	;
T0F	;Programme de gestion horizontal ;
T1F	;Création;Gestion;Consultation;Annulation;
	;
T0E	;Horizontaal beheerprogramma ;
T1E	;Creation of;Administration of;Consultation of;Remove;
	;
	; raadplegen   *** niet meer gebruiken voor nieuwe toepassingen ***
R(USH,UQH,UQC,UQM)	S J="R",K=4,R="^cAN213" G 0
	; Beheer       *** niet meer gebruiken voor nieuwe toepassingen ***
B(USH,UQH,UQC,UQM)	S J="R",K=3,R="^cAN212" G 0
	;              ^
	;        fout  |______
	;                     |  juist
	; Beheer Scroll       v
BS(USH,UQH,UQC,UQM,USORT,UDDET)	S J="W",K=3,R="^cAN214" G 0
	; Raadplegen Scroll
RS(USH,UQH,UQC,UQM,USORT,UDDET)	S J="R",K=4,R="^cAN214" G 0
	;
	; Beheer Teksten
BT(USH,UQH,UQC,UQM,TXTREF,UDDET)	S J="W",K=3,R="^cAN211" G 0
	; Raadplegen Teksten
RT(USH,UQH,UQC,UQM,TXTREF,UDDET)	S J="R",K=4,R="^cAN211" G 0
	;
	; test
0	I $S\1024<10 D PGMOV^cAFA1 G YZ
	;
	; algemene initialisatie
1	N UATT,UATTL,UDD,UFLT,UFU,UI1,UIND,UREF,USC,USCR,USEP,USM,UTIM,UTIT,UTOP,UTX,RSD,RSL,II,JJ,RSKEYS,OK
10	S $ZT="TRAP^cAN000"
11	S UFU=J,UTX=$P($T(@("T1"_QT)),U,K)
12	G YZ:$G(USH)="",YZ:$G(UQH)="",YZ:'$D(^DMH(UQH,USH,0,"DMC"))
13	S USC=^("DMC"),USM=$G(^("M")),UTIT=$G(^("TIT")),UIND=$G(^("INDEX"))
15	I $G(^("COM")) X $P(^("COM"),D,2)
17	S I=$G(^DMH(UQH,USH,0,"WIN")) I $L(I) F J=1:1:8 S $P(I,D,J)=+$P(I,D,J)
19	S J=I
	;
	; window + titel tonen
2	I 'UTIT D:$L(J) O^cA612($P(J,D),$P(J,D,2),$P(J,D,3),$P(J,D,4),$P(J,D,5),$P(J,D,6),$P(J,D,7),$P(J,D,8)) G 3
21	S I=$$TIT(.UTIT)
23	I '$P(UTIT,D,5) S I=UTX_" "_I
24	I $P(UTIT,D,8)=1 S I=$$UC^cAFA1($E(I))_$E(I,2,99)
25	I $P(UTIT,D,8)=2 S I=$$UC^cAFA1(I)
26	I '$L(J) D T^cA612(I,$P(UTIT,D,2),$P(UTIT,D,3),$P(UTIT,D,4),$P(UTIT,D,6),$P(UTIT,D,7)) G 3
27	D P^cA612($P(J,D),$P(J,D,2),$P(J,D,3),$P(J,D,4),$P(J,D,5),$P(J,D,6),$P(J,D,7),$P(J,D,8),I,$P(UTIT,D,2),$P(UTIT,D,3),$P(UTIT,D,4),$P(UTIT,D,6),$P(UTIT,D,7))
	;
	; reference + scroll + separator + tekst + filter + top
3	S UDD=^DMC(UQC,USC,"DATA"),UREF=^("DATA","REF")
31	S USCR=$G(^DMH(UQH,USH,0,"SCR")),USEP=$G(^("SEP")),UTX=$G(^("TXT"))
32	S UATT=7,UTIM=$G(^("REF")) I $L($G(^("ATT"))) S UATT=^("ATT")
33	S:$P(USCR,D)="" $P(USCR,D)=2 S:$P(USCR,D,2)="" $P(USCR,D,2)=$P(QW(QW),D,3)-($P(QW(QW),D,5)*2)
34	I USEP="" S USEP="$C(32)"
35	S UFLT=$G(^("FLT")) F I=1:1:3 S J=$P(UFLT,D,I) D
	. I $E(J)="@" S $P(UFLT,D,I)=$G(@$E(J,2,999))
37	S UTOP=$G(^("TOP")) I UTOP S OK=1 X $P(UTOP,D,2) I OK D TOP
39	D REFTOP
	;
	; overgang naar functionaliteit
4	N EXIT,REFRESH,REFTOP G @R
	;
YZ	Q
	;
TIT(UTIT)	; bepalen titel
	I $P(UTIT,D,5)=3 S I="" I $L($G(^DMH(UQH,USH,0,"TIT","X"))) X ^("X")   ; spec. execute
	I $P(UTIT,D,5)=2 S I=$P(^DMH(UQH,USH,0,"TIT","ALT"),D,QTU)          ; alternatieve titel
	I $P(UTIT,D,5)<2 S I=$P(^DMC(UQC,USC,"TAAL",$E(QT_"N")),D,2)
TITZ	Q I
	;
	; omvormen UTOP voor scherm
TOP	N R1,R2,R3,R4 S R1=$D(UTOP(1)),R2=$D(UTOP(2)),R3=$D(UTOP(3)) D
	. I R1 S R4=$L(UTOP(1))
	. I R2,$L(UTOP(2))>R4 S R4=$L(UTOP(2))
	. I R3,$L(UTOP(3))>R4 S R4=$L(UTOP(3))
TOPA	I R1 S UTOP(1.1)=2-R3_D_(R4+2)_D_": "_$E(UTOP(1.1),1,80-R4-5)_D_0,UTOP(1)=2-R3_D_1_D_UTOP(1)_D_4
TOPB	I R2 S UTOP(2.1)=3-R3_D_(R4+2)_D_": "_$E(UTOP(2.1),1,80-R4-5)_D_0,UTOP(2)=3-R3_D_1_D_UTOP(2)_D_4
TOPC	I R3 S UTOP(3.1)=3_D_(R4+2)_D_": "_$E(UTOP(3.1),1,80-R4-5)_D_0,UTOP(3)=3_D_1_D_UTOP(3)_D_4
TOPZ	Q
	;
	; refresh TOP
REFTOP	N I,J W /SGR(0) S I="" F  S I=$O(UTOP(I)) Q:I=""  S J=UTOP(I) W /CUP($P(J,D),$P(J,D,2)),/SGR(+$P(J,D,4)),$P(J,D,3),/SGR(0)
REFTOPZ	Q
	;
ZZ	; 04.04.05 - 14 u 29 * V8.03