cAN2140 ;Sorteren ;%AN214 ; [ 01/04/01  8:58 AM ]
 G 1
 ;
T0 ;Sorteren ;
 ;
T0F ;Triage ;
 ;
T0E ;Sorting ;
 ;
 ; volgende (1) of vorige (-1) index
S1(UI1,S2)         I $P(USCR,D,3) S S2=$S(S2<0:1,1:-1)
S1A K J S J=$O(@RSD,S2) I $L(J) S J(0)=$S(UIND:^(J),1:J)
S1Z Q
 ;
 ; ophalen data (meerdere velden worden geconcateneerd)
S2 S K="" F JJ=1:1 Q:'$D(I(JJ))  D
 . S K=""
 . S UI1=J(0)                                      ; K bepalen per veld
 . I UDD<5 S K=$P($G(@UREF@(I(JJ)\100-1)),D,I(JJ)#100)
 . I UDD=5 S K=$P($G(@UREF),D,I(JJ)#100)
 . I $L(K),$L(UREF(JJ)),II(JJ) S UI1=K D           ; doorschakelen
 .. I UDD(JJ)<3 S UI1=$O(@IREF(JJ)@(101,K_" ")),UI1=$S($P(UI1," ")=K:^(UI1),1:"") I UI1="" Q
 .. I UDD(JJ)<5 S K=$P($G(@UREF(JJ)@(II(JJ)\100-1)),D,II(JJ)#100)
 .. I UDD(JJ)=5 S K=$P($G(@UREF(JJ)),D,II(JJ)#100)
 . S K(JJ)=$$DI^cAN000(K,"")
S2A S K="" F JJ=1:1 Q:'$D(I(JJ))  S K=K_K(JJ)
S2Z S K=K_J Q
 ;
 ; test op filter
S3() N S1,S2,UI1 S S1=1,UI1=J(0) D
 . I $L($P(UFLT,D)) S S1=0,S2=$P(UFLT,D) D
 .. I S2=+S2,J>S2 S S1=1 Q
 .. I S2'=+S2,J]S2 S S1=1
 . I S1,$L($P(UFLT,D,2)) S S1=0,S2=$P(UFLT,D,2) D
 .. I S2=+S2,J<S2 S S1=1 Q
 .. I S2'=+S2,S2]J S S1=1 Q
 .. S J="~~~"  ; J naar einde bestand zetten
 . I S1,$L($P(UFLT,D,3)) X $P(UFLT,D,3) S S1=$T
S3Z Q S1
 ;
 ; initialisatie : hoe sorteren?
 ; er kunnen meerdere velden zijn, max. 1x doorschakelen per veld
 ; I(n)    : veld n, b-index 1' bestand
 ; II(n)   : veld n, b-index 2' bestand
 ; UDD(n)  : veld n, data-type 2' bestand
 ; UREF(n) : veld n, referentie 2' bestand
 ; IREF(n) : veld n, indexref.  2' bestand
1 D EG^cAFA1
 N REFRESH,UI1
11 S I=$G(^DMH(UQH,USH,0,"SORT",USORT))
13 F JJ=1:1:$L(I,U) Q:'$L($P(I,U,JJ))  D
 . S UREF(JJ)=$P($P(I,U,JJ),D,2),II(JJ)=$P($P(I,U,JJ),D,3),I(JJ)=+$P(I,U,JJ) I $L(UREF(JJ)) D
 .. N UQC,USC
 .. D DMS^cAN000("UQC","USC",UREF(JJ))
 .. I $L(UQC),$L(USC) S UDD(JJ)=^DMC(UQC,USC,"DATA"),UREF(JJ)=^("DATA","REF"),IREF(JJ)=^("INDEX")
 .. E  S (II(JJ),UREF(JJ))=""
 ;
 ; hersorteren
2 S RSD=UREF I UIND S RSD=^DMC(UQC,USC,"DATA","INDEX"),RSD=$E(RSD,1,$L(RSD)-1)_","_UIND_",UI1)"
21 S J=$P(UFLT,D,1+$P(USCR,D,3))
23 F  D S1(J,1) Q:J=""  I $$S3 D S2 S ^HULP("SORT",RSORT,K)=J(0)
 ;
 ; einde sorteren
Y F JJ=1:1 Q:'$D(I(JJ))  K I(JJ),II(JJ),UDD(JJ),UREF(JJ),IREF(JJ),K(JJ)
YZ D C^cA612 Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84