cAN2271	;Textbestanden;cAN2271
	G YZ
	;
T0	;Textbestanden ;
T1	;U kan maximaal ; bestanden definiëren ;
T2	;Beheer textbestanden;
T3	;Controlelijst textbestanden;
T4	;Vrije velden textbestanden;
	;
T0F	;Fichiers text ;
T1F	;Vous ne pouvez définier que 99 fichiers ;
T2F	;Gestion des fichiers text;
T3F	;Liste de contrôle des text;
T4F	;Champs libres des text;
	;
T0E	;Textfiles;
T1E	;You can only define up to 99 files ;
T2E	;Administration textfiles;
T3E	;Checklist textfiles;
T4E	;Free fields textfiles;
	;
CONV	; Bestaande text bestanden in TEXT.VV zetten
	N I1,UI1,STRING,BEHEER
	S $ZT="TRAP^cAN000"
	K ^DTEXT(0,"TEXT.VV")
	; Aflopen DMC's van alle text bestanden
	S I1="TEXT."
	F  S I1=$O(^DMC(0,I1)) Q:$E(I1,1,5)'="TEXT."  D
	. I I1="TEXT.VV" Q
	. I I1="TEXT.0" Q
	. S UI1=$P(I1,"TEXT.",2)
	. ; Nummer textbestand
	. S STRING=UI1
	. ; Omschrijving Ned.
	. S $P(STRING,D,2)=$P($G(^DMC(0,I1,"TAAL","N")),D)
	. ; Omschrijving Frans
	. S $P(STRING,D,12)=$P($G(^DMC(0,I1,"TAAL","F")),D)
	. ; Omscrhijving Duist
	. S $P(STRING,D,22)=$P($G(^DMC(0,I1,"TAAL","D")),D)
	. ; Omschrijving Engels
	. S $P(STRING,D,32)=$P($G(^DMC(0,I1,"TAAL","E")),D)
	. ; Type bestand
	. S $P(STRING,D,7)=$E(UI1)
	. S ^DIN(0,"TEXT.VV",$E(UI1))=UI1+1
	. ; Lengte code
	. S $P(STRING,D,3)=$P($G(^DMC(0,I1,"SYN",1,1,"TAAL","N")),D,2)
	. ; Lengte omschrijving
	. S $P(STRING,D,4)=$P($G(^DMC(0,I1,"SYN",1,2,"TAAL","N")),D,2)
	. S ^DTEXT(0,"TEXT.VV",UI1,0)=STRING
	S BEHEER=1
	D S1^cAN002(0,"TEXT.VV",24)
CONVZ	Q
	;
	; oproepen synoniemen vanuit vrije velden
SYN(DMS)	S K=$$^cANSYN(DMS,"",K)
SYNZ	Q
	;
MAX	S K=$P($T(T1),U,2)_((BEHEER*1000)+999)_$P($T(T1),U,3) D TXT^cAFA1(250)
MAXZ	Q
	;
	; Stap 1: controle op nummer bestand
STAP1	S $P(B(1),D)=UI1,OK=2
	I UI1>((BEHEER*1000)+999) D MAX S OK=0
	G YZ
	;
	; Stap 2: kopiëren standaard definitie + éénmalige wijzigingen + Stap 3
STAP2	M ^DMA(0,"TEXT."_UI1)=^DMA(0,"TEXT.0")
	S ^DMA(0,"TEXT."_UI1,0,"DMS")="TEXT."_UI1
	;
	M ^DMC(0,"TEXT."_UI1)=^DMC(0,"TEXT.0")
	S I=^DMC(0,"TEXT."_UI1,"DATA","INDEX")  D VERVANG S ^("INDEX")=I
	S I=^DMC(0,"TEXT."_UI1,"DATA","INDEX2") D VERVANG S ^("INDEX2")=I
	S I=^DMC(0,"TEXT."_UI1,"DATA","REF")    D VERVANG S ^("REF")=I
	S I=^DMC(0,"TEXT."_UI1,"DIN")           D VERVANG S ^("DIN")=I
	S I=^DMC(0,"TEXT."_UI1,"LOGGING")       D VERVANG S ^("LOGGING")=I
	S I=^DMC(0,"TEXT."_UI1,"LOGGING","TOP") D VERVANG S ^("TOP")=I
	S I=^DMC(0,"TEXT."_UI1,"SYN",0,0,2,0)   D VERVANG S ^(0)=I
	;
	M ^DMS(0,"TEXT."_UI1)=^DMS(0,"TEXT.0")
	S $P(^DMS(0,"TEXT."_UI1),D,2)="TEXT."_UI1
	S $P(^DMS(0,"TEXT."_UI1,0),D,4)="TEXT."_UI1
	S $P(^DMS(0,"TEXT."_UI1,"DMA","O"),D,2)="TEXT."_UI1
	S $P(^DMS(0,"TEXT."_UI1,"DMA","W"),D,2)="TEXT."_UI1
	S $P(^DMS(0,"TEXT."_UI1,"DMA","L"),D,2)="TEXT."_UI1
	;
	G STAP3
	;
	; Stap 3: wijzigingen overnemen uit definitie
STAP3	S ^DMA(0,"TEXT."_UI1,1,1,9)=$P(B(1),D,3)          ; code
	S ^DMA(0,"TEXT."_UI1,1,1,11)="$L(K)&$$UNIEK^cAFA1(""TEXT."_UI1_""",101,K)"
	S ^DMA(0,"TEXT."_UI1,1,2,9)=$P(B(1),D,4)          ; omschrijving
	S ^DMA(0,"TEXT."_UI1,1,3,9)=$P(B(1),D,4)
	S ^DMA(0,"TEXT."_UI1,1,4,9)=$P(B(1),D,4)
	S ^DMA(0,"TEXT."_UI1,1,5,9)=$P(B(1),D,4)
	;
	S $P(^DMC(0,"TEXT."_UI1,"TAAL","N"),D,2)=$$LC^cAFA1($P(B(1),D,2))
	S $P(^DMC(0,"TEXT."_UI1,"TAAL","F"),D,2)=$$LC^cAFA1($P(B(1),D,12))
	S $P(^DMC(0,"TEXT."_UI1,"TAAL","D"),D,2)=$$LC^cAFA1($P(B(1),D,22))
	S $P(^DMC(0,"TEXT."_UI1,"TAAL","E"),D,2)=$$LC^cAFA1($P(B(1),D,32))
	;
	S $P(^DMS(0,"TEXT."_UI1,0),D)=$$OMS^cAFA1("TEXT."_UI1,"N",2,1)
	S $P(^DMS(0,"TEXT."_UI1,0),D,11)=$$OMS^cAFA1("TEXT."_UI1,"F",2,1)
	S $P(^DMS(0,"TEXT."_UI1,0),D,21)=$$OMS^cAFA1("TEXT."_UI1,"D",2,1)
	S $P(^DMS(0,"TEXT."_UI1,0),D,31)=$$OMS^cAFA1("TEXT."_UI1,"E",2,1)
	D
	. N Q S Q=0 D S1^cAN002("DAM","DMS",0,0)          ; controle indexen
	;
	G YZ
	;
	; Definiëren vanuit 7.11.1
D	S BEHEER=1
	S FILTER="I $P($G(^DTEXT(0,""TEXT.VV"",UI1,0)),D,7)=1"
	D W^cAN200("TEXT.VV","","","","S UI1=$$^cANSYN(""TEXT.VV"","""","""","""","""","""",FILTER)")
	G YZ
	;
	; Definiëren vanuit ^cABI1
DDATAM	S BEHEER=$S(cs="PETC1":9,1:2)
	D W^cAN200("TEXT.VV","","","")
	G YZ
	;
	; Beheer
W	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T2"_QT)),U,2),0,0,7,1,1)
	S K=$$^cANSYN("TEXT.VV")
	I K D W^cAN200("TEXT."_K,"","","")
	G Y
	;
	; Controlelijst
L	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T3"_QT)),U,2),0,0,7,1,1)
	S K=$$^cANSYN("TEXT.VV")
	I K D L^cAN200("TEXT."_K,"","","")
	G Y
	;
	; Vrije velden
VV	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T4"_QT)),U,2),0,0,7,1,1)
	S K=$$^cANSYN("TEXT.VV")
	I K D ^cAN222("TEXT."_K,"","")
	G Y
	;
Y	D C^cA612
YZ	Q
	;
VERVANG	I I["TEXT.0" S I=$P(I,"TEXT.0")_"TEXT."_UI1_$P(I,"TEXT.0",2,99) G VERVANG
	Q
	;
ZZ	; 19.03.07 - 15 u 31 * V8.08