cANR11	; Print To File in Reflection On/off ; cANR11
	;
YZ	Q
	;
FILE(LOCATION)	; ophalen filename
	; LOCATION : niet verplicht in te vullen.
	;  indien ingevuld wordt de locatie uit ^DPAR(0,"PAR",RBA",1) overschreven met deze
	N A,FILE,NR
	S $ZT="TRAP^cAN000"
 	S A=$G(^DPAR(0,"PAR","RBA",1))
 	S FILE=$G(LOCATION)
 	S:'$L(FILE) FILE=$P(A,D)        ; uit parameters
 	S:'$L(FILE) FILE="C:\TEMP"      ; default
 	S FILE=$TR(FILE,"/","\") S:$E($L(FILE))'="\" FILE=FILE_"\"
 	L +@("NR"_$G(QU,"DAM"))
 	S NR=$P(A,D,2),NR=NR+1                ; ophalen nummer
 	I $P(A,D,3),NR>$P(A,D,3) S NR=1       ; boven de limiet ? Opnieuw beginnen
 	S $P(^DPAR(0,"PAR","RBA",1),D,2)=NR
 	L -@("NR"_$G(QU,"DAM"))
 	; Samenstellen naam van het bestand
 	S FILE=FILE_$G(QU,"DAM")_$TR($J(NR,4)," ",0)_".TXT"
FILEZ	Q FILE
	;
FORM(K,NR,SRT,TXT)	; bepalen dataformaat, beveiliging, functiekolom, subtotals, ...
	; K   = waarde
	; NR  = volgnr van de kolom
	; SRT = 0 = tekst, 1 = numerisch, 2 = datum (dd.mm.jj)	: niet verplicht
	;       indien niet ingevuld wordt dit hier bepaald
	; TXT = zoals TXT in algemeen printprogramma cA334 : niet verplicht
	N R
	I $G(PTS)'=4 G FORMZ   ; niet print to file via reflection
	S SRT=$G(SRT),TXT=$G(TXT),R=$P(TXT,D,20)
	I $L(R) S SRT=R
	; formaat
	I $L(SRT) S:SRT>2 SRT=0 S R=SRT G FORMA
	I $P($G(TXT),D,8) S R=1 G FORMA             ; totalen maken : general (getal)
	I $P($G(TXT),D,5) S R=1 G FORMA               ; afprinten via R3 : general (getal)
	I $P($G(TXT),D,9)=1 S R=1 G FORMA             ; alligneren op dec. :  general (getal)
	I $P($G(TXT),D,2)=1 S R=1 G FORMA             ; rechts uitlijnen : general (getal)
	I '$L(K) G FORMA
	I $P(K,D)?2N1"."2N1"."2N S R=2 G FORMA        ; datum dd.mm.jj
	S R=0                                         ; tekst
FORMA	I '$L($P($G(PTS("FORMAT")),D,NR)) S $P(PTS("FORMAT"),D,NR)=R
FORMZ	Q
	;
PAR(SRT,R)	; opzetten parameters
	; SRT=0 = file
	;     1 = formaat van de kolommen (in de vorm form. kol1\form. kol2... zie ook label FORM
	;     2 = titel
	;     3 = 1ste rij als header : 1 = ja
	;     4 = template
	;     5 = paswoord (paswoord van de beveiliging)
	;     6 = Beveilig volledig ExcelBlad
	;     7 = Fit To n Pages (horizontaal) n = aantal horizontale pagina's
	;     8 = Orientatie : 1 = Portrait, 2 = Landscape
	;    
	I $G(PTS)'=4 G PARZ   ; niet print to file via reflection
	S SRT=$G(SRT) I '$L(SRT) G PARZ
	S SRT=$P("PR2FON\FORMAT\TITLE\HEAD\TEMPL\PWD\ALLPROTECT\FTPHOR\PAGEORIENT\",D,SRT+1)
	I $L(SRT),'$D(PTS(SRT)) S PTS(SRT)=R
PARZ	Q
	;
PR2FON(FILE)	; Print To File On + invullen locatie
	D START^cANR0("PrintToFile")
	; indien file="" betekent dit print to file OFF
	I '$D(FILE) S FILE=$G(PTS("PR2FON")) I '$L(FILE) S FILE=$$FILE()  ; indien geen file doorgegeven automatisch ophalen
 	W FILE,!
 	D STOP^cANR0
PR2FONZ	Q FILE
	;
PR2FOFF()	; Print To File OFF
	Q $$PR2FON("")
	;
ZZ	; 18.08.04 - 16 u 29 * V8.01