cAT111	;BTW-listing ;%AT11 ; [ 06/19/01  9:29 AM ]
	G 1
	;
T0	;BTW-listing ;
T1	;Controlelijst;Blz :;Overdrachttotaal;Eindtotaal;Onbekend;
T2	;Nummer; Naam van de rekening; BTW-nummer; Omzetcijfer;  BTW-bedrag;
	;
T0F	;Listing annuel de TVA ;
T1F	;Liste contrôle;Page:;Total à transférer;Total final;Inconnu;
T2F	;Numéro; Nom du compte; N° de TVA;  Ch. d'aff.; Montant TVA;
	;
T0E	;VAT-report ;
T1E	;Check report;Page:;Transfer total;Final total;Unknown;
T2E	;Number; Account name; VAT number; Turnover;  VAT amount;
	;
R3	S R1=$P(R,D,2),R2=$P(R,D,4),R0=$J($P(R,D),0,R2),R3=" ",R4="" S:R2 R4=","_$P(R0,".",2),R1=R1-1-R2 S:R0<0 R3="-",R0=-R0
R3A	S R0=+$P(R0,".") F R5=3,7 S R6=$L(R0) Q:R6'>R5  S R0=$E(R0,1,R6-R5)_"."_$E(R0,R6-R5+1,R6)
R3B	W ?$P(R,D,3),$J(R0,R1),R4,R3
R3Z	K R0,R1,R2,R3,R4,R5,R6 Q  ;V3 05.07.88
	;
	; samenstelling per recordtype
REC1	;6\N;94\C;10\N;18\C;
REC2	;6\N;32\C;24\C;27\C;1\C;10\N;20\C;1\C;4\N;3\C;
REC	;6\N;32\C;24\C;4\C;23\C;1\C;10\N;10\N;10\N;8\C;
REC9	;6\N;16\N;16\N;51\C;1\C;10\N;28\C;
	;
	; opbouw + schrijven record
S1	S S1=$T(@("REC"_$P(R,D))),S2="",S3=1
S1A	S S3=S3+1,S4=$P(S1,U,S3),S6=$P(R,D,S3) G S1Y:S4="" S S5=$P(S4,D,2),S4=+S4,S6=$E(S6,1,S4)
S1B	I S5="C" S S6=S6_$J("",S4-$L(S6)) G S1D
S1C	I $L(S6)<S4 S S6=0_S6 G S1C
S1D	S S2=S2_S6_VS G S1A
S1Y	S ^HULP("TR",Q,TNR,TVG)=S2_RS
S1Z	K S1,S2,S3,S4,S5,S6 Q
	;
	; kolommen printen
S2	W !,@F30 F K=1:1:5 D S3:'LN W ?$P(TAB,D,K),@F30
S2Z	W $$CR^cA334 Q
	;
	; streepjeslijn
S3	S S1=$S(K>1:$P(TAB,D,K-1),1:0),S2=$P(TAB,D,K)-2 F S3=S1:1:S2 W "-"
S3Z	K S1,S2,S3 Q
	;
	; sorteren/groeperen op BTW-nr
1	S QQ=Q,Q=$P(XQ,U),HQ=$P(XQ,U,2,999),I1=" ",FP=2201 W @F,@F1 K ^TEMP(boot,$J)
10	S K=$$BJ^cAFE1(Q,KJ+.12),MNT=$$MNTC^cAFE1(Q,K),BF=$P(MNT,D),QD=$P(MNT,D,2)
	S LL=$P(@("^"_Q_"BA(39)"),D,4) I LL="" S LL="BE"       ; VJ 15.02.01
11	S I1=$O(@("^"_Q_"KL(I1)")) G 19:I1="",11:'$D(^(I1,0)),11:'$D(^(KJ+.01)),11:'$P(^(KJ+.01),D,2)
13	S L=^(KJ+.01),A(1)=$P(L,D,2),A(2)=$P(L,D,3)+$P(L,D,4),L=^(0),BTW=$P(L,D,16),KC=$P(L,D) W @F,$J(KC,8)
	S BTWO=$$BTW^cAFO1(BTW)                                ; VJ 15.02.01
15	I $E(BTWO,1,$L(LL))=LL!(BTW="") D
	. S ^TEMP(boot,$J,$S(BTW="":" ",1:BTW),KC)=A(1)_D_A(2)_D_Q    ; per KC
	. S L=$G(^(0),D),^(0)=$P(L,D)+A(1)_D_($P(L,D,2)+A(2))_D_BTWO  ; per BTW
17	G 11
19	S Q=QQ I $L(HQ) S Q=$P(HQ,U),HQ=$P(HQ,U,2,999),I1=" " G 11
	;
	I $G(XML) G ^cAT1190XML
	;
	; volgens BTW-nr
2	I DEF,'DV G ^cAT1190 ; definitief en op papier
	; Definitief (DEF) en in bestand
	;  of
	; Proeflijst ('DEF) op papier en in bestand
20	S BTW="",(BLZ,LN,TEL,T(1),T(2))=0,NM1=@("^"_Q_"BA(99,1)"),NM2=^(2),NM3=^(3),FP=2201 W @F,@F1
	I DV S VS="",RS=$C(13,10)                               ; in bestand
21	I 'DV X F70 W @F80 S LNMAX=LNMAX-5,TAB="7\35\51\65\79"  ; op papier
23	S BTW=$O(^TEMP(boot,$J,BTW)) I BTW="" S Q=QQ G 5:DV D HD:'LN,XF W $$FF^cA334 X F71 G YZ
25	S L=^(BTW,0),A(1)=$P(L,D),A(2)=$P(L,D,2),BTWO=$P(L,D,3),KC=0
	I DEF G 23:$$NOPRINT^cAT1190()  ; KU : 08.01.08
	; I DEF,$E(BTWO,1,$L(LL))'=LL G 23
	; I DEF,$E(BTW,3,999)?1."0" G 23
	;  KU : 08.01.08  : BTW -> $$BTW(BTW)
27	S KC=$O(^TEMP(boot,$J,BTW,KC)) G 23:KC=""
	S L=^(KC),Q=$P(L,D,3)
	I 'DEF!'$$BTW(BTW) S A(1)=$P(L,D),A(2)=$P(L,D,2) 
	; I 'DEF!'BTW S A(1)=$P(L,D),A(2)=$P(L,D,2)
28	I A(1)<MIN G 23:$$BTW(BTW),27
	; I A(1)<MIN G 23:BTW,27
29	S TEL=TEL+1
	S I1=@("^"_Q_"K1(KC)"),L=@("^"_Q_"KL(I1,0)")  ; ophalen klantgegevens
	S Q=QQ
	I DV G 4  ; in bestand
	; indien proeflijst ('DEV)
	I $$SIG^cAFA1("ISO.LAND",$P(L,D,8),101)'="BE" S TEL=TEL-1 G 23:$$BTW(BTW),27
	I SEL=0,'$$BTW(BTW) G 3
	I SEL=1,$E(BTW,3,999)?1."0" G 3
	S TEL=TEL-1 G 23:$$BTW(BTW),27 
	;
	; printen
3	D HD:'LN I LN>LNMAX D XF G 3
31	I LN S LN=LN+1 D S2
33	S LN=LN+1 D S2 S K=$P(L,D,4) S:$L(K) K=K_" " S K=K_$P(L,D,2) W $J(TEL,6),?$P(TAB,D)+1,$E(K,1,27)
34	S LN=LN+1 D S2 W ?$P(TAB,D)+1,$E($P(L,D,5),1,27)
35	S LN=LN+1 D S2 S K=$P(L,D,6) S:$L(K) K=K_" " S K=K_$P(L,D,7) W ?$P(TAB,D)+1,$E(K,1,27)
37	S K=BTW,U3=BTWO I K?1."0" S U3=$P($T(@("T1"_QT)),U,6)  ; VJ 15.02.01
38	W ?$P(TAB,D,2)+1,U3 S R=A(1)_D_12_D_($P(TAB,D,3)+1)_D_QD D R3 S R=A(2)_D_12_D_($P(TAB,D,4)+1)_D_QD D R3
39	S T(1)=T(1)+A(1),T(2)=T(2)+A(2) G 23:DEF&$$BTW(BTW),27
	;
	; file
4	I BF="EUR" S A(1)=$J(A(1)*100,0,0),A(2)=$J(A(2)*100,0,0)
40	S R=$P(L,D,4) S:$L(R) R=R_" " S R=D_TEL_D_R_$P(L,D,2)_D_$P(L,D,5,7)_D_LL_D_$S((KJ<2006)&($E(BTW,3,999)?10N):$E(BTW,4,999),1:$E(BTW,3,999))_D_A(1)_D_A(2)_D
41	S TVG=TEL+9 D S1 W @F,$J(TEL,8) G 39
	;
	; einde file
5	S R=$E(NM1_$J("",32),1,32)_$E(NM2_$J("",24),1,24)_NM3
51	S R=1_D_555555_D_R_D_TEL_D,TVG=1 D S1
53	S R=2_D_0_D_NM1_D_NM2_D_NM3_D_LL_D_$E(UBTW,3,999)_D_D_$S(BF="EUR":"E",1:"B")_D_KJ_D,TVG=2 D S1
55	S R=9_D_999999_D_T(1)_D_T(2)_D_D_LL_D_$E(UBTW,3,999)_D,TVG=TEL+10 D S1
56	I BF="EUR" S T(1)=T(1)/100,T(2)=T(2)/100
57	S L=^(0),$P(L,D)=$P($T(@("T0"_QT)),U,2)_KJ,$P(L,D,4)=TEL,$P(L,D,6)="A:BTW.TVA",^(0)=L
	S K=$G(@("^"_Q_"BA")@("%T",13,"J")) I $L(K) S $P(L,D,6)=$TR(K,D,U),^HULP("TR",Q,TNR,0)=L
	G ^cAT112
	;
YZ	Q
	;
BTW(BTW) ; BTW-nr ingevuld '="" of verschillend van LL000...
	N R
	S R=1
	I '$L($TR(BTW," "))!($E(BTW,3,999)?1."0") S R=0
	Q R
	;
	; hoofding
HD	W:BLZ $$FF^cA334 S BLZ=BLZ+1,LN=0 W !,NM1 W:'DEF ?35,$P($T(@("T1"_QT)),U,2) W ?72,$P($T(@("T1"_QT)),U,3),$J(BLZ,3)
HDA	S (K,U3)=UBTW D S1^cA248 W !,NM2,?35,$P($T(@("T0"_QT)),U,2),": ",KJ,?72,DT,!,NM3,?35,U3,?73,TD,!
HDB	D S2 W !,@F30 F K=1:1:5 W $P($T(@("T2"_QT)),U,K+1),?$P(TAB,D,K),@F30
HDZ	D S2 Q
	;
	; overdracht/eindtotaal
XF	S LN=0 D S2 S LN=1 D S2 W ?$P(TAB,D)+2,$P($T(@("T1"_QT)),U,BTW=""+4)," ",BF S LN=0
XFA	S R=T(1)_D_12_D_($P(TAB,D,3)+1)_D_QD D R3 S R=T(2)_D_12_D_($P(TAB,D,4)+1)_D_QD D R3
XFZ	D S2 Q
	;
ZZ	; 08.02.08 - 15 u 00 * V9.00