cI227	;Conversie codebestanden;
	;
	G 1
	;
T0	;Conversie codebestanden;
	;
1	N I1,NIND,I,USA,UQA,BLZ,VAN,TOT,RUB,STR,INH,VV
11	S $ZT="TRAP^cAN000"
13	D ^cA106,^cA105 S ^HULP($T(+0),0)=DT_D_TD_D_QU_D_boot_D_cs_D_$J
15	S I1=9
17	F  S I1=$O(^DKODE(0,"CODE.VV",I1)) Q:I1=""!(I1>99)  D
	. S NIND=I1+990
	. S ^HULP($T(+0),"CODE."_I1)="CODE."_I1_D_"CODE."_NIND
	. M ^DKODE(0,"CODE.VV",NIND)=^DKODE(0,"CODE.VV",I1)
	. S $P(^DKODE(0,"CODE.VV",NIND,0),D)=NIND
	. S $P(^DKODE(0,"CODE.VV",NIND,0),D,7)=1
	. M ^DLOG(0,"CODE.VV",NIND)=^DLOG(0,"CODE.VV",I1)
	. K ^DKODE(0,"CODE.VV",I1)
	. K ^DLOG(0,"CODE.VV",I1)
	. ;  Converteren definities
	. ;  ^DMA
	. M ^DMA(0,"CODE."_NIND)=^DMA(0,"CODE."_I1)
	. S ^DMA(0,"CODE."_NIND,0,"DMS")="CODE."_NIND
	. S I=^DMA(0,"CODE."_NIND,1,1,11) D VERVANG S ^(11)=I
	. K ^DMA(0,"CODE."_I1)
	. ; ^DMC
	. M ^DMC(0,"CODE."_NIND)=^DMC(0,"CODE."_I1)
	. S I=^DMC(0,"CODE."_NIND,"DATA","INDEX") D VERVANG S ^("INDEX")=I
	. S I=^DMC(0,"CODE."_NIND,"DATA","INDEX2") D VERVANG S ^("INDEX2")=I
	. S I=^DMC(0,"CODE."_NIND,"DATA","REF") D VERVANG S ^("REF")=I
	. S I=^DMC(0,"CODE."_NIND,"DIN") D VERVANG S ^("DIN")=I
	. S I=^DMC(0,"CODE."_NIND,"LOGGING") D VERVANG S ^("LOGGING")=I
	. S I=^DMC(0,"CODE."_NIND,"LOGGING","TOP") D VERVANG S ^("TOP")=I
	. S I=^DMC(0,"CODE."_NIND,"SYN",0,0,2,0) D VERVANG S ^(0)=$P(I,"CODE."_I1)_"CODE."_NIND_$P(I,"CODE."_I1,2,99)
	. K ^DMC(0,"CODE."_I1)
	. ; ^DMS
	. M ^DMS(0,"CODE."_NIND)=^DMS(0,"CODE."_I1)
	. S $P(^DMS(0,"CODE."_NIND),D,2)="CODE."_NIND
	. S $P(^DMS(0,"CODE."_NIND,0),D,4)="CODE."_NIND
	. S $P(^DMS(0,"CODE."_NIND,"DMA","O"),D,2)="CODE."_NIND
	. S $P(^DMS(0,"CODE."_NIND,"DMA","W"),D,2)="CODE."_NIND
	. S $P(^DMS(0,"CODE."_NIND,"DMA","L"),D,2)="CODE."_NIND
	. K ^DMS(0,"CODE."_I1)
	. ;  Converteren data
	. M ^DKODE(0,"CODE."_NIND)=^DKODE(0,"CODE."_I1)
	. K ^DKODE(0,"CODE."_I1)
	. M ^DIN(0,"CODE."_NIND)=^DIN(0,"CODE."_I1)
	. K ^DIN(0,"CODE."_I1)
	. M ^DLOG(0,"CODE."_NIND)=^DLOG(0,"CODE."_I1)
	. K ^DLOG(0,"CODE."_I1)
	. M ^IND(0,"CODE."_NIND)=^IND(0,"CODE."_I1)
	. K ^IND(0,"CODE."_I1)
	. M ^INDEX(0,"CODE."_NIND)=^INDEX(0,"CODE."_I1)
	. K ^INDEX(0,"CODE."_I1)
	. S ^DIN(0,"CODE.VV",1)=NIND+1
19	D S1^cAN002(0,"CODE.VV","","")
	;
	;  ^DMS(0,"CODE.VV") moet altijd operationeel zijn + Menu 7.11 moet altijd opstaan.
2	S $P(^DMS(0,"CODE.VV",0),D,30)=""
21	S @("^"_Q_"BA(""MENU"",16,11)")="Codebestanden\15\3\16.11\M\16.11\\\\\Fichiers-code\\\\\\\\\\\\\\\\\\\\Codefiles"
	;
	; Scannen van alle DMA's met vrije velden op "CODE."_I1 en vervangen door "CODE."_NIND
3	S UQA=""
31	F  S UQA=$O(^DMA(UQA)) Q:UQA=""  D
	. S USA=""
	. F  S USA=$O(^DMA(UQA,USA)) Q:USA=""  D
	.. ; Testen of deze DMA vrije velden bezit
	.. I '$L($G(^DMA(UQA,USA,0,"VV"))) Q
	.. S INH=^DMA(UQA,USA,0,"VV")
	.. F i=1:1:$L(INH,D) s VV=$p(INH,D,i) i $L(VV) D
	... S BLZ=$P(VV,U)
	... S VAN=$P(VV,U,2)
	... S TOT=$P(VV,U,3)
	... S RUB=VAN-1
	... F  S RUB=$O(^DMA(UQA,USA,BLZ,RUB)) Q:RUB=""!(RUB>TOT)  D
	.... S STR=$G(^DMA(UQA,USA,BLZ,RUB,18))
	.... I '$L(STR) Q
	.... I '$D(^HULP($T(+0),STR)) Q
	.... S ^DMA(UQA,USA,BLZ,RUB,18)=$P(^HULP($T(+0),STR),D,2)
	;
YZ	Q
	;
VERVANG	I I["CODE."_I1 S I=$P(I,"CODE."_I1)_"CODE."_NIND_$P(I,"CODE."_I1,2,99)
	Q
	;
ZZ	; 07.05.02 - 17 u 05 * V7.92