cI3301	;Opsporen %Q1= ;%I3301 ; [ 03/28/00  12:15 PM ]
	;
T1	;Kies eerst uw groep van programma's.;
T2	;Daarna worden uit die groep alle programma's onderzocht.;
T3	;Dit programma zoekt naar :;
T4	;%Q1=^;%Q1="^;"%1";
T5	;Aantal gevonden : ;
T6	;Start <N>;
	;
	; init + uitleg
1	S $ZT="ERR^"_$T(+0)
	S Q=$G(Q) D ^cA604,MASTER^cQ5:'$D(boot)
11	w !!,$P($T(+1),U,2),!!,$P($T(T1),U,2),!!
13	f i=2:1:3 w $p($t(@("T"_i)),U,2),!
14	s x=$p($t(T4),U,2,99)
15	f i=1:1 s j=$p(x,U,i) q:j=""  w:i>1 ", " w:$x>69 ! w """",j,""""
	;
	; vraagstelling
2	I $ZV["MSM" d ^cRSEL S RGE="^UTILITY("_$J_")" I '$L($O(^UTILITY($J,""))) G YZ
	I $ZV'["MSM" D ^%RSETN("Routine(s): ","SD","MAC,INT,INC,OBJ","DEVN") S RGE="^mtemp("_%msub_",""@"",""INT"")",i=$o(@RGE@("")),RGE=$P(RGE,")")_","_i_")" I $O(^mtemp(%msub,""))="" K ^mtemp(%msub) G YZ
20	s (%DEV,dev)=$i  ; s dev=$i d CRT^cSDEV
21	w !,$p($t(T6),U,2) r k g 2:"-^"[k&$l(k) s k=$tr(k,"JjYy1","11110") g 21:k'=1
23	w ! i %DEV'=dev u %DEV
25	w !,$zu(5)," / " d @("^%D") w " / " d @("^%T")
	;
	; uitvoering
	; a = aantal lijnen in programma
	; i = loopvar.
	; j = loopvar.
	; l = lijn uit programma
	; p = naam programma in behandeling
	; s = aantal geconverteerde programma's
	; sw = switch programma geconverteerd (1=ja)
	; t = totaal aantal geselecteerde programma's
	; x = zoekcriteria
	; y = criterium
	; z = hulpvariabele
3	w !! s (s,p,t)=""
31	f  s p=$o(@RGE@(p)) q:p=""  d
	. s t=t+1 i $t(+0)=p q
	. i %DEV'=dev u dev w "." u %DEV
	. i p="%D" q
	. i $e(p,1,3)="%DI" q                   ; geen %DI*    MSM
	. i $e(p,1,3)="%DO" q                   ; geen %DO*    MSM
	. i $e(p,1,3)="%ER" q                   ; geen %ER*    MSM
	. i $e(p,1,2)="%I" q                    ; geen %I*     MSM + intern
	. i $e(p,1,4)="%MCO" q                  ; geen %MCO*
	. i $e(p,1,2)="%R" q                    ; geen %R*     MSM
	. i $e(p,1,2)="%S" q                    ; geen %S*     MSM
	. i p="%T" q
	. i $e(p,1,3)="SQL" q                   ; geen SQL*    MSM
	. k ^HULP(boot,$J)
	. x "zl @p f i=1:1 s l=$t(+i) q:'$l(l)  s ^HULP(boot,$J,i)=l"
	. s a=i-1,sw=0                          ; aantal lijnen, switch af
	. f i=1:1:a s l=^HULP(boot,$J,i) d
	.. i $e($p(l," ",2))=";" q              ; geen commentaarlijnen
	.. k z s swl=0 f j=1:1 s y=$p(x,U,j) q:y=""  i l[y d
	... i y["%1",$e(l,$f(l,y)-15,$f(l,y))["^TEMP(" Q
	... i y["%Q1",$e(l,$f(l,y)-5,$f(l,y)+10)["^TEMP(" Q
	... s z=$e(l,$f(l,y),999)
	... s (sw,swl)=1,z($f(l,y)-$l(y)-1)=$l(y)
	.. i swl s z="" d
	... w !,p,": +",i,!,l,!
	... f  s z=$o(z(z)) q:z=""  w ?z,$e("^^^^^^^^^^",1,z(z))
	... i %DEV=dev r k:5
	. i sw s s=s+1
33	w !!,$p($t(T5),U,2),s," / ",t,!
35	i %DEV'=dev w # c %DEV
	;
YZ	w ! Q
	;
ERR	I $ze["NOROUT"!($ze["NOPGM") W !,$ze s $ze="" G 31
	ZQ
	;
ZZ	; 15.04.03 -  9 u 31 * V7.94