cI370 ;Hernummeren verkoopfacturen ;%I37 ; [ 10/10/96  4:17 PM ]
 ;
 ; aflopen oude factuurnummers
1 s FNR=""
11 s FNR=$o(^HULP(H1,Q,FNR)) i FNR="" g YZ
13 s N=^(FNR),SW=0 f i=2:1:7 i $l($p(N,D,i)) s SW=1 q
15 g 11:SW s NNR=$p(N,D),FP=601 w @F,$j(FNR,8)," : ",NNR,@F1
17 l (^HULP(H1),@("^"_Q_"BA")):10 e  g YZ
 ;
 ; controle op nieuw nummer
2 s US="" f  s US=$o(@("^"_Q_"FA(US)")) q:US=""  i $d(^(US,NNR)) S SW=1 q
20 i SW s $p(^HULP(H1,Q,FNR),D,4)=US,$p(^(FNR),D,8)="bestaat reeds!" g 11
21 s BP="" f  s BP=$o(@("^"_Q_"VE(BP)")) q:BP=""  i $d(^(BP,NNR)) S SW=1 q
22 i SW s $p(^HULP(H1,Q,FNR),D,5)=BP,$p(^(FNR),D,8)="bestaat reeds!" g 11
23 i $d(@("^"_Q_"VEB(NNR)")) s KC=$o(^(NNR,0)),SW=1
24 i $d(@("^"_Q_"VF(NNR)")) s KC=$p(^(NNR),D),SW=1 i KC[" " s KC=$p(KC," ",2)
25 i SW s $p(^HULP(H1,Q,FNR),D,7)=KC,$p(^(FNR),D,8)="bestaat reeds!" g 11
 ;
 ; factuurdocument
3 s US="" f  s US=$o(@("^"_Q_"FA(US)")) q:US=""  i $d(^(US,FNR)) q
31 i $l(US) d
 . m @("^"_Q_"FA(US,NNR)")=@("^"_Q_"FA(US,FNR)")
 . k @("^"_Q_"FA(US,FNR)") s $p(^HULP(H1,Q,FNR),D,4)=US
 . s UR="" f  s UR=$o(@("^"_Q_"U1")@(US,UR)) q:UR=""  d
 .. i $p(^(UR),D,2)=FNR s $p(^(UR),D,2)=NNR
 .. i $d(^(UR,FNR)) s ^(NNR)=^(FNR) k ^(FNR)
 ;
 ; verkoopdagboek
4 s BP="" f  s BP=$o(@("^"_Q_"VE(BP)")) q:BP=""  i $d(^(BP,FNR)) q
41 i $l(BP) d
 . s ^(NNR)=^(FNR) k ^(FNR) d  s $p(^HULP(H1,Q,FNR),D,5)=BP
 .. f i=.01:.01 q:'$d(^(FNR+i))  s ^(NNR+i)=^(FNR+i) k ^(FNR+i)
 ;
 ; klant
5 s KC="" i $l(BP) s KC=$p(@("^"_Q_"VE(BP,NNR)"),D,4)
51 i $d(@("^"_Q_"VF(FNR)")) s ^(NNR)=^(FNR) k ^(FNR) i KC="" s KC=$p(^(NNR),D) i KC[" " s KC=$p(KC," ",2)
52 s I1=$g(@("^"_Q_"K1(+KC)"),0)
53 l (^HULP(H1),@("^"_Q_"KL(I1)")):10 e  g YZ
55 s KN=$p($g(@("^"_Q_"KL(I1,0)")),D,2)
57 i $d(^(FNR)) s ^(NNR)=^(FNR) k ^(FNR)
59 s $p(^HULP(H1,Q,FNR),D,7)=KC_D_KN
 ;
 ; historieken + financieel dagboek
6 i $l(BP) d
 . s I2=BP*100+1E6,J2=I2 f  s I2=$o(@("^"_Q_"KL(I1,I2)")) q:I2\1'=J2  d
 .. s HN=^(I2) f i=1:1:$l(HN,D) s HV=$p(HN,D,i) d
 ... i HV=("V"_FNR) s $p(HN,D,i)=("V"_NNR),@("^"_Q_"KL(I1,I2)")=HN
 ... i $e(HV)="B" d
 .... s j1=$e(I2,2,5)_"."_$e(I2,6,7),j2=$p($e(HV,2,99),"#"),j3=$p(HV,"#",2)
 .... s N=$g(@("^"_Q_"FI(j1,j2,j3)")) i $p(N,D,13)=FNR d
 ..... s $p(N,D,13)=NNR
 ..... i $p(N,D,9)=FNR s $p(N,D,9)=NNR
 ..... s ^(j3)=N,^HULP(H1,Q,FNR,$zr)=""
 ;
 ; grootboekrekeningen
7 i $l(BP) s AR="",I2=NNR f  s I2=$o(@("^"_Q_"VE(BP,I2)")) q:I2\1'=NNR  d
 . s VN=^(I2) f j=1:1:$l(VN,D) s VV=$p(VN,D,j) d
 .. s I1=$p(VV,"#"),AR=AR_I1
 .. s I2=BP*100+1E6,J2=I2 f  s I2=$o(@("^"_Q_"AR(I1,I2)")) q:I2\1'=J2  d
 ... s HN=^(I2) f i=1:1:$l(HN,D) s HV=$p(HN,D,i) d
 .... i HV=("V"_FNR) s $p(HN,D,i)=("V"_NNR),@("^"_Q_"AR(I1,I2)")=HN
71 i $l(BP) s $p(^HULP(H1,Q,FNR),D,6)=AR
 ;
 ; einde factuur
8 s $p(^HULP(H1,Q,FNR),D,2)=$$HD^cAFA1($h),$p(^(FNR),D,3)=$$HT^cAFA1($h)
81 g 11
 ;
YZ Q
 ;
ZZ ; 10.10.96 - 17 u 03 * V6.2.05