cI39E42(SWMNT,SWVP,DEC) ;Conversie klanten naar EURO; GROEUR [ 01/09/01  11:37 AM ]
 ; SWMNT = "" : enkel klanten met munt = munt BH
 ;       = 1  : alle klanten (uitz. EUR)
 ; SWVP  = 1  : omrekenen vaste prijzen
 ; DEC        : aantal decimalen om vaste prijzen om te rekenen
 ;
T0 ;Conversie klanten ivm Euro;
 ;
1 N I1,OMNTBH,MUNT
 S I1=0,OMNTBH=$P(@("^"_Q_"BA(39)"),D,9) I OMNTBH="" G YZ
 I '$L($G(DEC)) S DEC=2
11 F  S I1=$O(@("^"_Q_"KL(I1)")) Q:I1=""  D
 . S MUNT=$P(^(I1,0),D,11)
 . W $$CR^cA334,I1
 . I MUNT="EUR" Q
 . I '$G(SWMNT),MUNT'=OMNTBH Q
 . D W^cAN220("KL","1",I1,111,"EUR") I K="-" D FOUT^cI39E40("Klant "_I1_", muntcode "_MUNT_" werd niet geconverteerd naar EUR")
 . ; omrekenen vaste prijzen ?
 . I '$G(SWVP) Q
 . D VP($P(I1," ",2),MUNT,DEC)
 ;
 ;
YZ Q
 ;
FOUT(R) I '$D(HULPI1)!'$D(HULPI2) W !,R G FOUTZ
 S FOUTCODE=1 D FOUT^cI39E4(R)
FOUTZ Q
 ;
VP(KC,MUNT,DEC) ; Vaste prijzen
 N I1,A,B,NVP,TEL
 I '$L($G(DEC)) S DEC=2
 S I1=KC_" "
 F  S I1=$O(^DATA(Q,"KL_PR.PRIJS",I1)) Q:$P(I1," ")'=KC  D
 . S A=^(I1,0)
 . I $D(^eDATA(Q,"KL_PR.PRIJS",I1,0)) Q
 . S ^(0)=A
 . I '$P(A,D,3) Q
 . S NVP=$$OMREK^cAFE1(Q,$P(A,D,3),MUNT,"EUR","V",DEC)
 . D W^cAN220("KL_PR.PRIJS",0,I1,103,NVP) I K="-" D FOUT^cI39E40("Vaste prijs klant "_KC_" werd niet geconverteerd naar euro")
 ;
 S I1=KC_D
 F  S I1=$O(@("^"_Q_"KORT(7,I1)")) Q:$P(I1,D)'=KC  D
 . S A=^(I1)
 . I $P(A,U)'=4 Q
 . I $D(@("^e"_Q_"KORT(7,I1)")) Q
 . S ^(I1)=A
 . F TEL=1:1:$L($P(A,D)) D
 .. S B=$P(A,D,TEL) I '$P(B,"#",3) Q
 .. S $P(B,"#",3)=$$OMREK^cAFE1(Q,$P(B,"#",3),MUNT,"EUR","V",DEC)
 .. S $P(A,D,TEL)=B
 . S @("^"_Q_"KORT(7,I1)")=A
VPZ Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84