cI49	;Conversie Historiek producten: aanvullen met UI1 PR.STCOR; cI49
	;
YZ	Q
	;
CONV	; Aanvullen historiek producten met UI1 PR.STCOR
	N PR,I1,HSTRING,I,STRING,STCOR,COMM,INH,BEW
	S $ZT="TRAP^cAN000"
	; Testen of conversie wel moet worden uitgevoerd
	I '$P(@("^"_Q_"PR(0,19)"),D,96) G CONVZ
	; Aflopen producten
	S PR=0
	F  S PR=$O(@("^"_Q_"PR(PR)")) Q:PR=""  D
	. S I1="H"
	. ; Aflopenen H-lijnen product
	. F  S I1=$O(@("^"_Q_"PR(PR,I1)")) Q:$E(I1)'="H"  D
	.. S HSTRING=^(I1)
	.. ; Aflopen stuk per stuk van de H-lijn
	.. F I=1:1:$L(HSTRING,D)-1 D
	... S STRING=$P(HSTRING,D,I)
	... I STRING="" Q
	... S BEW=$E(STRING,7)
	... ; Samenstellen UI1 van PR.STCOR
	... S STCOR=PR_" "_$P(STRING,"#",9)_" "_$$DC^cAFD1($$DCO^cAFD1($E(STRING,1,6)))
	... ; Samenstellen inhoud PR.STCOR
	... S INH=PR_D_$P(STRING,"#",9)_D_$$DCO^cAFD1($E(STRING,1,6))
	... S $P(INH,D,4)=$S(BEW=2!(BEW=4)!(BEW=12):-$E($P(STRING,"#",1),8,99),1:$E($P(STRING,"#",1),8,99))
	... I $P(INH,D,4)=0 S $P(INH,D,4)=""
	... I $E($P(STRING,"#",1),8,99) S $P(INH,D,5)=$P(STRING,"#",2)/$E($P(STRING,"#",1),8,99) S $P(INH,D,5)=+$P(INH,D,5)
	... S $P(INH,D,6)=$P(STRING,"#",3)
	... S $P(INH,D,28)=$P(STRING,"#",8)
	... S $P(INH,D,29)=$P(STRING,"#",7)
	... ; Opzoeken commentaar PR.STCOR
	... S COMM=$$STCOR(STCOR,INH)
	... ; Wegschrijven commentaar op veld 10 van het stuk van de H-lijn
	... I $L(COMM) S $P(STRING,"#",10)=COMM S $P(@("^"_Q_"PR(PR,I1)"),D,I)=STRING
	W !,"Einde aanvullen historiek producten met UI1 van PR.STCOR"
CONVZ	Q
	;
STCOR(UI1STCOR,INHH)	; Opzoeken overeenkomstige UI1 in PR.STCOR
	N UI1,INH,SWOK,COMM
	S $ZT="TRAP^cAN000"
	S SWOK=0
	S COMM=""
	S UI1=UI1STCOR_" "
	; Aflopenen PR.STCOR binnen het zelfde product, verantwoording en datum
	F  S UI1=$O(^DATA(Q,"PR.STCOR",UI1)) Q:$P(UI1," ",1,3)'=UI1STCOR  D  Q:SWOK
	. S INH=^(UI1,0)
	. ; Veld commentraar leeg maken om inhoud te kunnen vergelijken
	. S $P(INH,D,7)=""
	. ; Omvormen prijs
	. S $P(INH,D,5)=+$P(INH,D,5)
	. ; Indien aantal leeg, prijs ook leeg maken
	. I $P(INH,D,4)="" S $P(INH,D,5)=""
	. ; Controleren of inhoud overeen komt
	. I $P(INH,D,1,27)=$P(INHH,D,1,27),($P(INH,D,29)=$P(INHH,D,29)) S SWOK=1,COMM=$P(^DATA(Q,"PR.STCOR",UI1,0),D,7)
STCORZ	Q COMM
	;
NA	; toevoegen kolom 'Commentaar' aan grid
	D UPD^cABVB01("PROG.TECH.PRHIS-1",,1)
	D UPDI^cABVB01
NAZ	Q
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09