cI720(TK)	;Aanpassen vertalingen in ^DM* ;%I720 [ 12/29/00  11:01 AM ]
	; TK = taalcode
	;
1	W #!,$P($T(+1),";",2),!
11	W !!?2,"Alle ^DMA, ^DMC, ^DMH, ^DMM, ^DMS worden aangepast !"
15	W !!,"Deze globals mogen aangepast worden?   J[] = ja   N[] = nee",!!,"KEUZE : " R K G 1:K="-",11:$L(K)'=1,11:"JjNn"'[K,YZ:"Nn"[K
	;
2	F best="^DMA","^DMC","^DMH","^DMM","^DMS" D
	. W !!!,best
	. S uq=""
	. f  s uq=$o(@best@(uq)) q:uq=""  d
	.. s us="" f  s us=$o(@best@(uq,us)) q:us=""  W !?5,uq,?10,us D @($p(best,"^",2)_"("""_uq_""","""_us_""","""_TK_""")")
	.. i best="^DMS" D
	... N Q
	... S Q=uq D S2^cAN002("DAM","DMS","",TKU-1*10+101)
	;
YZ	Q
	;
DMA(UQA,USA,TK,OTK)	      ; aanpassen ^DMA
	; TK  : op te zetten taalcode
	; OTK : over te nemen taalcode : niet ingevuld : "N"
	I '$L($G(OTK)) S OTK="N"
	S TKU=$F("NFDE",TK)-1
	S OTKU=$F("NFDE",OTK)-1
	s ge="^DMA(UQA,USA)"
	I $L($G(@ge@(0,"ALT"))),'$L($P(^("ALT"),D,TKU)) S $P(^("ALT"),D,TKU)=$P(^("ALT"),D,OTKU)
	S i=0
	F  S i=$o(@ge@(i)) q:i=""  s j="" f  s j=$o(@ge@(i,j)) q:j=""  s jj=$g(^(j,1)) f jj=1,10 I $L($G(^(jj))),'$L($P(^(jj),D,TKU)) S $P(^(jj),D,TKU)=$P(^(jj),D,OTKU)
	Q
	;
DMC(UQC,USC,TK,OTK)	      ; aanpassen ^DMC
	; TK  : op te zetten taalcode
	; OTK : over te nemen taalcode : niet ingevuld : "N"
	I '$L($G(OTK)) S OTK="N"
	S i=0,ge="^DMC(UQC,USC)"
	F  S i=$O(@ge@("INDEX",i)) q:i=""   I '$L($G(^(i,"TAAL",TK))) S ^(TK)=$G(^(OTK))
	S i=0
	F  S i=$O(@ge@("SYN",i)) q:i=""   s j=0 f  s j=$o(@ge@("SYN",i,j)) q:j'?1.N  I '$L($G(^(j,"TAAL",TK))) S ^(TK)=$G(^(OTK))
	I '$L($G(@ge@("TAAL",TK))) s ^(TK)=$G(^(OTK))
	Q
	;
DMH(UQH,USH,TK,OTK)	      ; aanpassen ^DMH
	; TK  : op te zetten taalcode
	; OTK : over te nemen taalcode : niet ingevuld : "N"
	I '$L($G(OTK)) S OTK="N"
	S TKU=$F("NFDE",TK)-1
	S OTKU=$F("NFDE",OTK)-1
	s ge="^DMH(UQH,USH)"
	I $L($G(@ge@(0,"TIT","ALT"))),'$L($P(^("ALT"),D,TKU)) S $P(^("ALT"),D,TKU)=$P(^("ALT"),D,OTKU)
	I $L($G(@ge@(0,"TXT"))),'$L($P(^("TXT"),D,TKU)) S $P(^("TXT"),D,TKU)=$P(^("TXT"),D,OTKU)
	S i=0
	F  S i=$o(@ge@("DET",i)) q:i=""  s j=0 f  s j=$o(@ge@("DET",i,j)) q:j=""  I $L($G(^(j,0))),'$L($P(^(0),D,TKU)) S $P(^(0),D,TKU)=$P(^(0),D,OTKU)
	Q
	;
DMM(UQM,USM,TK,OTK)	      ; aanpassen ^DMM
	; TK  : op te zetten taalcode
	; OTK : over te nemen taalcode : niet ingevuld : "N"
	I '$L($G(OTK)) S OTK="N"
	S TKU=$F("NFDE",TK)-1
	S OTKU=$F("NFDE",OTK)-1
	s ge="^DMM(UQM,USM)"
	S i=0
	F  S i=$o(@ge@(i)) q:i=""  I $L($G(^(i,0,2))),'$L($P(^(2),D,TKU)) S $P(^(2),D,TKU)=$P(^(2),D,OTKU)
	Q
	;
DMS(UQS,USS,TK,OTK)	      ; aanpassen ^DMS
	; TK  : op te zetten taalcode
	; OTK : over te nemen taalcode : niet ingevuld : "N"
	I '$L($G(OTK)) S OTK="N"
	S TKU=$F("NFDE",TK)-1
	S OTKU=$F("NFDE",OTK)-1
	s ge="^DMS(UQS,USS)"
	I '$D(@ge@(0)) Q
	I $P(^(0),D,31)?2N1"."2N1"."2N S:'$L($P(^(0),D,32)) $P(^(0),D,32)=$P(^(0),D,31) S $P(^(0),D,31)=""
	I '$L($P(^(0),D,TKU-1*10+1)) S $P(^(0),D,TKU-1*10+1)=$P(^(0),D,OTKU-1*10+1)
	Q
	;
ZZ	; 22.06.04 - 16 u 32 * V8