cQI29	;Modify ZZ-line in routines ;cQI29 ;
	G 1
	;
date	;date
	N %H,%J,%R S %H=1+$H,%J=%H\1461,%R=%H#1461,DJ=%J*4+1841+(%R\365),DD=%R#365,DM=1 I %R=1460 S DD=365,DJ=DJ-1
	F %J=31,(%R>1154)+28,31,30,31,30,31,31,30,31,30 Q:%J'<DD  S DM=DM+1,DD=DD-%J
	S:'DD DJ=DJ-1,DM=12,DD=31 S:DD<10 DD=0_DD S:DM<10 DM=0_DM S DT=DD_"."_DM_"."_$E(DJ,3,4)
datez	Q
time	;time
	N %J,%R S QT=$G(QT),%R=$P($H,",",2)\60,%J=%R\60
	S TD=$J(%J,2)_$P(" u ; h ; h ",";",$S(QT="F":2,QT="E":3,1:1))_(%R#60\10)_(%R#10)
timez	Q
doubleq(X)	;Double quotes in string
	N Y S Y=0 F  S Y=$F(X,"""",Y) Q:'Y  S X=$E(X,0,Y-1)_""""_$E(X,Y,$L(X)),Y=Y+1
doubleqz	K Y Q X
	;
1	D QQM^cQ6 W !,$P($T(+1),";",2),!
11	D SELECT^cABR
	S PRG="",$ZT="ERR^"_$T(+0),%T=0 W !!!
12	S (VERS,I2)="" F  S I2=$O(^cLOG(0,"VERS",I2)) Q:I2=""  W !,I2,?10,$P(^(I2),"\")
13	W !!,"Choose a module: " R K G 12:K?.E1C.E,YZ:K="-",2:K="",2:'$D(^(K)) S VERS=$P(^(K),"\")
	;
2	D date,time S Z="ZZ"_$C(9)_"; "_DT_" - "_TD_" * "_VERS W !,"The ZZ-line will be: ",Z
21	W !!,"Ready to clean up these routines <N> : .",$C(8) R K,! G YZ:K="" I $L(K)=1,"yYjJ"[K G 3
23	I $L(K)=1,"-Nn"[K G YZ
24	I K?1"ZZ ; "2N1"."2N1"."2N1" - ".1" "1.2N1" u "2N.1" * ".E S Z=K G 3
25	G 21
	;
3	K ^TEMP(boot,$J)
31	S PRG=$P($$NEXT^cABR(PRG),".")
	I PRG="" G 4
32	U 0 X "ZL @PRG ZI Z:ZZ ZR ZZ ZS @PRG"
33	W:'(%T#8) ! W ?%T#8*10,PRG S %T=%T+1 G 31
	;
4	G YZ:$O(^TEMP(boot,$J,0))="" W !!!,"In de global ^TEMP(",boot,",",$J,") vindt U alle programma's waarvoor de omzetting",!,"NIET doorgevoerd werd.",!
41	W !,"[] = ok: .",$C(8) R K,!
42	F  S PRG=$O(^(PRG)) Q:PRG=""  W !,PRG,?10,^(PRG)
	;
YZ	Q  ;K PRG,%T,DD,DJ,DM,DT,TD,K,X,Z Q
	;
F1	S K="Compiled routine" G FZ
F2	S K="Running at the moment" G FZ
F3	S K="No ZZ-lijn in routine" G FZ
FZ	W !,PRG,?10,K,!?10,"Routine not modified... Continuing",! S ^TEMP(boot,$J,PRG)=K Q
	;
ERR	S $ZT="ERR^"_$T(+0),%T=0 I $ZE["<PROT" D F1 G 31
ERRA	I $ZE["<CLOBR" G 33:$ZN=PRG D F2 G 31
ERRB	I $ZE["<NOLINE>" D F3 G 31
ERRZ	U 0 W !!,$ZE,!! Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9