cQLBUV	;Check Backup ;cQLBUV;
	;
T0	;Controle Backup ;
T1	;Backup succesvol!;Beëindigd: ;. Duur: ;
T2	;Geen backup-logfile gevonden!;
T3	;Geen backup gestart op voorziene dag!;
T4	;Backup heeft abnormale duur: ;Gemiddeld: ;
T5	;Backup was niet succesvol!;
	;
T0F	;Contrôle copie de sauvegarde ;
T1F	;Copie de sauvegarde succedé!;Fini: ;. Duré: ;
T2F	;Pas de journal de copie de sauvegarde trouvé!;
T3F	;Pas de copie de sauvegarde le jour attendu!;
T4F	;Copie de sauvegarde a une durée abnormale: ;Moyenne: ;
T5F	;Copie de sauvegarde n'est pas OK!; 
	;
T0E	;Check Backup ;
T1E	;Backup successfull!;Ended: ;. Duration: ;
T2E	;No backup-logfile found!;
T3E	;No backup started on the intended day!;
T4E	;Backup has abnormal duration: ;Average: ;
T5E	;Backup was not successfull!;
	;
T0D	;Check Backup ;
T1D	;Backup successfull!;Ended: ;. Duration: ;
T2D	;No backup-logfile found!;
T3D	;No backup started on the intended day!;
T4D	;Backup has abnormal duration: ;Average: ;
T5D	;Backup was not successfull!;
	;
1	D INI^cQ6 S QU="SU" I $G(^cLOG(0,"WORKSTATION",$ZCVT($ZU(110),"U")))!$D(^cLOG($ZU(5),"CLIENT",$ZCVT($ZU(110),"U"))) G YZ
	D G^cQLBV	;Get windows logbook
	;
2	S LOGB="^cLOG("""_$ZU(5)_""",""BACKUP"",""LOGBOEK"",TYPE)",TYPE="",ERR=0
	F  S TYPE=$O(^cLOG(0,"BACKUP","TYPE",TYPE)) Q:TYPE=""  S TYPEN=$G(^(TYPE)) I $D(@LOGB)#11 D
	. S LBU="",(LBUHD,LBUHT)=0,NOW="\\"_$TR($ZD($H,4),"/",".")_"\"_$ZT($H,2)_"\\",NOWHD=+$H,NOWHT=$P($H,",",2)
	. S K=$O(@LOGB@("@"),-1) I K'="" S L=$O(@LOGB@(K,"@"),-1) I L'="" S LBU=^(L),LBUHD=K,LBUHT=L
	. S LBUD=$P(LBU,D,3),LBUT=$P(LBU,D,4),LBUTI=$P(LBU,D,6) D AVER
	. S LBUHT=LBUHT-LBUTI I LBUHT<0 S LBUHT=24*3600+LBUHT,LBUHD=LBUHD-1
	. S AU=LBUTI\3600,AM=LBUTI#3600\60,AS=LBUTI#3600#60
	. S AU=$E("0"_AU,$L(AU),4),AM=$E("0"_AM,$L(AM),4),AS=$E("0"_AS,$L(AS),4)
	. S LBUTIC=AU_":"_AM_":"_AS
	. I $E(LBU)'="B" S ERR=6,R($O(R(""),-1)+1)=$P($T(@("T5"_QT)),";",2)
	. ;geen logboek?
	. I LBUHD=0!(LBUHT=0) S ERR=1,R($O(R(""),-1)+1)=$P($T(@("T2"_QT)),";",2) Q
	. ;periodiciteit = 1 = dagelijks/vandaag (default)
	. ;              = 2 = dagelijks/gisteren
	. ;              = 7 = op vorige werkdag
	. S PER=$G(^cLOG($ZU(5),"BACKUP","PER"),1)
	. I ($H-LBUHD>4)!(PER=1&(LBUHD#7'=($H#7)))!(PER=2&(LBUHD#7'=$TR($H#7,"0123456","6012345")))!(PER=7&(LBUHD#7'=$TR($H#7,"0123456","6011145"))) S ERR=2,R($O(R(""),-1)+1)=$P($T(@("T3"_QT)),";",2)
	. ;duur?
	. I 'ERR,LBUTI<(100-DELTA/100*AVER)!(LBUTI>(100+DELTA/100*AVER)) S ERR=4,R($O(R(""),-1)+1)=$P($T(@("T4"_QT)),";",2)_LBUTI_" sec. "_$P($T(@("T4"_QT)),";",3)_AVER_" sec."
	. I 'ERR S R($O(R(""),-1)+1)=TYPEN_" "_$P($T(@("T1"_QT)),";",2)
	. I $L(LBU) S R($O(R(""),-1)+1)=$P($T(@("T1"_QT)),";",3)_$G(LBUD)_" "_$G(LBUT)_$P($T(@("T1"_QT)),";",4)_LBUTI_" sec ("_LBUTIC_")."
6	S PG=$T(+0),PN=$P($T(@("T0"_QT)),";",2)
	I '$O(R(""),-1) S ERR=5,R($O(R(""),-1)+1)=$P($T(@("T2"_QT)),";",2)
	I 'ERR D D1013^cANEM0(PG,PN,.R)
	I ERR D D1014^cANEM0(PG,PN,.R)
	;
YZ	Q
	;
AVER	N AL,I,J S AVER=0,(AL,I,J)=0,DELTA=$G(^cLOG($ZU(5),"BACKUP","DELTA"),50)
	F  S I=$O(^cLOG($ZU(5),"BACKUP","LOGBOEK",TYPE,I)) Q:I=""  F  S J=$O(^cLOG($ZU(5),"BACKUP","LOGBOEK",TYPE,I,J)) Q:J=""  S K=^(J) I $E(K)="B" S AVER=AVER+$P(K,D,6),AL=AL+1
	I AVER S AVER=AVER\AL
	I 'AVER S AVER=+$P($G(^cLOG($ZU(5),"BACKUP","TIME",TYPE)),D,3)
AVERZ	Q
	;
ZZ	; 17.01.2012 - 15:58 * Cache-r6.4.9