cQUP610	;Update cQ ;cQUP610;  ; Compiled March 5, 2009 12:13:23
	;
	;Release 6.1.0 - mm.dd.2009
	;Updated routines
	;cQ17    ;23.02.2009 14:06 ;ASK+5: ,1) -> ,0) = allow first dbase to be copied
	;cQAUTOBU;23.02.2009 17:40 ;DATA+37: exclude Cache2008.2 files clockjd and clockwd
	;cQCPF   ;03.03.2009 11:20 ;adjust globalmapping for Caché 2008
	;cQCPF0  ;03.03.2009 11:15 ;globalmapping base is Caché 5.0
	;cQFILE  ;23.02.2009 17:35 ;XCP: exclude added
	;cQMAC   ;24.02.2009 13:40 ;WLC: modified
	;cQSYS   ;02.03.2009 11:45 ;$ZT added
	;cQZSTART;27.02.2009 14:38 ;NBN: $ZU(67,12,$J)
	;        ;04.03.2009 15:55 ;STUSSD+9: added, I '$D(^DMS(0,"ALERT"))
	;        ;04.03.2009 17:39 ;Line +2: marker DATA-M added
	;%ZSTOP  ;04.03.2009 17:40 ;Line +2: marker DATA-M added
	;New Routines
	;cQCPFR  ;26.02.2009 20:05 ;Check globalmapping
	;cQUP610 ;23.02.2009 10:46 ;changes in version 6.1.0
	;Deleted Routines
	;
	;Update
	W !!,"Update voor  ",$ZV,"  release  ",$P($T(ZZ),"-r",2),!
	S NSPC=$G(^["%SYS"]cLOG(0,"NAMESPACE",0)) I $L(NSPC) ZN NSPC
	;
	S REL=$P($T(ZZ),"-r",2),RELDP=$TR(REL,".")
	F K="cQINT","cQUP" D
	. S (I,J)=K
	. F  S I=$O(^$R(I)) Q:$E(I,1,$L(J))'=J  S K=$P(I,J,2) I K?.N,K'=RELDP X "ZR  ZS @I"
	;
	S CN=$ZU(5),SN="%SYS",LN="%CACHELIB"
	;
	;Save routines in namespace %SYS
	I '($P($P($ZV,")",2),"(",1)[" 2008") D
	. D RS("cQCW\%CHARWIN",CN,SN),RS("cQX364\%X364",CN,SN)
	. D RS("cQCW\cCHARWIN",CN,SN),RS("cQX364\cX364",CN,SN)
	. D RS("cQCW\cCHARWIN",CN,CN),RS("cQX364\cX364",CN,CN)
	. D RS("cQQ\cQQ",CN,LN)
	I ($P($P($ZV,")",2),"(",1)[" 2008") D
	. D RS("cQCW2008\%ZCHARWIN",CN,SN),RS("cQX364\%ZX364",CN,SN)
	. D RS("cQCW2008\cCHARWIN",CN,SN),RS("cQX364\cX364",CN,SN)
	. D RS("cQCW2008\cCHARWIN",CN,CN),RS("cQX364\cX364",CN,CN)
	D RS("cQQ\cQQ",CN,SN)
	D RS("cQSYS\%ZQSYS",CN,SN)
	S MM="" ZN SN X:$D(^$R("%ZSTART")) "ZL %ZSTART S MM=$P($T(+2),"";"",2)" ZN CN
	I MM="DATA-M" D RS("cQZSTART\%ZSTART",CN,SN)
	S MM="" ZN SN X:$D(^$R("%ZSTOP")) "ZL %ZSTOP S MM=$P($T(+2),"";"",2)" ZN CN
	I MM="DATA-M" D RS("cQZSTOP\%ZSTOP",CN,SN)
	;Save routines in current namespace
	D RS("cQIINT\IINT",CN,CN)
	D RS("cQTTSC\TTSC",CN,CN)
	;
	;Delete routines in namescpace %SYS
	D RD("cQMSMQ",CN,SN)
	;Delete routines in current namespace 
	D RD("cQDSCON",CN,CN)
	D RD("cQVGCOM",CN,CN)
	;
	;Delete logbook ^ZZLOG
	F K="%GSIZE","GCOMPACT","INTEGRIT" I $D(^ZZLOG(K)) K ^ZZLOG(K)
	;
	;Skip next updates if already on cQ 5.4.3 or beyond
	S K=$P($P($G(^cLOG(0,"VERS","cQ"),"1.1.0"),"\"),"r",2),L=""
	S L=($P(K,".",1)*10000)+($P(K,".",2)*100)+$P(K,".",3)
	I L>50402 G NEW
 	;
	;Set ^cLOG(0,"LOGOUT")
	D LOGOUT^cQ7
	;
	;Change references to routines cQMSM... to cQ...
	K N D NSPC^cQ21(.N,1) S N=""
	F  S N=$O(N(N)) Q:N=""  D
	. F G="^DAMBA","^cDAMBA","^EABA" S GS=G_"(""MENU"")",I1="" D
	.. F  S I1=$O(@GS@(I1)) Q:I1=""  S I2="" D
	... F  S I2=$O(@GS@(I1,I2)) Q:I2=""  S A=^(I2) I A["cQMSM" D  S ^(I2)=A
	.... F  S A=$P(A,"cQMSM",1)_"cQ"_$P(A,"cQMSM",2,$L(A,"cQMSM")) Q:A'["cQMSM"
	;
	;change ^cLOG(0,"SYSTEM") to ^cLOG( cs ,"SYSTEM")
	I $D(^cLOG(0,"SYSTEM")) D
	. S K=$TR($ZU(5),"1234567890","")
	. F I=1:1:99 I $ZU(90,10,K_I) M ^cLOG(K_I,"SYSTEM")=^cLOG(0,"SYSTEM")
	. K ^cLOG(0,"SYSTEM")
	;
	;Change settings in Cache.cpf
	I '($P($P($ZV,")",2),"(",1)[" 2008") D
	. D FR^cQCPF("gmheap=","[config]","gmheap=32768")
	. D FR^cQCPF("BIGINT=","[SqlSysDatatypes]","BIGINT=%Library.BigInt")
	. D FR^cQCPF("ExtrinsicFunctions=","[SQL]","ExtrinsicFunctions=1")
	I ($P($P($ZV,")",2),"(",1)[" 2008") D
	. D FR^cQCPF("Mnemonic_OTH=^%X364","[IO]","Mnemonic_OTH=^%ZX364")
	. D FR^cQCPF("Mnemonic_SEQ=^%X364","[IO]","Mnemonic_SEQ=^%ZX364")
	. D FR^cQCPF("Mnemonic_TTY=^%X364","[IO]","Mnemonic_TTY=^%ZX364")
	;
	;Update backgroundjobs
	D UCTK0^cQ10
	;
	;Change backuptime to seconds
	S (I,J)=""
	F  S I=$O(^cLOG($ZU(5),"BACKUP","LOGBOEK",4,I)) Q:I=""  D
	. F  S J=$O(^cLOG($ZU(5),"BACKUP","LOGBOEK",4,I,J)) Q:J=""  D
	.. S K=$P(^(J),"\",6) I K<60 S $P(^(J),"\",6)=K*60
	;
NEW	;new for this version
	;
	;Set Update directory
	S K=$$MD^cQFILE($E($ZU(86))_":\DataM\Updates")
	S K=$G(^cLOG($ZU(5),"cABIE","DIR"),$G(^cLOG($ZCVT($ZU(110),"U"),"cABIE","DIR"),$E($ZU(86))_":\DataM\Temp\"))
	S K=$ZCONVERT(K,"U") I $E(K,$L(K))'="\" S K=K_"\"
	I K=($ZCONVERT($E($ZU(86)),"U")_":\DATAM\TEMP\") S ^cLOG($ZCVT($ZU(110),"U"),"cABIE","DIR")=$E($ZU(86))_":\DataM\Updates\"
	;
	D PDF^cQ7
	D SYM^cQ7
	D VERS^cQ7
	;
	I '$D(^cLOG(0,"BACKUP","TYPE",4)) S ^cLOG(0,"BACKUP","TYPE",4)="M Xcopy"
	;
YZ	Q
	;
RS(R,From,To)	      ; Save routine R in namespace To
	S R=$G(R),From=$G(From),To=$G(To)
	Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$D(^$R($P(R,"\")))  Q:'$L($P(R,"\",2))  Q:'$L(From)  Q:'$L(To)
	W !,"Saving ",$P(R,"\")," as ",$P(R,"\",2)," in namespace ",To
	X "ZL "_$P(R,"\")_" ZN To ZS "_$P(R,"\",2)_" ZN From"
	Q
	;
RD(R,From,To)	      ; Delete routine R in namespace To
	S R=$G(R),From=$G(From),To=$G(To)
	Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$L(From)  Q:'$L(To)
	W !,"Removing ",$P(R,"\")," in namespace ",To
	X "ZN To ZR  ZS "_$P(R,"\")_" ZN From"
	Q
	;
XL(R,From,To)	      ; Xecute R in namespace To
	S R=$G(R),From=$G(From),To=$G(To)
	Q:'$L(R)  Q:'$L($P(R,"\"))  Q:'$L(From)  Q:'$L(To)
	W !,"Xecuting ",$P(R,"\")," in namespace ",To
	X "ZN To "_$P(R,"\")_" ZN From"
	Q
	;
SYS	;Update %ZSTART and %ZSTOP without check
	S CN=$ZU(5),SN="%SYS"
	D RS("cQZSTART\%ZSTART",CN,SN)
	D RS("cQZSTOP\%ZSTOP",CN,SN)
SYSZ	Q
	;
ZZ	; 05.03.2009 - 12:13 * Cache-r6.1.0