cT00C	;Algemene functies boekhouding ;%T00C ; [ 11/14/01  10:37 AM ]
	G YZ
	;
T0	;Algemene functies boekhouding ;
	;
T0F	;Functions générales comptabilité ;
	;
T0E	;General functions accounting ;
	;
	; ====================================================================
S1	S RZR=$ZR           ; onthouden last reference
S1Z	Q
	;
S2	I $O(@RZR)          ; terugzetten last reference
S2Z	Q
	;
	; ====================================================================
	; beginsaldo
BSAL(Q,AKL,UI1,BJ)	
	; input: AKL = bestand ("AR"=rekening <> "KL"=klant <> "LE"=lev.)
	;        UI1 = index (subscript) uit hoofdbestand
	;        BJ  = boekjaar waarvoor beginsaldo wordt gevraagd
	; output: beginsaldo (in muntcode van het boekjaar)
	S $ZT="TRAP^cAN000" N RZR D S1
	N BSAL S BSAL=0,D="\" D ^cA106
	I $L($G(Q)),$L($G(AKL)),$L($G(UI1)),$G(BJ) S BSAL=$$BSAL^cAFE1(Q,BJ,AKL,UI1)
BSALZ	D S2 Q BSAL
	;
	;
	; ====================================================================
	; saldo
SAL(Q,AKL,UI1,BP)	
	; input: AKL = bestand ("AR"=rekening <> "KL"=klant <> "LE"=lev.)
	;        UI1 = index (subscript) uit hoofdbestand
	;        BP  = maand (jjjj.mm) waarvoor saldo wordt gevraagd
	; output: saldo (in muntcode van het boekjaar)
	S $ZT="TRAP^cAN000" N RZR D S1
	N SAL S SAL=0,D="\"
	I $L($G(Q)),$L($G(AKL)),$L($G(UI1)),$G(BP) D
	. N BJ,BM,BH,BX,OK D D2M^cT00A(Q,"01."_$E(BP,6,7)_"."_$E(BP,3,4))
	. S SAL=$$BSAL(Q,AKL,UI1,BJ)
	. N DC,CC,I S DC=$G(@("^"_Q_AKL)@(UI1,BJ)),CC=$G(^(BJ+.02))
	. F I=2:1:BX S SAL=SAL+$P(DC,D,I)-$P(CC,D,I)
SALZ	D S2 Q SAL
	;         
	;
YZ	Q
	;
ZZ	; 10.12.01 - 10 u 49 * V7.9