cT170	;Stap 1: voorlopige dom.lijst ;%T170 ; [ 05/28/01  9:53 AM ]
	G 1
	;
T0	;Voorlopige domiciliëringslijst ;
T1	;Domiciliëring aanwezig en nog niet geprint\",[] = behouden gegevens   V[] = verwijderen gegevens";
T3	;Vervaldag domiciliëring\"dd.mm.jj[] = bepaalde datum";
T4	;Alle banknummers\"[] = ja   1[] = enkel de banknummers met het eerste cijfer gelijk aan ";
T6	; Klant\Woonplaats\ Nr\\Document\Dat.doc.\Verv.dom\Openstaand ;1\Korting ;1\Bedrag dom.;1\Munt\ Nr;
T7	; Eindtotaal;
	;
T0F	;Listing provisoire domiciliations ;
T1F	;Domiciliation présente et pas encore imprimée\",[] = garder les données   V[] = radier les données";
T3F	;Echéance domiciliation\"jj.mm.aa[] = date spécifique";
T4F	;Comptes en banques\"[] = tous   1[] = seulement les comptes commençant par ";
T6F	; Client\Localité\ N°\\Document\Dat.doc.\Ech.dom.\Non soldé ;1\Escompte ;1\Montant dom.;1\Mon.\ N°;
T7F	; Total final;
	;
T0E	;Voorlopige domiciliëringslijst ;
T1E	;Domiciliëring aanwezig en nog niet geprint\",[] = behouden gegevens   V[] = verwijderen gegevens";
T3E	;Vervaldag domiciliëring\"dd.mm.jj[] = bepaalde datum";
T4E	;Alle banknummers\"[] = ja   1[] = enkel de banknummers met het eerste cijfer gelijk aan ";
T6E	; Klant\Woonplaats\ Nr\\Document\Doc.date\Verv.dom\Openstaand ;1\Korting ;1\Bedrag dom.;1\Munt\ Nr;
T7E	; Eindtotaal;
	;
	; start
1	;I QP D O^cA612(2,1,20,80,1,0,1,1),T^cA612($P($T(@("T0"_QT)),U,2),0,0,7,1,1) ;10.03.00
	I QP D P^cA612(2,1,20,80,1,0,1,1,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
11	L @("^"_Q_"K3"):2 E  D:QP TXT^cAFA1(14) G YZ
13	S BA39=@("^"_Q_"BA(39)"),BF=$P(BA39,D),K=$P(BA39,D,3) I K'="BE" G YZ
15	S K=$G(@("^"_Q_"K3(0,0)")) I $O(^(0,0))="" G 19
17	G YZ:'QP W /CUP(18,3),$P(K,D,2)
18	S R="K\22\3\"_$P($T(@("T1"_QT)),U,2)_"\1\\""V-,""[K&$L(K)\\\1" D R0 G YZ:K'="V" K @("^"_Q_"K3(0,0)")
19	I 'QP S BNR=PP(1),QA=PP(2),BNM=PP(3),MNT=PP(4),DAT=PP(5),SRT=PP(6) K PP G 3
	;
	; vraagstelling
2	S R="K\1800\1\1\1\1\1\1\" D ^cT278 G YZ:K="-" S K=^(K,0),BNR=$P(K,D),BNK=$E($P(K,D,9))
21	S QA=QD,BNM=$P(K,D,2),MNT=$P(K,D,11) S:'$L(MNT) MNT=BF I MNT'=BF S QA=$$DEC^cAFA1(MNT)
22	I MNT'=$P(BA39,D),MNT'=$P(BA39,D,7),MNT'=$P(BA39,D,9) G 2
23	W /CUP(2,3),BNM,@F1 I '$G(DAT) S DAT=DT
25	S R="DAT\22\3\"_$P($T(@("T3"_QT)),U,2)_"\8\\$$DCTR^cAFI1(K)&$L(K)\\\\\1" D R0 G 2:K="-" W /CUP(2,60),DAT
27	S R="SRT\22\3\"_$P($T(@("T4"_QT)),U,2)_"_BNK\1\\""1-""[K" D R0 G 25:K="-"
29	D ^cAN3223(1,"1",">80","") G 27:K="-" I K="." D S9 G YZ
	;
	; printen lijst + opbouw 'voorlopig' bestand
3	S @("^"_Q_"K3(0,0)")=D_BNM_D_D_D_BNR_D_DAT_D_MNT_D_QA
30	S BNR=$E($P(@("^"_Q_"AR(BNR_"" "",0)"),D,9)) ; banknr
31	S HD(1)=D,HD(2)=D_$P($T(@("T0"_QT)),U,2)_";C;F82",HD(3)=D_DAT_";C;F82"
33	S TAB="30\51\55\57\66\75\84\98\108\122\127\131"
35	S TIT(1)=$P($T(@("T6"_QT)),U,2,99)
	;
	; klanten in alfabetische volgorde
4	S I1=0,DTT=$$DC^cAFD1(DAT),TDOM=0
41	S I1=$O(@("^"_Q_"KL(I1)")) I I1="" G 8
43	S B(1)=^(I1,0),KC=$P(B(1),D),DOM=$P(B(1),D,23),KOR=$P(B(1),D,25)
45	G 41:DOM'?12N I SRT G 41:$E(DOM)'=BNR
47	S TXT(1)=$J(KC,6)_" "_$P(B(1),D,2)_"\\\\\\\\\1"   ; nummer + naam
49	S TXT(2)=$P(B(1),D,7)_"\\\\\\\\\1"                ; woonplaats
	;
	; openstaande facturen per klant
5	S I2=99999,NR=0
51	S I2=$O(@("^"_Q_"KL(I1,I2)")) I I2'?6N G 41
53	S OF=^(I2),VVD=$P(OF,D,11) I $P(VVD,U)=1 S VVD=$P(VVD,U,3)
55	G 51:$L(VVD)'=8,51:$$DC^cAFD1(VVD)>DTT
57	S VM=$P(OF,D,9) S:VM="" VM=BF S DEC=$$DEC^cAFA1(VM)
59	I VM'=$P(BA39,D),VM'=$P(BA39,D,7),VM'=$P(BA39,D,9) G 51
	;
	; factuur op lijst
6	S FC=$P(OF,D),FDT=$P(OF,D,2),OBF=$P(OF,D,5),Y=FC="F"*2-1
61	S TKK=OBF*KOR/100+$S(OBF=$P(OF,D,4):$P(OF,D,6),1:0),DOM=OBF-TKK
62	I 'NR,$G(LN) S END=132 D ^cA334
63	S NR=NR+1,TXT(3)=NR_D_1                           ; volgnummer
65	S TXT(4)=FC                                       ; F/C
67	S TXT(5)=I2_D_1                                   ; factuurnummer
69	S TXT(6)=FDT,TXT(7)=VVD                           ; datums
	;
7	S TXT(8)=OBF*Y_"\\\\1\"_DEC                       ; openstaand
71	S TXT(9)=TKK*Y_"\\\\1\"_DEC                       ; totale korting
73	S TXT(10)=DOM*Y_"\\\\1\"_DEC                      ; bedrag dom.
75	S TXT(11)=VM,TXT(12)=TXT(3) D ^cA334              ; printen
77	S K=KC_"\\\\"_FDT_D_VVD_D_OBF_D_D_FC_D_D_DOM_D_TKK_D_D_I2_D_VM_D
79	S @("^"_Q_"K3(0,0,KC,NR)")=K_$$OMREK^cAFE1(Q,DOM,VM,MNT,"V",QA)_D
	S TDOM=$P(^(NR),D,16)*Y+TDOM G 51                 ; VJ 18.12.00
	;
	; eindtotaal
8	S AFS(1,1)=$P($T(@("T7"_QT)),U,2)
81	S AFS(1,10)=TDOM_"\\\\1\"_QA,AFS(1,11)=MNT,END=1 D ^cA334
	;
YZ	D:QP C^cA612 Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
S9	S PP(1)=BNR,PP(2)=QA,PP(3)=BNM,PP(4)=MNT,PP(5)=DAT,PP(6)=SRT
S9Z	S QPT=$T(+0) D ^cA109 Q
	;
ZZ	; 06.08.01 - 17 u 28 * V7.87