cT483	;Historiek KL/LE naar Excel; cT48
	;
T0	;Historiek KL/LE;
T1	;Nummer\Naam van de ;\Datum\JRN\ \Document\Debet ;\Credit ;\Saldo ;\Referte\Omschrijving\;Mnt\Debet Mnt\Credit Mnt\;Nummer\Naam\;Ini;\Datum;
T2	;klant;leverancier;rekening;
T3	;Historiek ;klanten;leveranciers;rekeningen;analytische rekeningen;
T4	;Periode : ;
T5	;\Boekingsmaand;
T6	;Beginsaldo;
	;
T0F	;Historique KL/LE;
T1F	;Numéro\Nom du ;\Date\JRN\ \Document\Débit ;\Crédit ;\Solde ;\Référence\Description\;Mon\Débit Mon\Crédit Mon\;Numéro\Nom\;Par;\Date;
T2F	;client;fournisseur;compte;
T3F	;Historique ;clients;fournisseurs;comptes;comptes analytiques;
T4F	;Période : ;
T5F	;\Mois comptable;
T6F	;Solde initial;
	;
T0E	;History KL/LE;
T1E	;Number\;\Date\JRN\ \Document\Debit ;\Credit ;\Balance ;\Reference\Description\;Cur\Debit Cur\Credit Cur\;Number\Name\;Ini;\Date;
T2E	;Customer Name;Supplier Name;Account Name;
T3E	;History ;Customers;Suppliers;Accounts;analytical Accounts;
T4E	;Period : ;
T5E	;\Fiscal month;
T6E	;Initial Balance;
	;
	;  Bepalen Van-datum en Tot-datum
1	N B,RJ,RM,R3,KLUQC,KLUSC,SWLST,TIT,TAB,I1,I2,INH,MNT,DEC,I,BSAL,JAAR,BJ,BSALDO1,SWPRINT,SWLN,SWBSAL1,EJAAR,TJAAR
11	S $ZT="TRAP^cAN000"
	; indien gekozen per jaar	
13	I 'KEU S KM1=KM1(KJ),KM2=KM2(KJ) I SW,KJ<J4 S KM2=KM2(J4)  ; SW = 1 indien JAAR+ ingegeven werd : laatste maand = laatste maand jongst openstaand BJ
15	I KEU S KJ=$$BJ^cAFE1(Q,KM1)
	S $P(B(1),D)="01."_$P(KM1,".",2)_"."_$E(KM1,3,4)
	S RJ=$P(KM2,"."),RM=$P(KM2,".",2) D S1^cA104
	S $P(B(1),D,2)=R3_"."_$P(KM2,".",2)_"."_$E(KM2,3,4)
	;  Bepalen UQC en USC van KL/LE
17	S KLUQC=$P(^DMS(Q,$P(TXT,D,2)),D),KLUSC=$P(^DMS(Q,$P(TXT,D,2)),D,2)
18	S SWLST=1
19	I '$L($P(MUNT,D,2)) S $P(MUNT,D,2)=QD
	;
2	S HD(1)=D,HD(3)=D_$P($T(@("T4"_QT)),U,2)_$P(B(1),D)_" - "_$P(B(1),D,2)_";C;F82",HD(2)=D_$P($T(@("T3"_QT)),U,2)_$S($P(TXT,D,2)="KL":$P($T(@("T3"_QT)),U,3),$P(TXT,D,2)="LE":$P($T(@("T3"_QT)),U,4),$P(TXT,D,2)="AR":$P($T(@("T3"_QT)),U,5),1:$P($T(@("T3"_QT)),U,6))_";C;F82"
21	S TIT(1)=$P($T(@("T1"_QT)),U,2)_$S($P(TXT,D,2)="KL":$P($T(@("T2"_QT)),U,2),$P(TXT,D,2)="LE":$P($T(@("T2"_QT)),U,3),1:$P($T(@("T2"_QT)),U,4))_$P($T(@("T1"_QT)),U,3)_$P(MUNT,D)_$P($T(@("T1"_QT)),U,4)_$P(MUNT,D)_$S(SWSAL:$P($T(@("T1"_QT)),U,5)_$P(MUNT,D),1:"")_$P($T(@("T1"_QT)),U,6)_$S($P(TXT,D,2)="AR"!($P(TXT,D,2)="ARA"):$P($T(@("T1"_QT)),U,8),1:$P($T(@("T1"_QT)),U,7))_$P($T(@("T1"_QT)),U,9)
	I $P($G(QU(0,2)),D,39) S TIT(1)=TIT(1)_$P($T(@("T1"_QT)),U,10)
22	I SWSAL&($E($P(TXT,D,2),1,2)'="AR") S TAB="7\37\46\50\52\59\70\81\92\108\158\162\173\184\188"
23	I 'SWSAL&($E($P(TXT,D,2),1,2)'="AR") S TAB="7\37\46\50\52\59\70\81\97\148\152\163\174\178"
24	I SWSAL&($E($P(TXT,D,2),1,2)="AR") S TAB="7\37\46\50\52\59\70\81\92\108\158\165\194\199"
25	I 'SWSAL&($E($P(TXT,D,2),1,2)="AR") S TAB="7\37\46\50\52\59\70\81\97\148\155\184\189"
26	I $P($G(QU(0,2)),D,39) S TAB=TAB_D_($P(TAB,D,$L(TAB,D))+8)
27	I PTS=3!(PTS=4) S TIT(1)=TIT(1)_$P($T(@("T5"_QT)),U,2),TAB=TAB_"\"_($P(TAB,"\",$L(TAB,"\"))+8)
	;
	; volgende KL/LE
3	S I1=""
31	I $G(SWVB) S I1=$$UI1^cAFA1($P(TXT,D,2),101,KC) G YZ:'$L(I1),YZ:'$L($$SIGN^cAFA1($P(TXT,D,2),I1,0)) G 33
	D ^cAN004("I1",$P(TXT,D,2)) G 4:I1=""
33	S KLI1=I1
	;  Indien AR: geen tekstrekeningen meenemen
	I $E($P(TXT,D,2),1,2)="AR",($$SIG^cAFA1($P(TXT,D,2),I1,113)=1) G 31
	F I=1:1:17 S TXT(I)=""
	D FORM
	;  Nummer KL/LE
	S TXT(1)=$$SIG^cAFA1($P(TXT,D,2),I1,101)
	;  Naam KL/LE
	S TXT(2)=$P(^(0),D,2),TSAL=0,BSAL=""
	S SWLN=0
	; Kijken of beginsaldo moet worden geprint
	I SWSAL D 
	. ; Datum begin saldo
	. S TXT(3)=$P(B(1),D)
	. ;  boekjaar
 	. S BJ=KJ
 	. S JAAR=KM2(KJ)
	. ;  Bepalen beginsaldo boekjaar
	. S BSAL=$$BSAL^cAFE1(Q,BJ,$P(TXT,D,2),I1)
	. I $P(TXT,D,2)="ARA" S BSAL=$$SALDOARA^cTA180(Q,I1,$G(KM1(BJ)))
	. ;  Bepalen beginsaldo tot eerste gekozen maand
	. I KEU,KM1(BJ)'=KM1 S BSAL=$$SAL(BSAL,"01."_$P(KM1(BJ),".",2)_"."_$E(KM1(BJ),3,4),$P(B(1),D))
	. ;  Bepalen muntcode en decimalen beginsaldo
	. S MNT=$$MNTC^cAFE1(Q,BJ)
	. S BSAL=$$OMREK(BSAL,MNT,MUNT,TXT)
	. S BSALDO1=BSAL
	. I $P(TXT,D,2)="AR",$$SIG^cAFA1($P(TXT,D,2),I1,120),KJ>($P(BPB,D,2)\1) S BSAL=0
	; Opbouwen ^HULP per KL/LE
35	D ^cT48H
	S I2="",SWP=0,SWPRINT=0,SWBSAL1=0
	F  S I2=$O(^HULP(boot,$J+.01,I2)) Q:I2=""  D
	. S INH=^(I2,0)
	. S SLN=1
	. I SWSAL,($P(INH,D,17)>JAAR) D
	.. I SWBSAL1=0 D PSAL S SWP=1
	.. S BSAL=TSAL
	.. I $P(TXT,D,2)="AR",$$SIG^cAFA1($P(TXT,D,2),I1,120) S BSAL=0
	.. I $P(TXT,D,2)="ARA" S BSAL=$$SALDOARA^cTA180(Q,I1,$G(KM1($$BJ^cAFE1(Q,$P(INH,D,17)))))
	.. S MNT=$$MNTC^cAFE1(Q,$$BJ^cAFE1(Q,$P(INH,D,17)))
	.. S BSAL=$$OMREK(BSAL,MNT,MUNT,TXT)
	.. S JAAR=KM2($$BJ^cAFE1(Q,$P(INH,D,17))),TSAL=BSAL
	.. F I=3:1:16 S TXT(I)=""
	.. S TXT(3)=$$DCO^cAFD1($TR(KM1($$BJ^cAFE1(Q,$P(INH,D,17))),".","")_"01")
	.. I SWPRINT=0&(BSALDO1=BSAL) Q
	.. S SWP=0
	.. D PSAL 
	.. S SWP=1,SWPRINT=0,BSALDO1=BSAL
	. I 'SWP D PSAL S SWP=1
	. S MNT=$P(INH,D,13)  ; munt van de BH op ogenblik van registratie
	. I MNT="" S MNT=$$BF^cAFA1()
	. S DEC=$$DECVM^cAFE5(MNT)
	. ;  Datum
	. S TXT(3)=$P(INH,D)
	. ;  Journaal
	. S TXT(4)=$P(INH,D,2)
	. ;  F/C
	. S TXT(5)=$P(INH,D,3)
	. ;  Document
	. S TXT(6)=$P(INH,D,4)
	. ; Debet
	. S TXT(7)=$S($P(MNT,D)=$P(MUNT,D):$P(INH,D,5),1:$$OMREK($P(INH,D,10),$P(INH,D,8),MUNT,TXT))_"\\\\1\"_$P(MUNT,D,2)_"\\1"
	. ; Credit
	. S TXT(8)=$S($P(MNT,D)=$P(MUNT,D):$P(INH,D,6),1:$$OMREK($P(INH,D,11),$P(INH,D,8),MUNT,TXT))_"\\\\1\"_$P(MUNT,D,2)_"\\1"
	. ; S TXT(9)="=R[-1]C+RC[-2]-RC[-1]"
	. S VNR=8,TSAL=TSAL+TXT(7)-TXT(8)
	. ;  Saldo
	. ; I SWSAL S VNR=VNR+1,TXT(VNR)=$S('$G(SWVB):"=R[-1]C+RC[-2]-RC[-1]",1:TSAL),$P(TXT(VNR),D,20)=1,$P(TXT(VNR),D,21)=1
	. I SWSAL S VNR=VNR+1,TXT(VNR)=TSAL_"\\\\1\"_$P(MUNT,D,2),$P(TXT(VNR),D,20)=1
	. ;  Referte
	. ; S VNR=VNR+1,TXT(VNR)=$S($P(TXT,D,2)="AR"&($L($P(INH,D,3))):"",1:$P(INH,D,7))
	. S VNR=VNR+1,TXT(VNR)=$P(INH,D,7)
	. ;  Omschrijving (indien bij de klanten referte = omschr. --> omschr. leeg maken)
	. ;  KO - 16.08.06
	. ; S VNR=VNR+1,TXT(VNR)=$S($P(TXT,D,2)="KL"&($P(INH,D,14)=$P(INH,D,7)):"",1:$P(INH,D,14))
	. S VNR=VNR+1,TXT(VNR)=$P(INH,D,14)
	. ; Historiek KL/LE
	. I $E($P(TXT,D,2),1,2)'="AR" D
	.. ;  Munt
	.. S VNR=VNR+1,TXT(VNR)=$P(INH,D,8)
	.. ;  Debet Mnt
	.. S VNR=VNR+1,TXT(VNR)=$P(INH,D,10)_"\\\\1\"_$$DECVM^cAFE5($P(INH,D,8))
	.. ; Credit Mnt
	.. S VNR=VNR+1,TXT(VNR)=$P(INH,D,11)_"\\\\1\"_$$DECVM^cAFE5($P(INH,D,8))
	. ; Historiek grootboekrekeningen
	. I $E($P(TXT,D,2),1,2)="AR" D
	.. S VNR=VNR+1,TXT(VNR)=$P(INH,D,15)
	.. S VNR=VNR+1,TXT(VNR)=$P(INH,D,16)
	. ; Ini
	. S VNR=VNR+1,TXT(VNR)=$P(INH,D,9)
	. ; Datum
	. I $P($G(QU(0,2)),D,39) S VNR=VNR+1,TXT(VNR)=$S($L($P(INH,D,12)):$$HD^cAFD1($P(INH,D,12)),1:"")
	. ; Boekingsperiode
	. I PTS=3!(PTS=4) S VNR=VNR+1,TXT(VNR)=$P(INH,D,17)
	. D FORM
	. I $G(SWVB) D @BTEMP Q
	. S SWPRINT=1
	. D ^cA334
	; indien alle geselecteerde : ook beginsaldo indien geen bedragen
	I ACT!BSAL,'SWP D PSAL
	; Indien printen saldo: controleren of er nog meerdere jaren moeten geprint worden
	I SWSAL D
	. S EJAAR=$$DC^cAFD1($P(B(1),D,2))
	. S EJAAR=$E(EJAAR,1,4)_"."_$E(EJAAR,5,6)
	. S EJAAR=$$BJ^cAFE1(Q,EJAAR)
	. S TJAAR=$$BJ^cAFE1(Q,JAAR)
	. I TJAAR<EJAAR D
	.. F J=(TJAAR+1):1:EJAAR D
	... S BSAL=$$BSAL^cAFE1(Q,J,$P(TXT,D,2),I1)
	... I $P(TXT,D,2)="AR",$$SIG^cAFA1($P(TXT,D,2),I1,120) S BSAL=0
	... I $P(TXT,D,2)="ARA" S BSAL=$$SALDOARA^cTA180(Q,I1,$G(KM1(J)))
	... F I=3:1:16 S TXT(I)=""
	... S TXT(3)=$$DCO^cAFD1($TR(KM1(J),".","")_"01")
	... I SWPRINT=0&(BSALDO1=BSAL) Q
	... S SWPRINT=0
	... S BSALDO1=BSAL
	... D PSAL 
	; Indien alle geselecteerd, zonder beginsaldo: nummer en naam printen
	I ACT,'SWSAL,'SWLN,'SWPRINT D ^cA334
	I $G(SWVB) G YZ
	G 31
	;
4	S END=1 D ^cA334
	;
YZ	Q
	;
FORM	; bepalen formaat
	N I
	F I=1:1:17 S $P(TXT(I),D,20)=0
	F I=7:1:8 S $P(TXT(I),D,20)=1,$P(TXT(I),D,6)=$P(MUNT,D,2),$P(TXT(I),D,8)=1
	I $E($P(TXT,D,2),1,2)'="AR" F I=12+SWSAL:1:13+SWSAL S $P(TXT(I),D,20)=1
	I SWSAL S $P(TXT(9),D,20)=1
	S $P(TXT(3),D,20)=2
	I $E($P(TXT,D,2),1,2)'="AR" S:$P($G(QU(0,2)),D,39) $P(TXT(15+SWSAL),D,20)=2 F I=12,13 S $P(TXT(I+SWSAL),D,27)="0.00"
	I $E($P(TXT,D,2),1,2)="AR" S:$P($G(QU(0,2)),D,39) $P(TXT(14+SWSAL),D,20)=2
FORMZ	Q
	;
OMREK(R,MNT,MUNT,TXT)	; omrekenen bedragen
	Q $S($P(MNT,D)=$P(MUNT,D)!'R:R,1:$$OMREK^cAFE1(Q,R,$P(MNT,D),$P(MUNT,D),$S($P(TXT,D,2)="KL":"V",1:"A"),$P(MUNT,D,2)))
	;
PSAL	; printen saldo
	I 'SWSAL!'$L(BSAL) G PSALZ
	N I2,i
	S TXT(9)=$J(BSAL,0,$P(MUNT,D,2))_"\\\\1\"_$P(MUNT,D,2) S $P(TXT(9),D,20)=1,$P(TXT(9),D,21)=1,TSAL=+TXT(9) 
	; I $P(TXT,D,2)="AR" S TXT(14+$P($G(QU(0,2)),D,39)+SWSAL)=$E($$DC^cAFD1($P(TXT(3),D)),1,4)_"."_$E($$DC^cAFD1($P(TXT(3),D)),5,6)
	; I $P(TXT,D,2)'="AR" S TXT(15+$P($G(QU(0,2)),D,39)+SWSAL)=$E($$DC^cAFD1($P(TXT(3),D)),1,4)_"."_$E($$DC^cAFD1($P(TXT(3),D)),5,6)
	S TXT(10)=$P($T(@("T6"_QT)),U,2)
	S SWBSAL1=1
	D FORM
	I '$G(SWVB) D ^cA334 Q
	S I2=0 D @BTEMP 
PSALZ	Q
	;  Berekenen beginsaldo tot aan de gekozen maand 
SAL(BSAL,VANM,TOTM)	N R,B,I1,INH,RJ,RM,R3
	S $ZT="TRAP^cAN000"
	S TOTM=$$DC^cAFD1(TOTM)
	S RJ=$E(TOTM,1,4),RM=$E(TOTM,5,6)-1
	I RM=0 S RM=12 S RJ=RJ-1
	D S1^cA104
	S TOTM=R3_"."_$TR($J(RM,2)," ",0)_"."_$E(RJ,3,4)
	S B(1)=VANM_D_TOTM
	D ^cT48H
	S R=BSAL
	S I1=""
	F  S I1=$O(^HULP(boot,$J+.01,I1)) Q:I1=""  D
	. S INH=^(I1,0)
	. S R=R+$P(INH,D,5)-$P(INH,D,6)
SALZ	Q R
	;
ZZ	; 19.03.07 - 15 u 31 * V8.08