cT66	;Leveranciersbetalingen V6 ;%T66 ; [ 02/23/00  1:53 PM ]
	;
T0	;Voorbereiden & uitvoeren betalingen ;
T1	;Omschrijving;
T2	;Rekening;
T3	;Uitgevoerd;Europees;Internationaal
	; binnenland;buitenland;
T4	;Actueel saldo;
T5	;Factuurnummer; komt reeds voor bij deze betaling; reeds betaald;
T6	;Tot. uitgevoerd;
T7	;Betalingscumul.;
T8	;Muntcode werd gewijzigd: ;
	;
T0F	;Préparation & exécution des paiements ;
T1F	;Description;
T2F	;Compte;
T3F	;Exécuté;national;internat.;
T4F	;Solde actuel;
T5F	;N° de facture; existe déjà pour ce paiement; déjà payé;
T6F	;Total exécuté;
T7F	;Cumul de paiem.;
T8F	;Code mon. a été modifiée: ;
	;
T0E	;Voorbereiden & uitvoeren betalingen ;
T1E	;Omschrijving;
T2E	;Rekening;
T3E	;Uitgevoerd;binnenland;buitenland;
T4E	;Actueel saldo;
T5E	;Factuurnummer; komt reeds voor bij deze betaling; reeds betaald;
T6E	;Tot. uitgevoerd;
T7E	;Betalingscumul.;
T8E	;Muntcode werd gewijzigd: ;
	;
	; window + titel
1	;D O^cA612(2,1,20,80,1,1,1,1),T^cA612($P($T(@("T0"_QT)),U,2),0,0,7,1,1) ;10.03.00
	D P^cA612(2,1,20,80,1,1,1,1,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
13	D DMS^cAN000("UQC","USC","BVB") G YZ:UQC=""!(USC="")
15	S UREF=^DMC(UQC,USC,"DATA","REF"),BF=$$BF^cAFA1
	;
	; synoniemen op voorbereiding
2	S BVB=$$^cANSYN("BVB") G YZ:K="-"
21	S UI1=BVB L +@UREF:2 E  D TXT^cAFA1(14) G 2
23	S B(1)=$$SIGN^cAFA1("BVB",BVB,0),DATUMUIT=$P(B(1),D,6)
25	S BR=$P(B(1),D,2),K=$$SIGN^cAFA1("AR",BR,0)       ; grootboekrekening
26	S BNR=$P(K,D,9),J=$TR($E($P(BNR,"-"),1,2),"0123456789")
	I $$IBAN^cAFI2(BNR) S BNR=$E(BNR,5,99),J=""   ; KU 09.06.08   ; IBAN omvormen naar gewoon nr
	I J'="" S BNR=$P(BNR,"-",2)   ; GD - 08.08.03
27	S BNK=$P(K,D,2),AFK=$P(K,D,10),HBF=$P(K,D,11),PRO=$P(K,D,12),HQD=$$DEC^cAFA1(HBF) I HBF="" S HBF=BF
29	I HBF'=$P(B(1),D,4) S K=$P($T(@("T8"_QT)),U,2)_HBF_" / "_$P(B(1),D,4) D TXT^cAFA1(250) G YZ
	;
	; detaillijnen
3	D ^cT66L ; totaal/lev. ipv. D BS^cAN210("BVB.DET",0,0,0,0)
31	L -@UREF G 2
	;
YZ	D C^cA612 Q
	;
CUM	; berekenen cumul = som detaillijnen; UREF = BVB.DET
	S (K,UI1)=0 F  S UI1=$O(@UREF) Q:UI1=""  S K=K+$P(^(UI1),D,4)
	S $P(^(0),D,5)=K
CUMZ	Q
	;
REF	; refresh TOP van BVB
	S B(1)=$$SIGN^cAFA1("BVB",BVB,0),DATUMUIT=$P(B(1),D,6) D TOP
REFZ	S OK=1 Q
	;
TOP	; opzetten top detail voorbereiding
	N R
	S UTOP(1)="1\1\"_$P($T(@("T1"_QT)),U,2)_"\4"      ; omschrijving
	S UTOP(1.1)="1\14\: "_$P(B(1),D)_D_0
	S UTOP(2)="2\1\"_$P($T(@("T2"_QT)),U,2)_"\4"      ; rekening
	S UTOP(2.1)="2\14\: "_$E(BR_BNK,1,25)_D_0
	S UTOP(3)="3\1\"_$P($T(@("T3"_QT)),U,2)_"\4"      ; datum uitvoering
	S K=DATUMUIT I 'K S K=$$JN^cAFO1(K)
	; E  S K=K_" ("_$P($T(@("T3"_QT)),U,3+$P(B(1),D,7))_")"
	S UTOP(3.1)="3\14\: "_$E(K_$J("",25),1,25)_D_0
	S UTOP(4)="1\43\"_$P($T(@("T4"_QT)),U,2)_"\4"     ; saldo
	D SAL
	S UTOP(4.1)="1\59\: "_$$IP^cAFA1(K,HQD,13)_" "_HBF_D_0
	S UTOP(5)="2\43\"_$P($T(@("T6"_QT)),U,2)_"\4"     ; tot. uitgevoerd
	D UIT
	S UTOP(5.1)="2\59\: "_$$IP^cAFA1(K,HQD,13)_" "_HBF_D_0
	S UTOP(6)="3\43\"_$P($T(@("T7"_QT)),U,2)_"\4"     ; bet.cumulatie
	S UTOP(6.1)="3\59\: "_$$IP^cAFA1($P(B(1),D,5),HQD,13)_" "_$P(B(1),D,4)_D_0
	S UTOP(7.1)="3\25\"_$P($T(@("T3"_QT)),U,3+$P(B(1),D,7))_"\0"     ; Europees <> Internationaal
	S OK=0    ; niet meer converteren
TOPZ	S REFTOP=1 Q
	;
SAL	; berekenen saldo K van BR in muntcode HBF
	N BJ,CI,CN,DI,DN,MNT
	S BJ=$P(@("^"_Q_"BA(2)"),D,2)\1,DI=BJ I HBF'=BF S DI=DI+.01
	S CI=DI+.02,DN=$G(@("^"_Q_"AR(BR,DI)")),CN=$G(^(CI)),K=+DN D  S DN=$G(^(DI)),CN=$G(^(CI)) D
	. F I=2:1:25 S K=K+$P(DN,D,I)-$P(CN,D,I)
	. I DI=BJ S MNT=$P($$MNTC^cAFE1(Q,BJ),D) I MNT'=BF S K=$$BEDR^cAFE1(Q,K,MNT,BF,"F")
	. S DI=DI+1,CI=CI+1
SALZ	Q
	;
UIT	; totaal uitgevoerd K van BR in muntcode HBF
	N UQC,USC,UREF,UI1
	D DMS^cAN000("UQC","USC","BVB") S UREF=^DMC(UQC,USC,"DATA","REF")
	S K=0,UI1="" F  S UI1=$O(@UREF) Q:UI1=""  D
	. S J=^(UI1,0) I $P(J,D,30) Q           ; enkel operationele
	. I $P(J,D,2)'=BR Q                     ; andere financiële rekening
	. I '$L($P(J,D,6)) Q                    ; niet definitief
	. S K=K+$P(J,D,5)
UITZ	Q
	;
ZZ	; 19.06.08 - 12 u 09 * V9.01