cT661G	;Betalingsvoorstel leveranciers ;%T66 ; [ 10/21/99  11:15 AM ]
	G 1
	;
T0	;Groeperen ;
	;
T0F	;Groupegement ;
	;
T0E	;Groeperen ;
	;
	; LOCK betalingsvoorstellen
1	N UQC,USC,UREF,UI1 K ^HULP(boot,$J)
11	D DMS^cAN000("UQC","USC","BVS") S UREF=^DMC(UQC,USC,"DATA","REF"),UI1=0
13	S UI1=$O(@UREF) G 2:UI1="",13:UI1=BVS
15	L +@UREF:2
17	I $T S ^HULP(boot,$J,UI1,0)=@UREF@(0)
19	G 13
	;
	; selectie (gelockte) betalingsvoorstellen
2	D BS^cAN210("BVS.G",1,1,1,0)
	;
	; UNLOCK betalingsvoorstellen
3	S UI1=0
31	S UI1=$O(^HULP(boot,$J,UI1)) G Y:UI1=""
33	L -@UREF G 31
	;
	; einde
Y	K ^HULP(boot,$J)
YZ	Q
	;
	; groeperen geselecteerde (gelockte) betalingsvoorstellen
G	S UI1=0 K ^HULP(boot,$J+.01) D EG^cAFA1 ; hergroeperen per leverancier
GA	S UI1=$O(^HULP(boot,$J,UI1)),I4=0 G GD:UI1="",GA:'$P(^(UI1,0),D,11)
GB	S I4=$O(^DATA(Q,"BVS",UI1,I4)) I I4="" G GA
GC	S N=^(I4),KC=$P(N,D),FNR=$P(N,D,2),^HULP(boot,$J+.01,KC,FNR)=N G GB
GD	S I1=0,VNR=0,BVSNR=0                    ; alfabetisch per leverancier
GE	S I1=$O(@("^"_Q_"LE(I1)")) I I1="" G GJ
GF	S KC=$P(^(I1,0),D) I '$D(^HULP(boot,$J+.01,KC)) G GE
GG	S VNR=VNR+1,FNR=99999 W /CUP(1,40),$P(@("^"_Q_"LE(I1,0)"),D,2),@F1
GH	S FNR=$O(@("^"_Q_"LE(I1,FNR)")) G GE:FNR'?6N,GH:'$D(^HULP(boot,$J+.01,KC,FNR))
GI	S N=^(FNR),$P(N,D,5)=VNR,BVSNR=BVSNR+1,$P(N,D,7)=BVSNR,I4=VNR*1E6+FNR+1E12,^DATA(Q,"BVS",BVS,I4)=N
	S $P(^(0),D,8)=VNR+1,$P(^(0),D,7)=$P(^(0),D,7)+$P(N,D,4),$P(^(0),D,12)=BVSNR+1,^DATA(Q,"BVS.NR",BVS,BVSNR)=I4 G GH
GJ	S UI1=0                                 ; verwijderen oude voorstellen
GK	S UI1=$O(^HULP(boot,$J,UI1)) I UI1="" K ^HULP(boot,$J+.01) G GY
GL	I $P(^(UI1,0),D,11) D X^cAN220("BVS",0,UI1)
GM	G GK
GY	S EXIT=1
GZ	D C^cA612 Q
	;
	; [] = (de)selecteren
SEL	S K=$P(@UREF@(0),D,11),$P(^(0),D,11)='K
SELZ	Q
	;
ZZ	; 05.02.01 - 16 u 23 * V7.84