cT860	;Eenmalige boekingsreeksen ;%T86* ; [ 01/22/01  2:24 PM ]
	G 1
	;
T0	;Eenmalige boekingsreeksen;
T1	;Saldo;
T4	;Verwijderen\"[] = enkel detaillijnen   .[] = volledig verwijderen";
T5	;Bevestiging\".[] = alles omdraaien";
T6	;Boekingsreeks;Boekingsmaand;Analytisch;Jrn.;Creatiedatum;Initialen;Referte - oms.;Datum;
	;
T0F	;Série d'écritures uniques;
T1F	;Solde;
T4F	;Annuler\"[] = seulement lignes dét.   .[] = annuler complètement";
T5F	;Confirmation\".[] = inverser tout";
T6F	;Série d'écr.;Mois compt.;Analytique;Jrn.;Date création;Initiales;Référ. - descr.;Date;
	;
T0E	;Once-only automatic registrations;
T1E	;Balance;
T4E	;Remove\"[] = only detail lines   .[] = remove completely";
T5E	;Confirmation\".[] = invert all";
T6E	;Aut. reg.;Fiscal month;Analytical;Jrn.;Creat. date;Initials;Refer. -des.;Date;
	;
	; initialisatie
1	S SWFI=0,SAFI=0,HBF="",HQD=""
11	;D O^cA612(2,1,20,80,1,0,0,0),T^cA612($P($T(@("T0"_QT)),U,2),0,0,7,1,1) ;10.03.00
	D P^cA612(2,1,20,80,1,0,0,0,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
13	D DMS^cAN000("UQC","USC","FID.J") G YZ:UQC=""!(USC="")
14	S UREF=^DMC(UQC,USC,"DATA","REF"),UI1=0 L +@UREF:2 E  D BUSY^cAFA1 G YZ
15	D ^cT164 G YZ:'OK
17	S BF=$P(@("^"_Q_"BA(39)"),D),QD=$G(^(34))
19	S HBF=BF,RB="D",Q41="^"_Q_"AR(BR,0)",Q95="^"_Q_"FI(BP,RB,BNR)",PAR=1,(BPE,BPEC)=$G(@("^"_Q_"BA(""SWBP"")"))
	;
	; vraag naar journaal
2	S R="JRN\D\1300\1\1700" D ^cA336 G YZ:K="-" S JRNO=JRN
21	S RB="D" S:JRN RB=RB_JRN S K=$$DC^cAFD1(DT),Q93="^"_Q_"BA(4,RB,"_K_")",@Q93=$G(@Q93,K_"0001")
23	D BS^cAN210("FID.J",0,0,0,0)
	;
YZ	D C^cA612 Q
	;
	; registratie detaillijn
DET	I 'UI1 S UI1=UI1FID_" z" S UI1=$O(@UREF,-1) S UI1=$P(UI1," ")_" "_($P(UI1," ",2)+1) I $P(UI1," ")'=UI1FID S UI1=UI1FID_" "_1000
DETA	I $D(@UREF) D
	. N I,J,K S J=UI1 N UI1
	. S I=J F LYN=$P(I," ",2):1 S UI1=UI1FID_" "_LYN Q:'$D(@UREF)
	. S I=$P(UI1," ",2) F LYN=I:-1:$P(J," ",2)+1 S UI1=UI1FID_" "_(LYN-1),K=@UREF@(0),UI1=UI1FID_" "_LYN,@UREF@(0)=K
DETB	S $P(B(1),D,11)=UI1FID S @UREF@(0)=B(1)
DETZ	S OK=1 Q
	;
	; wijzigen hoofding
H	D W^cAN200("FID.J",0,"","",$$IDEM^cAFA1)          ; wijzigen hoofding
HA	D TOP S REFTOP=1                                  ; TOP opnieuw tonen
HZ	Q
	;
	; verwijderen
V	S R="K\22\3\"_$P($T(@("T4"_QT)),U,2)_"\1\\""-.""[K" D R0 G VZ:K="-"
VA	I K="" D VDET(UI1FID),TOP S (REFRESH,REFTOP)=1 G VZ
VC	S UI1=UI1FID D X^cAN200("FID.J",0,"","",$$IDEM^cAFA1) I $G(KILL) S EXIT=1 K KILL
VZ	Q
	;
	; alles omdraaien
X	S R="K\22\3\"_$P($T(@("T5"_QT)),U,2)_"\1\\K="".""!(K=""-"")" D R0 G XZ:K="-"
XB	N I,J S UI1=UI1FID_" " F  S UI1=$O(@UREF) Q:$P(UI1," ")'=UI1FID  D
	. S J=^(UI1,0),I=$P(J,D,2),I=$S(I["-":+I,1:I_"-"),$P(^(0),D,2)=I
XC	D TOP S (REFRESH,REFTOP)=1
XZ	Q
	;
	; TOP updaten
TOP	N UQC,USC,UI1 D DMS^cAN000("UQC","USC","FID.J")
	S MNT=BF,DEC=$$DECVM^cAFE5(MNT)
	S UI1=UI1FID S UTOP(1)=$P($T(@("T6"_QT)),U,2),UTOP(1.1)=$$SIG^cAFA1("FID.J",UI1,101)_" "_$P(^(0),D,2)_$J("",30)
	S UTOP(2)=$P($T(@("T6"_QT)),U,3),UTOP(2.1)=$P(^(0),D,4)
	S JRN=$P(^(0),D,3) S UTOP(102)=1_D_55_D_$P($T(@("T6"_QT)),U,5)_D_4,UTOP(102.1)=1_D_60_D_": "_$$JRN^cAFO2("D",JRN)_" "_D_0
	S UTOP(103)=2_D_32_D_$P($T(@("T6"_QT)),U,4)_D_4,UTOP(103.1)=2_D_42_D_": "_$$SIG^cAFA1("FID.J",UI1,105)_D_0
	S UTOP(108)=2_D_55_D_$P($T(@("T6"_QT)),U,9)_D_4,UTOP(108.1)=2_D_60_D_": "_$P(^(0),D,11)_D_0
	S UTOP(3)=$P($T(@("T6"_QT)),U,6),UTOP(3.1)=$P(^(0),D,9)
	S UTOP(104)=3_D_32_D_$P($T(@("T6"_QT)),U,7)_D_4,UTOP(104.1)=3_D_42_D_": "_$P(^(0),D,8)_D_0
	S UTOP(106)=4_D_1_D_$P($T(@("T6"_QT)),U,8)_D_4,UTOP(106.1)=4_D_15_D_": "_$P(^(0),D,6)_" - "_$P(^(0),D,7)_D_0
	S UI1=UI1FID_" "
	S UTOP(105)=3_D_55_D_$P($T(@("T1"_QT)),U,2)_D_4,UTOP(105.1)=0,UTOP(107.1)=0
	F  S UI1=$O(@UREF) Q:UI1=""!($P(UI1," ")'=UI1FID)  S K=$P(^(UI1,0),D,2),UTOP(107.1)=UTOP(107.1)+$S(K["-":-K,1:K)
	S UTOP(105.1)=3_D_60_D_":                     "
	S UTOP(107.1)=3_D_60_D_": "_$$IP^cAFA1(UTOP(107.1),DEC,13)_MNT
TOPZ	D TOP^cAN210 Q
	;
	;check boekingsmaand ok ?
OKBP(BP)	S OK=0 I '$G(BENTER) G OKZ:"-,"[K!(RK=31)
	N K,R S K=+$P(BP,".",2),R=K_D_$S($G(BENTER):1,1:0)_D_1 D M^cT163 I K="-" S OK=0
OKZ	Q OK
	;
	;check analytische maand ok ?
OKABP(BP)	S OK=1 G OKAZ:"-,"[K!(RK=31)
	I BP'>$P(@("^"_Q_"BA(2)"),D,3) S OK=0
	I OK,BP?4N1"."2N,BP#1<.13 G OKAZ
	S OK=0
OKAZ	Q OK
	;
	;verwijderen detaillijnen vanuit B[]
VDET(NR)	N UI1 S UI1=NR_" " 
	F  S UI1=$O(^DATA(Q,"FID.J.DET",UI1)) Q:$P(UI1," ")'=NR  D X^cAN220("FID.J.DET",0,UI1)
VDETZ	Q
	;
	; bepalen boekinsgdatum
BODA(MN)	N R I 'MN S R="" G BODAZ
	S R="01."_$E(MN,6,7)_"."_$E(MN,3,4)_"\0DEM" D ^cA104
	I $$DC^cAFD1(R)>$$DC^cAFD1(DT) S R=DT
BODAZ	Q R
	;
	; berekenen saldo van een reeks
SAL(I1)	N UI1,IND,BED,INH S SALDO=0,UI1=I1_" "
SALA	S UI1=$O(@UREF) G SALZ:$P(UI1," ")'=I1 
	S INH=^(UI1,0),BED=$P(INH,D,2) I BED["-" S BED=-BED
SALB	S SALDO=SALDO+BED G SALA
SALZ	S SALDO=-$J(SALDO,0,DEC) Q SALDO
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 15.12.05 - 12 u 16 * V8.05