cTEA7	;Beheer budgetten rekening - anal.rekening; cTEA7
	;
T0	;Beheer budgetten rekening - anal. rekening;
T1	;Jaarbedrag;Identiek maandbedrag;Manuele ingave alle maanden;Wijzigen 1 maandbedrag;Proportionele verdeling jaarbedrag volgens patroon;
T2	;Keuze\"-[] = einde zonder wijziging";
T3	;Bedrag\;
T4	;Bevestiging\"[] = ok   ,[] = hernemen";
T5	;Gewenste maand\"-[] = einde wijzigingen";
T6	;nnnnnn of nnnnnn-[] = bedrag in ;
T7	; Rekening : ;  Anal.rek.: ;
T10	;Boekjaar\"-[] = einde programma   [] = ;
	;
T0F	;Gestion des budgets compte - compte anal.;
T1F	;Montant annuel;Montant mensuel identique;Entrée manuel par mois;Modification d'un montant mensuel;Répartition montant annuel suivant modèle;
T2F	;Choix\"-[] = fin sans modifications";
T3F	;Montant\;
T4F	;Confirmation\"[] = ok   ,[] = reprendre";
T5F	;Mois désiré\"-[] = fin des modifications";
T6F	;nnnnnn ou nnnnnn-[] = montant en ;
T7F	; Compte   : ;  Compte anal.: ;
T10F	;Année comptable\"-[] = fin du programme   [] = ;
	;
1	S Q1="AR",Q2="ARA"
101	S K=$P($T(@("T0"_QT)),U,2)_" "_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
102	S J=@("^"_Q_"BA(2)"),I=$P(J,D,2),I=I\1*12+(I#1*100),K=^(7),J=J-1,PAT="",MAX=0
11	D 7 G YZ:K="-"
12	S J=J+1 I J<I S BJ=J\12,MAX=MAX+1,X=J-(BJ*12)+1,X=^cBA(2,$E(QT_"N"),X),PAT=PAT_X_" "_BJ_D G 12
13	F I=1:1 S K=$P(PAT,D,I) Q:'$L(K)  S FP=I*100+303-(I>13*1260) W @F,$J("",$L(K)+4),@F9,@F,$J(I,2),".",@F6,K,@F9,$J(":",15-$L(K))
14	S MNTC=$$MNTC^cAFE1(Q,BJ),BF=$P(MNTC,D),QD=$P(MNTC,D,2)
15	S AR=$$^cANSYN(Q1) G YZ:K="-",15:$P(^(AR,0),D,13)!'$P(^(0),D,21)
16	S ARA=$$^cANSYN(Q2) G 15:K="-",16:$P(^(ARA,0),D,13)!'$P(^(0),D,21)
17	L +^DBH(Q,"BUD.AR.ARA",AR_ARA):2 E  D TXT^cAFA1(14) G 15
	; Ophalen reeds geregistreerde bedragen
18	F I=1:1:MAX S INH=$G(^DBH(Q,"BUD.AR.ARA",BJ_$TR($J(I,2)," ",0)_" "_AR_ARA_"0 0",0)) S BDR(I)=$P(INH,D,6)-$P(INH,D,7) D 9:BDR(I)
19	S K=$P($T(@("T7"_QT)),U,2)_$E($$SIG^cAFA1(Q1,AR,101)_" "_$P(^(0),D,2)_" ",1,16)_$P($T(@("T7"_QT)),U,3)_$E($$SIG^cAFA1(Q2,ARA,101)_" "_$P(^(0),D,2)_" ",1,16),FP=1720+$L(K) W @F,@F93 S FP=1719 W @F,@F92,K,@F93 F I=1:1:5 S FP=I*100+1603 W @F,I,". ",$P($T(@("T1"_QT)),U,I+1)
	;
	; keuze 1-2-3-4-5
2	S R="KEU\22\3\"_$P($T(@("T2"_QT)),U,2)_"\1\\K>0&(K<6)!(K=""-"")" D R0 G 85:K="-",3:K=3,4:K=4
21	S R="BDR\22\3\"_$P($T(@("T3"_QT)),U,2)_"C1\10\\$$W^cAFI2(K,QD,1)" D R0 S:K["-" BDR=-K G 2:K="-",5:KEU=5
22	S X=BDR F I=1:1:MAX S BDR(I)=BDR
23	I KEU=1 S K=+$J(BDR/MAX,0,QD),X=0 F I=1:1:MAX S BDR(I)=K,X=X+K
25	S BDR(MAX)=BDR(MAX)+BDR-X G 8
	;
	; alle maanden
3	S I=0
31	I I<MAX S I=I+1 D 45 G 31:K'="-" S I=I-2 G 31:I>-1,85
32	G 81
	;
	; één maand
4	S R="I\22\3\"_$P($T(@("T5"_QT)),U,2)_"\2\\K?.N&(K>0&(K<MAX+1))!(K=""-"")" D R0 G 81:K="-" D 45 G 4
45	S R="K\22\3\"_$P(PAT,D,I)_"\C1\10\\$$W^cAFI2(K,QD,1)" D R0 Q:K="-"
46	S:K["-" K=-K S BDR(I)=K G 9
	;
	; volgens patroon
5	D S1 G 19:K="-" S K=^(K),(X,KEU)=0 F I=1:1:MAX S KEU=KEU+$P(K,D,I+2)
51	S:'KEU KEU=1 F I=1:1:MAX S BDR(I)=$J(BDR*$P(K,D,I+2)/KEU,0,QD),X=X+BDR(I)
52	G 25
	;
	; Vraagstelling boekjaar
7	S R="K\22\3\"_$P($T(@("T10"_QT)),U,2)_(I-1\12+1)_"   .[] = "_(I-1\12)_"""\1\\""-.""[K" D R0 Q:$L(K)
71	S J=I-1,I=I+12 Q
	;
	; bevestiging
8	F I=1:1:MAX D 9
81	S R="K\22\3\"_$P($T(@("T4"_QT)),U,2)_"\1\\"",-""[K" D R0 G 19:$L(K)
82	S @%Q1=0
83	F I=1:1:MAX D
	. S UI1=BJ_$TR($J(I,2)," ",0)_" "_AR_ARA_"0 0"
	. S K=BDR(I),J="" S:K<0 J=-K,K=""
	. ; Wijzigen bestaande bedragen budgetten
	. I $D(^DBH(Q,"BUD.AR.ARA",UI1)) D  Q
	.. K TAB
	.. S TAB(106)=K,TAB(107)=J
	.. D B^cAN220("BUD.AR.ARA",0,UI1,"TAB")
	. ; Openen nieuw budget
	. K BB
	. S BB(1)=AR_D_ARA_D_"0 "_D_BJ_"."_$TR($J(I,2)," ",0)_D_0_D_K_D_J
	. D P^cAN220("BUD.AR.ARA",0,UI1,"BB","")
84	S @%Q1=1
85	F I=1:1:MAX S BDR(I)=0 D 9    ; vegen
86	L -^DBH(Q,"BUD.AR.ARA",AR_ARA) G 16
	;
	; tonen bedrag
9	S FP=I*100+324-(I>13*1260),R=BDR(I)_D_14_D_D_QD W @F,$J("",15),@F I R D R3 W BF
91	Q
	;
YZ	Q
	;
	; commentaar bedrag
C1	W !?2,$P($T(@("T6"_QT)),U,2),BF Q
	;
R0	S R0=$P(R,D,5) I $L(R0),R0'["""" S $P(R,D,5)=R0_"^"_$T(+0)
R0A	S R0=$P(R,D,7) I $L(R0),R0'="DCTR" S $P(R,D,7)="",R1=$P(R,D,8),R0=$P($T(@R0),U,2,99) S:$L(R1) R0=R0_"&("_R1_")" S $P(R,D,8)=R0
R0Z	S $P(R,D,12)=$T(+0) K R0,R1 D ^cA100 Q  ; v11 30.05.94
	;
R3	S R1=$P(R,D,2),R2=$P(R,D,4),R0=$J($P(R,D,1),0,R2),R3=" ",R4="" S:R2 R4=","_$P(R0,".",2),R1=R1-1-R2 S:R0<0 R3="-",R0=-R0
R3A	S R0=+$P(R0,".",1) F R5=3,7 S R6=$L(R0) Q:R6'>R5  S R0=$E(R0,1,R6-R5)_"."_$E(R0,R6-R5+1,R6)
R3B	W ?$P(R,D,3),$J(R0,R1),R4,R3
R3Z	K R0,R1,R2,R3,R4,R5,R6 Q  ;V2 20.11.86
	;
S1	D ^cAN105("K",18,0,"KODE.PAT") Q
	;
ZZ	; 23.06.05 - 17 u 03 * V8.04