cTEA9	;Lijst evaluatie rekening - analytische rekening ;cTEA9 ; 
	;
T0	;Lijst evaluatie rekening-anal. rekening ;
T1	;Nummer\Naam van de rekening\Nummer\Naam van de anal.rekening\Realisatie\Budget\Evaluatie\%;2\Maand\C.Realisatie\C.Budget\C.Evaluatie\%;2
T8	;Gewenste maand\"-[] = einde programma   jjjj.mm[] = bepaalde maand   [] = ;
T9	;Maand;
	;
T0F	;Liste d'évaluation compte-compte analytique ;
T1F	;Numéro\Nom du compte\Numéro\Nom du compte anal.\Réalisation\Budget\Evaluation\%;2\Mois\C.Réalisation\C.Budget\C.Evaluation\%;2
T8F	;Mois désiré\"-[] = fin du programme   aaaa.mm[] = mois spécifique   [] = ;
T9F	;Mois;
	;
1	D P^cA612(2,1,20,80,1,0,1,1,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
11	W /CUP(2,2),@F1
	S BPB=@("^"_Q_"BA(2)"),S=^(7)
	S S=S+.01 S:$P(S,".",2)=13 S=S+.88 S:$L(S)=6 S=S_0
15	S R="BP\22\3\"_$P($T(@("T8"_QT)),U,2)_S_"""\7\\K?4N1"".""2N&($P(K,""."",2)<13&$P(K,""."",2))!(""-""[K)"
	D R0 G YZ:K="-" S:K="" BP=S  
	I BP'>$P(BPB,D,3) D TXT^cAFA1(61) G 15
	S BJ=$$BJ^cAFE1(Q,BP)
	W /CUP(2,2),@F6,$P($T(@("T9"_QT)),U,2),@F9,": "_BP
	;
2	D ^cAN003(4,"AR") G 11:K="-"
	;
3	D ^cAN003(9,"ARA") G 2:K="-"
	;
4	D ^cAN3223("","1#4#5",">80") G 3:K="-"
	;
5	K ^TEMP(boot,$J) 
	S j=0
51	D ^cAN004("UI1ARA","ARA") G 6:UI1ARA="" S j=j+1
	S ^TEMP(boot,$J,1,j_" "_UI1ARA)=UI1ARA G 51
	;
6	S HD(1)=D,HD(2)=D_$P($T(@("T0"_QT)),U,2)_BP_";C;F82;2",HD(3)=D 
	S TAB="8\41\49\82\95\108\121\126\134\147\160\173\178",TIT(1)=$P($T(@("T1"_QT)),U,2,99)
	;
7	D ^cAN004("UI1AR","AR") G 79:UI1AR="" 
	D GD("AR",UI1AR,.BREK,.BOMSCH)
	S TXT(1)=BREK
	S TXT(2)=BOMSCH
	S IARA="" F  S IARA=$O(^TEMP(boot,$J,1,IARA)) Q:IARA=""  D
	. S IARAMS=^(IARA)
	. S BSALDO=$$GA("BUD.AR.ARA",BP*100,UI1AR,IARAMS)
	. ; I $L(BSALDO) D 
	. ; SW - 01.07.05 - gegevens met realisaties zonder budget ook tonen.
	. ; vroeger stonden er ".." voor elke lijn tot en met D ^cA334
	. S:'$L(BSALDO) BSALDO=0 ; SW - 01.07.05 - deze codelijn werd toegevoegd 
	. S BREK="",BOMSCH="",RREK="",ROMSCH=""
	. D GD("ARA",IARAMS,.RREK,.ROMSCH)
	. S RSALDO=$$GA("CUM.AR.ARA",BP*100,UI1AR,IARAMS)
	. S TXT(3)=RREK
	. S TXT(4)=ROMSCH
	. S:'$L(RSALDO) RSALDO=0
	. ; I BSALDO=0,RSALDO=0 Q  ; SW - 01.07.05 - deze codelijn werd toegevoegd 
	. ; ; Records zonder realisaties en budget worden niet toegevoegd in de lijst. 
	. ; SW - 04.07.05 - bovenstaande 2 codelijnen werden in commentaar gezet omdat 
	. ; gegevens met real.=0 en budget=0 WEL moeten getoond worden als er een 
	. ; gecumuleerde waarde is als gevolg van registraties in voorgaande maanden.
	. S TXT(5)=$$FN(RSALDO)
	. S TXT(6)=$$FN(BSALDO)
	. S TXT(7)=$$FN(BSALDO-RSALDO)
	. S TXT(8)=$$FP("0")
	. S:(BSALDO) TXT(8)=$$FP(RSALDO/BSALDO*100)
	. S TXT(9)=BP
	. S CRSALDO=$$SALDO^cTA180(Q,UI1AR,IARAMS,0,BP,0,"CUM.AR.ARA",1)
	. S CBSALDO=$$SALDO^cTA180(Q,UI1AR,IARAMS,0,BP,0,"BUD.AR.ARA",1)
	. I 'BSALDO,'RSALDO,'CRSALDO,'CBSALDO Q  ; SW - 04.07.05 - deze codelijn werd toegevoegd
	. ; Records met realisaties=0 en budget=0 EN ZONDER gecumuleerde waarden worden niet toegevoegd in de lijst. 
	. S TXT(10)=$$FN(CRSALDO)
	. S TXT(11)=$$FN(CBSALDO)
	. S TXT(12)=$$FN(CBSALDO-CRSALDO)
	. S TXT(13)=$$FP("0")
	. S:(CBSALDO) TXT(13)=$$FP(CRSALDO/CBSALDO*100)
	. D ^cA334
	G 7
79	S END=1 D ^cA334 
	;
Y	K ^TEMP(boot,$J)
YZ	D E^cA612 Q
	;
FN(NUMGEG)	; Formaat voor export Excel en interpunctie bij printen voor numeriek gegeven
	S $ZT="TRAP^cAN000"
	S NUMGEG=NUMGEG_"\\\\1\"_$P($$MNTC^cAFE1(Q,BJ),D,2)
FNZ	Q NUMGEG
	;
FP(PERGEG)	; Formaat voor export Excel voor percentage gegeven
	S $ZT="TRAP^cAN000"
	S PERGEG=PERGEG_"\\\\1\0"
FPZ	Q PERGEG
	;
GA(GLSUB,HMAAND,I1,I2)	; Ophalen saldo van actieve records 
	N SALDO,RETSTR  
	S $ZT="TRAP^cAN000"
	S SALDO=""
	S RETSTR=$G(^DBH(Q,GLSUB,HMAAND_" "_I1_I2_"0 0",0))  ;I1 , I2 doorgeven met spatie achteraan (key)
	I '$L($G(RETSTR)) G GAZ
	I ($P($G(RETSTR),D,30)) G GAZ
	S SALDO=$P(RETSTR,D,6)-$P(RETSTR,D,7)
GAZ	Q SALDO
	;
GD(GLOB,IREK,OREK,OMSCH)	; Ophalen rekening nummer en omschrijving van de rekening
	S $ZT="TRAP^cAN000"
	S OREK=$$SIG^cAFA1(GLOB,IREK,101)
	S OMSCH=$P(^(0),D,2)
GDZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 15.12.05 - 12 u 16 * V8.05