cTN8020	;BTW-aangifte dotNet: berekenen gewonen firma's; cTN8020;                         [ 05/12/09  12:45:19 ]
	;
T1	;Aangifte van 2010 kan maar vanaf 05.02.10 worden ingediend.;
	;
T1F	;Une déclaration de 2010 ne peut être déposée qu'à partir du 05.02.10.;
	;
T1E	;It is only possible to submit the declaration of 2010 as from 05.02.10.;
	;
YZ	Q
	;
BA(UI1BA)	; Berekenen gewone Belgische firma
	; Input : UI1BA: UI1 van de BTW aangifte
	;
	N INHBA,KEU,KW,BP1,BP2,STAT,I
	S $ZT="TRAP^cAN000"
	; Ophalen gegevens BTW-aangifte
BAA	S INHBA=$$SIGN^cAFA1("BA",UI1BA,0)
	I $G(SWXW) S INHBA=B(1)   ; indien vanuit wijzigen hoofding
	N B
	; Keuze: "" = per kwartaal,  1 = per maand
	S KEU=$S($L($P(INHBA,D)):"",1:1)
	; Bepalen kwartaal
	S KW=$P(INHBA,D,2)
	; Bepalen begin en einde boekingsmaand
	S BP1=$P(INHBA,D),BP2=$P(INHBA,D)
	I $L(KW) S BP1=$P(KW,".")_"."_$TR($J($P(KW,".",2)-1*3+1,2)," ",0)
	I $L(KW) S BP2=$P(KW,".")_"."_$TR($J($P(KW,".",2)*3,2)," ",0)
	I $L(KW) S KW=+($P(KW,".",2))
	; Bepalen status
	S STAT=$P(INHBA,D,3)
	;
BA1	G ^cTN80200   ; nieuwe versie vanaf 01.12.09  : zie KU
	;
	; BTW-nr, naam vennootschap, adres, postcode, gemeente
BA2	F I=2:1:5 S $P(B(1),D,I)=$P(INHBA,D,I+4)
	; BTW-nummer
	S $P(B(1),D,7)=$P(INHBA,D,5)
	; Naam ondertekenaar
	S $P(B(1),D,9)=$P(INHBA,D,10)
	; Functie ondertekenaar
	S $P(B(1),D,12)=$P(INHBA,D,11)
	; Telefoon ondertekenaar
	S $P(B(1),D,13)=$P(INHBA,D,12)
	; Herziening vak 61
	; S $P(B(2),D)=$$SIG^cAFA1("BA.DET",UI1BA_" "_61,106)
	; Herziening vak 62
	; S $P(B(2),D,2)=$$SIG^cAFA1("BA.DET",UI1BA_" "_62,106)
	; Voorschot vak 91
	; S $P(B(2),D,3)=$$SIG^cAFA1("BA.DET",UI1BA_" "_91,106)
	; BTW-bankkosten
	S $P(B(2),D,4)=$P("\S\",D,$P(INHBA,D,16)+1)
	; Aanvraag om terugbetaling
	S $P(B(2),D,7)=$P(INHBA,D,14)
	; Aanvraag van betaalformuier
	S $P(B(2),D,8)=$P(INHBA,D,15)
	;
	I $G(SWXW) G BAC  ; komt vanuit wijzigen hoofding en er dient geen bereking te gebeuren
	;
BAB	D VB^cTN8021(KEU,KW,BP1,BP2,STAT,.B)
	;
BAC	D S4^cTN8023  ; vakken 71 en 72
	; Opnieuw berekenen controletotaal
BAD	S CONTR=$$CONTR^cTN8020(UI1BA,.VAK,INHBA)
BAZ	Q
	;
BE(UI1BA,UI1BAD)	; Berekenen BTW-eenheid
	; Input: UI1BA: UI1 van de BTW-aangifte
	;        UI1BAD: UI1's van BA van de deelnemende vennootschappen
	N UREF,UI1,UI1Q,INH,INHBA,B,KW,MAAND,JAAR,BVAK
	S $ZT="TRAP^cAN000"
	K VAK
	S UREF=$P($$REF^cAFA10(.Q,"BA.DET"),D)
	; Aflopen UI1's BA van de deelnemende vennootschappen
BEA	S UI1Q=$P(UI1BAD,U),UI1BAD=$P(UI1BAD,U,2,$L(UI1BAD,U)) I '$L(UI1Q) G BEY
	S UI1=UI1Q_" "
BEB	S UI1=$O(@UREF)
	I $P(UI1," ")'=UI1Q G BEA
	S INH=^(UI1,0)
	S $P(VAK($P(INH,D,2)),D)=$P($G(VAK($P(INH,D,2))),D)+$P(INH,D,5)
	S $P(VAK($P(INH,D,2)),D,2)=$P($G(VAK($P(INH,D,2))),D,2)+$P(INH,D,6)
	G BEB
	; Berekenen controletotaal voor BTW-eenheid
BEY	K BVAK
	S I1=""
	F  S I1=$O(VAK(I1)) Q:I1=""  S BVAK(I1)=$P(VAK(I1),D,2)
	S CONTR=$$CONTR^cTN80200(.Q,UI1BA,"",.BVAK,"")
BEZ	Q
	;
CONTR(UI1BA,VAK,INHBA)	; Herberkenen controletotaal
	; Input: UI1BA: intern nr. BA
	; 	VAK  : tabel met vakken uit de BTW-aangifte
	; 	INHBA: tabel met gegevens uit BA
	; Output: nieuw controlegetal
	; 
	N KW,BP2,MAAND,JAAR,UREF,UI1,INH,B
	S $ZT="TRAP^cAN000"
	S CONTR=""
	I UI1BA="" G CONTRZ
	; Ophalen gegevens BTW-aangifte
	I '$L($G(INHBA)) S INHBA=$$SIGN^cAFA1("BA",UI1BA,0)
	; BTW-nummer
	S $P(B(1),D,7)=$P(INHBA,D,5)
	; Aannvraag om terugbetaling
	S $P(B(2),D,7)=$P(INHBA,D,14)
	; Aanvraag om betaalformulier
	S $P(B(2),D,8)=$P(INHBA,D,15)
	; Opzetten variablen ivm kwartaal, maand en jaar
	S KW=$P(INHBA,D,2)
	; Bepalen einde boekingsmaand
	S BP2=$P(INHBA,D)
	I $L(KW) S BP2=$P(KW,".")_"."_$TR($J($P(KW,".",2)*3,2)," ",0)
	I $L(KW) S KW=+($P(KW,".",2))
	S MAAND(1)="",MAAND(2)="" F I=1:1:4 S JAAR(I)=$E(BP2,I)
	I 'KW S MAAND(1)=$E(BP2,6),MAAND(2)=$E(BP2,7)
	; Indien geen vakken werden doorgegeven: ophalen vakken
	I $O(VAK(""))'="" G CONTRB
	S UREF=$P($$REF^cAFA10(.Q,"BA.DET"),D)
	S UI1=UI1BA_" "
CONTRA	S UI1=$O(@UREF)
	I $P(UI1," ")'=UI1BA G CONTRB
	S INH=^(UI1,0)
	S VAK($P(INH,D,2))=$G(VAK($P(INH,D,2)))+$P(INH,D,6)
	G CONTRA
CONTRB	S CONTR=$$CONTR^cTN8025(KW,.MAAND,.JAAR,.B,.VAK)
CONTRZ	Q CONTR
	;
EXP(UI1BA,PC,FILE)	; Exporteren Belgische BTW-aangifte
	; Input: UI1BA: UI1 van de BTW-aangifte
	; 	PC   : postcode vennootschap
	; 	FILE : pad + file naar waar file moet geexporteerd worden
	N INHBA,KW,BP2,MAAND,JAAR,VAK,B,UREF,UI1,INH
	S $ZT="TRAP^cAN000"
	; Ophalen gegevens BTW-aangifte
	S INHBA=$$SIGN^cAFA1("BA",UI1BA,0)
	I $$BM^cTN801($P(INHBA,D),$P(INHBA,D,2))>2010,$$DC^cAFD1(DT)<20100205 S OK="0\"_$P($T(@("T1"_QT)),U,2) G EXPZ   ; KU : 16.11.09 : aangifte van 2010 pas vanaf 05.02.10
	; Opzetten variablen ivm kwartaal, maand en jaar
	S KW=$P(INHBA,D,2)
	; Bepalen einde boekingsmaand
	S BP2=$P(INHBA,D)
	I $L(KW) S BP2=$P(KW,".")_"."_$TR($J($P(KW,".",2)*3,2)," ",0)
	I $L(KW) S KW=+($P(KW,".",2))
	S MAAND(1)="",MAAND(2)="" F I=1:1:4 S JAAR(I)=$E(BP2,I)
	I 'KW S MAAND(1)=$E(BP2,6),MAAND(2)=$E(BP2,7)
	; BTW-nr, naam vennootschap, adres, postcode, gemeente
	F I=2:1:5 S $P(B(1),D,I)=$P(INHBA,D,I+4)
	S $P(B(1),D,5)=" "_$P(B(1),D,5)
	; BTW-nummer
	S $P(B(1),D,7)=$P(INHBA,D,5)
	; Naam ondertekenaar
	S $P(B(1),D,9)=$P(INHBA,D,10)
	; Functie ondertekenaar
	S $P(B(1),D,12)=$P(INHBA,D,11)
	; Telefoon ondertekenaar
	S $P(B(1),D,13)=$P(INHBA,D,12)
	; E-mail ondertekenaar
	S $P(B(1),D,14)=$P(INHBA,D,13)
	; Datum
	S $P(B(1),D,15)=$P(INHBA,D,4)
	; Herziening vak 61
	S $P(B(2),D)=$$SIG^cAFA1("BA.DET",UI1BA_" "_61,106)
	; Herziening vak 62
	S $P(B(2),D,2)=$$SIG^cAFA1("BA.DET",UI1BA_" "_62,106)
	; Voorschot vak 91
	S $P(B(2),D,3)=$$SIG^cAFA1("BA.DET",UI1BA_" "_91,106)
	; BTW-bankkosten
	S $P(B(2),D,4)=$P("\S\",D,$P(INHBA,D,16)+1)
	; Aanvraag om terugbetaling
	S $P(B(2),D,7)=$P(INHBA,D,14)
	; Aanvraag van betaalformulier
	S $P(B(2),D,8)=$P(INHBA,D,15)
	; Opvullen VAK met gegevens BTW-aangifte
	S UREF=$P($$REF^cAFA10(.Q,"BA.DET"),D)
	S UI1=UI1BA_" "
EXPB	S UI1=$O(@UREF)
	I $P(UI1," ")'=UI1BA G EXPY
	S INH=@UREF@(0)
	S VAK($P(INH,D,2))=$P(INH,D,6)
	G EXPB
EXPY	S OK=$$VB^cTN8026(KW,.JAAR,.MAAND,PC,FILE,.B,.VAK)
EXPZ	Q OK
	;
ZZ	; 16.10.08 - 14 u 11 * V9.04