vhEMAIL2 ;EMail [ 08/29/97  2:58 PM ]
 ;
SELECT(Type,Ref,EMAdres) 
 ;Type (M,L,K) = (Manueel, Leverancier, Klant)
 New R,OEMAdres
 Set Type=$G(Type,"M"),Ref=$G(Ref),(EMAdres,OEMAdres)=$G(EMAdres)
 If EMAdres="" Do
 .If $L(Type)>1 Set R=$$KONTAKT(Type,Ref),Type=$P(R,";"),Ref=$P(R,";",2)
 .If Type="M",EMAdres="" Set EMAdres=$$MANUEEL("M","",EMAdres)
 .Set:Type="L" EMAdres=$$PERSOON("L",Ref,$$LEVERANC(Ref,EMAdres))
 .Set:Type="K" EMAdres=$$PERSOON("K",Ref,$$KLANT(Ref,EMAdres))
 Set EMAdres=$$LIST(EMAdres,OEMAdres)
 Quit EMAdres
 ;
LIST(EMAdres,OEMAdres) 
 New I,R,LD,IEMAdres
 Do STORE^vhTERMINA()
 For I=1:1:$L(EMAdres,";") Do
 .Quit:$P(EMAdres,";",I)=""
 .Quit:$D(IEMAdres($P(EMAdres,";",I)))
 .Set IEMAdres($P(EMAdres,";",I))=""
 .Set EMAdres($O(EMAdres(""),-1)+1)=$P(EMAdres,";",I)
 Do INIT^vhLIST("EMAIL","SELECT",.LD)
 Do WRITE^vhLIST(.LD)
 For  Set Type=$$SCROLL^vhLIST(.LD) Quit:Type="O"  Do  Quit:Type="A"
 .If Type="A" Set EMAdres=OEMAdres Quit
 .If Type="V" Do  Quit
 ..Quit:'$D(EMAdres(LD("SELECT")))
 ..Kill IEMAdres(EMAdres(LD("SELECT")))
 ..Do DELETE^vhLISTE(.LD)
 .If Type="M" Set R=$$MANUEEL(Type) Quit:R=""
 .If Type="K" Set R=$$KONTAKT("KL","") Quit:"-"[R  Do
 ..Set Type=$P(R,";"),Ref=$P(R,";",2)
 ..Set:Type="L" R=$$LEVERANC(Ref),R=$$PERSOON("L",Ref,R)
 ..Set:Type="K" R=$$KLANT(Ref),R=$$PERSOON("K",Ref,R)
 .For I=1:1:$L(R,";") Do
 ..Quit:$P(R,";",I)=""
 ..Quit:$D(IEMAdres($P(R,";",I)))
 ..Set IEMAdres($P(R,";",I))=""
 ..Do NIEUW^vhLISTE(.LD,$P(R,";",I))
 If Type="O" Do
 .Set EMAdres=""
 .For I=1:1 Quit:'$D(EMAdres(I))  Set EMAdres=EMAdres_";"_EMAdres(I)
 .Set $E(EMAdres)=""
 Do REFRESH^vhTERMINA()
 Quit EMAdres
 ;
KONTAKT(Type,Ref) 
 New Kontakt
 Do STORE^vhTERMINA()
 Set Kontakt=$$SELECT^KONTAKT(Type,"",Ref,"","","-")
 Do REFRESH^vhTERMINA()
 Quit Kontakt
 ;
PERSOON(Type,Ref,R) 
 New Optie
 Set R=$G(R)
 If $L(R) For I=1:1 Quit:$P(R,";",I)=""  Set Optie("BEFORE",I)="`````"_$P(R,";",I)
 Set Optie("AUTOSEL")=1,Optie("AANSPR")=0,Optie("CASE")="L",Optie("CONNECT")="E",Optie("PIECE")=6
 Set Optie("MULTI")="MS",Optie("FILTER")=1,Optie("SELECT")=R
 Set R=$$SELECT^PERS(Type,Ref,.Optie)
 Quit R
 ;
MANUEEL(Type,Ref,EMAdres) 
 New %SC
 Do STORE^vhTERMINA()
 Set Type=$G(Type),Ref=$G(Ref),EMAdres=$G(EMAdres)
 Do FIELD^vhScherm("EMAIL",$S(Type="M":"MANUEEL",Type="L":"LEVERANC",Type="K":"KLANT",1:""))
 Do REFRESH^vhTERMINA()
 Quit EMAdres
 ;
LEVERANC(LEVNr,EMAdres) 
 Do STORE^vhTERMINA()
 Set LEVNr=$G(LEVNr),EMAdres=$G(EMAdres)
 Set:'LEVNr LEVNr=$P($$SELECT^KONTAKT("L",""),";",2)
 If LEVNr Do
 .Set EMAdres=$$EMADRES("L",LEVNr,EMAdres)
 Do REFRESH^vhTERMINA()
 Quit EMAdres
 ;
KLANT(KLNr,EMAdres) 
 Do STORE^vhTERMINA()
 Set KLNr=$G(KLNr),EMAdres=$G(EMAdres)
 Set:'KLNr KLNr=$P($$SELECT^KONTAKT("K",""),";",2)
 If KLNr Do
 .Set FP=2101
 .Write @F,@F1
 .Set EMAdres=$$EMADRES("K",KLNr,EMAdres)
 Do REFRESH^vhTERMINA()
 Quit EMAdres
 ;
EMADRES(Type,Kontakt,EMAdres) 
 New I,R,Count,Rubriek,Select,sFmt,Global,IGlobal,Titel,Position
 Do STORE^vhTERMINA()
 Set Global=$S(Type="K":"KL",Type="L":"LE",1:""),IGlobal=$S(Type="K":"K1",Type="L":"L1",1:"")
 Set EMAdres=$G(EMAdres)
 Set Titel="E-Mail adres "
 Set Titel=Titel_$S(Type="K":"klant",Type="L":"leverancier",1:"")_" "
 Set Titel=Titel_$P(@("^"_Q_Global_"(@(""^""_Q_IGlobal_""(Kontakt)""),0)"),D,2)
 Set sFmt="^RES(""KONTAKT"",""LD"",""EMAILADRES"")"
 Set Count=0,Select=""
 Set I=100
 For  Set I=$O(@("^"_Q_Global_"(0,I)")) Quit:I=""  Do
 .Set Rubriek=@("^"_Q_Global_"(0,I)"),R=$P(Rubriek,";",16)
 .Quit:"\319\"'[(D_R_D)
 .Set R=$P(@("^"_Q_Global_"(@(""^""_Q_IGlobal_""(Kontakt)""),R\100-1)"),D,R#100) Quit:R=""
 .Set Count=Count+1
 .Set EMAdres(Count)=Count_"`"_$E($P(Rubriek,";"))_$$LOCASE^vhRtn1($E($P(Rubriek,";"),2,99))_"`"_R
 .If R=EMAdres,'Select Set Select=Count
 Set Position=12-(Count\2)_";23"
 Set R=$$WILD^vhPOPUP(Position,"AO1L-",Titel,.EMAdres,$G(Select))
 If R Do
 .Set R=$P(EMAdres(R),"`",3)
 .Quit:";"_EMAdres_";"[(";"_R_";")
 .Set:$L(EMAdres) EMAdres=EMAdres_";" Set EMAdres=EMAdres_R
 Do REFRESH^vhTERMINA()
 Quit EMAdres
 ;