vhR
 Quit
 
 ; Druk een set routines af
A
 Write !,"LVH afdrukken routines",!
 New %JO,Routine
 Set %JO=$J#256
 Kill ^UTILITY(%JO)
 Do ^%RSET
 If $D(^UTILITY(%JO)) Do
 . Set Routine=0
 . For  Set Routine=$O(^UTILITY(%JO,Routine)) Quit:Routine=""  Do a(Routine)
 . Kill ^UTILITY(%JO)
 Quit
 
 ; Druk een routine af
a(Routine)
 New X,Device
 Write !,"Routine: ",Routine,?25,"--> "
 If $D(^ROUTINE(Routine)) Do
 . Set Device="|PRN|\\NOTES01\LISTING"
 . Set X="Xecute X(1)",X(1)="ZL @Routine Print"
 . Open Device
 . Use Device
 . Xecute X
 . Write #
 . Close Device
 . Write "afgedrukt"
 Else  Write "bestaat niet in ",$ZU(5)
 Quit
 
 ; Vergelijk een set routines
V
 Write !,"LVH vergelijken routines",!
 New %JO,Routine
 Set %JO=$J#256
 Kill ^UTILITY(%JO)
 Do ^%RSET
 If $D(^UTILITY(%JO)) Do
 . Set Routine=0
 . For  Set Routine=$O(^UTILITY(%JO,Routine)) Quit:Routine=""  Do v(Routine,1)
 . Kill ^UTILITY(%JO)
 Quit
 
 ; Vergelijk een routine
v(Routine,Bevestig)
 New I,R,JournalRef,DevSize,REMSize,DevLines,REMLines,DevCompilDate,REMCompilDate
 Write !,"Routine: ",Routine,?20,"--> "
 If $D(^ROUTINE(Routine)) Do
 . Set JournalRef="REM-ADMIN1"
 . If $D(^|JournalRef|ROUTINE(Routine)) Do
 .. Set DevSize=$G(^ROUTINE(Routine,0,"SIZE")),REMSize=$G(^|JournalRef|ROUTINE(Routine,0,"SIZE"))
 .. If DevSize=REMSize Do
 ... Set DevLines=$G(^ROUTINE(Routine,0,0)),REMLines=$G(^|JournalRef|ROUTINE(Routine,0,0))
 ... If DevLines=REMLines Do
 .... Set FirstLine=0
 .... For I=1:1 Set R=$G(^ROUTINE(Routine,0,I)) Quit:R=""  Quit:R'=^|JournalRef|ROUTINE(Routine,0,I)
 .... If I=1 Do
 ..... Set FirstLine=1
 ..... For I=I+1:1 Set R=$G(^ROUTINE(Routine,0,I)) Quit:R=""  Quit:R'=^|JournalRef|ROUTINE(Routine,0,I)
 .... If R="" Do
 ..... If 'FirstLine Do
 ...... Set DevCompilDate=$$FMTDT^vhLib.DataTypes($G(^ROUTINE(Routine,0)))
 ...... Set REMCompilDate=$$FMTDT^vhLib.DataTypes($G(^|JournalRef|ROUTINE(Routine,0)))
 ...... If DevCompilDate=REMCompilDate Write "ok" Set:$D(Bevestig) Bevestig=0
 ...... Else  Write "compilatie ",DevCompilDate," - ",REMCompilDate Set:$D(Bevestig) Bevestig=0
 ..... Else  Write "enkel de eerste lijn verschilt" Set:$D(Bevestig) Bevestig=0
 .... Else  Write "niet ok" Set:$D(Bevestig) Bevestig=1
 ... Else  Write "aantal lijnen ",DevLines," - ",REMLines Set:$D(Bevestig) Bevestig=1
 .. Else  Write "routine omvang ",DevSize," - ",REMSize Set:$D(Bevestig) Bevestig=1
 . Else  Write "bestaat niet in ",JournalRef Set:$D(Bevestig) Bevestig=1
 Else  Write "bestaat niet in ",$ZU(5) Set:$D(Bevestig) Bevestig=1
 If $G(Bevestig) Write @FCH Read !,"^^^ ",R Write @FCS
 Quit