Index: TECH/MethodDefinition.cls.xml
===================================================================
diff -u
--- TECH/MethodDefinition.cls.xml	(revision 0)
+++ TECH/MethodDefinition.cls.xml	(revision 350)
@@ -0,0 +1,192 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="TECH.MethodDefinition">
+<Super>%RegisteredObject</Super>
+
+<Property name="UsedClassNames">
+<Type>%String</Type>
+<Collection>list</Collection>
+<Private>1</Private>
+</Property>
+
+<Property name="UsedRoutineNames">
+<Type>%String</Type>
+<Collection>list</Collection>
+<Private>1</Private>
+</Property>
+
+<Property name="MethodDefintion">
+<Type>%Dictionary.MethodDefinition</Type>
+<Private>1</Private>
+</Property>
+
+<Method name="Instance">
+<ClassMethod>1</ClassMethod>
+<ReturnType>TECH.MethodDefinition</ReturnType>
+<Implementation><![CDATA[	quit ..%New()
+]]></Implementation>
+</Method>
+
+<Method name="GetUsedRoutines">
+<FormalSpec>MethodDefinition:%MethodDefinition</FormalSpec>
+<ReturnType>%ListOfDataTypes</ReturnType>
+<Implementation><![CDATA[
+	set ..MethodDefintion = MethodDefinition
+	do ..UsedRoutineNames.Clear()
+	
+	do ..AddUsedRoutineNamesFromImplementation()
+	
+	quit ..UsedRoutineNames
+]]></Implementation>
+</Method>
+
+<Method name="GetUsedClassNames">
+<FormalSpec>MethodDefinition:%MethodDefinition</FormalSpec>
+<ReturnType>%ListOfDataTypes</ReturnType>
+<Implementation><![CDATA[
+	set ..MethodDefintion = MethodDefinition
+	do ..UsedClassNames.Clear()
+	
+	do ..AddUsedClassFromResultType()
+	do ..AddUsedClassesFromFormalSpec()
+	do ..AddUsedClassesFromImplementation()
+	
+	quit ..UsedClassNames
+]]></Implementation>
+</Method>
+
+<Method name="AddUsedRoutineNamesFromImplementation">
+<Private>1</Private>
+<Implementation><![CDATA[
+	#dim Implementation As %Stream = ..MethodDefintion.Implementation
+	while 'Implementation.AtEnd {
+		do ..AddUsedRoutinesFromImplementationLine(Implementation.ReadLine())
+	}
+]]></Implementation>
+</Method>
+
+<Method name="AddUsedRoutinesFromImplementationLine">
+<FormalSpec>Line:%String</FormalSpec>
+<Implementation><![CDATA[
+	set itPieces = ##class(TECH.PiecesIterator).%New(Line," ")
+	while itPieces.HasNext() {
+		#dim Piece As %String = $zstrip(itPieces.Next(),"*C")
+		#dim Position As %Integer = itPieces.Key()
+		#dim LoweredPiece = ##class(TECH.StringUtils).ToLower(Piece)
+		if ( Piece["^" ) { 
+			if ( ##class(TECH.StringUtils).StartsWith(Piece,"$$") ) {
+				do ..AddRoutineNameIfNeeded(..ParseRoutineNameFromStatement(Piece))
+			} else {
+				#dim PreviousStatement As %String = $zstrip(##class(TECH.StringUtils).ToLower($piece(Line," ",Position-1)),"*C")
+				if ##class(TECH.StringUtils).StartsWith(PreviousStatement,"do") {
+					do ..AddRoutineNameIfNeeded(..ParseRoutineNameFromStatement(Piece))
+				}
+			}
+		}
+	}
+]]></Implementation>
+</Method>
+
+<Method name="ParseRoutineNameFromStatement">
+<FormalSpec>Statement:%String</FormalSpec>
+<Private>1</Private>
+<ReturnType>%String</ReturnType>
+<Implementation><![CDATA[	quit $piece($piece(Statement,"^",2),"(",1)
+]]></Implementation>
+</Method>
+
+<Method name="AddUsedClassesFromImplementation">
+<Private>1</Private>
+<Implementation><![CDATA[
+	#dim Implementation As %Stream = ..MethodDefintion.Implementation
+	while 'Implementation.AtEnd {
+		do ..AddUsedClassesFromImplementationLine(Implementation.ReadLine())
+	}
+]]></Implementation>
+</Method>
+
+<Method name="AddUsedClassesFromImplementationLine">
+<FormalSpec>Line:%String</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	#dim ClassName As %String = ""
+	if Line["##class(" {
+		set itPieces = ##class(TECH.PiecesIterator).%New(Line,"##class(")
+		while itPieces.HasNext() {
+			set ClassName = $piece(itPieces.Next(),")",1)
+			do ..AddClassnameIfNeeded(ClassName)
+		}
+	}
+	
+	set itPieces = ##class(TECH.PiecesIterator).%New(Line," ")
+	while itPieces.HasNext() {
+		#dim Piece As %String = itPieces.Next()	
+		#dim LoweredPiece = ##class(TECH.StringUtils).ToLower(Piece)
+		
+		if ##class(TECH.StringUtils).StartsWith(LoweredPiece,"##class(") {
+			set ClassName = $piece($piece(Piece,"(",2),")")
+			do ..AddClassnameIfNeeded(ClassName)
+		} elseif Piece["_" {
+			set ClassName = $replace(Piece,"_",".")
+			set ClassName = $piece(ClassName,"->",1)
+			set ClassName = $piece(ClassName,"""",1)
+			do ..AddClassnameIfNeeded(ClassName)
+		}
+		elseif Piece["." {
+			do ..AddClassnameIfNeeded(Piece)
+		}
+	}
+]]></Implementation>
+</Method>
+
+<Method name="AddUsedClassFromResultType">
+<Private>1</Private>
+<Implementation><![CDATA[	do ..AddClassnameIfNeeded(..MethodDefintion.ReturnType)
+]]></Implementation>
+</Method>
+
+<Method name="AddUsedClassesFromFormalSpec">
+<Private>1</Private>
+<Implementation><![CDATA[
+	set itParams = ##class(TECH.PiecesIterator).%New(..MethodDefintion.FormalSpec,",")
+	while itParams.HasNext() {
+		#dim ResultType As %String = ..GetResultTypeFromFormalSpecParameter(itParams.Next())
+		do ..AddClassnameIfNeeded(ResultType)
+	}
+]]></Implementation>
+</Method>
+
+<Method name="AddRoutineNameIfNeeded">
+<FormalSpec>RoutineName:%String</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	
+	#dim Needed As %Boolean = '##class(TECH.StringUtils).StartsWith(RoutineName,"%")
+	if Needed set Needed = ##class(%Routine).%ExistsId(RoutineName_".mac")
+	if Needed set Needed = '..UsedRoutineNames.Find(RoutineName)
+	if Needed do ..UsedRoutineNames.Insert(RoutineName)
+]]></Implementation>
+</Method>
+
+<Method name="AddClassnameIfNeeded">
+<FormalSpec>ClassName:%String</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	#dim Needed As %Boolean = ##class(TECH.ClassUtils).IsOurs(ClassName)
+	if Needed set Needed = '..UsedClassNames.Find(ClassName)
+	
+	if Needed do ..UsedClassNames.Insert(ClassName)
+]]></Implementation>
+</Method>
+
+<Method name="GetResultTypeFromFormalSpecParameter">
+<FormalSpec>Param:%String</FormalSpec>
+<Private>1</Private>
+<ReturnType>%String</ReturnType>
+<Implementation><![CDATA[	quit $piece(Param,":",2)
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>