Index: APPS/VKP/Order/VerzendMaatwerkDirectControleur.cls.xml
===================================================================
diff -u
--- APPS/VKP/Order/VerzendMaatwerkDirectControleur.cls.xml	(revision 0)
+++ APPS/VKP/Order/VerzendMaatwerkDirectControleur.cls.xml	(revision 38098)
@@ -0,0 +1,124 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="APPS.VKP.Order.VerzendMaatwerkDirectControleur">
+<IncludeCode>BL.Derde.LevSpecifiek</IncludeCode>
+<Super>TECH.PubSub.EventHandler</Super>
+
+<Parameter name="AantalWerkDagen">
+<Description>
+Vandaag op transport en morgen leveren = Aantalwerkdagen=1, maar er mag 1 dag extra omdat DI1 in de namiddag wordt geproduceerd.</Description>
+<Default>2</Default>
+</Parameter>
+
+<Parameter name="MaxAantalLades">
+<Default>15</Default>
+</Parameter>
+
+<Parameter name="GewensteVerzendwijze">
+<Default>DI1</Default>
+</Parameter>
+
+<Method name="CheckAll">
+<Description>
+d ##class(APPS.VKP.Order.VerzendMaatwerkDirectControleur).%New().CheckAll()</Description>
+<Implementation><![CDATA[
+
+	Set ORDNr=""
+	For  Set ORDNr=$O(^KO1(ORDNr)) Quit:ORDNr=""  Do
+	. Set KLNr=$P(^KO1(ORDNr,"F"),"\")
+	. Set Hoofding=$G(^KOD(KLNr,"F",ORDNr,1))
+	. Set Verzendwijzen=$P(Hoofding,"\",7)
+	. Quit:Verzendwijzen'[..#GewensteVerzendwijze
+	. Write KLNr," ", ORDNr, " ",..ControleViaOrder(ORDNr),!
+]]></Implementation>
+</Method>
+
+<Method name="ControleViaToelevering">
+<Description>
+w ##class(APPS.VKP.Order.VerzendMaatwerkDirectControleur).%New().ControleViaToelevering(247031)</Description>
+<FormalSpec>TOENr:%String</FormalSpec>
+<ReturnType>%String</ReturnType>
+<Implementation><![CDATA[
+	Set KLNr=$P($G(^KTO($$$LevHalux,TOENr,1)),"\",8)
+	Quit:'KLNr "GEEN KLANT IN TOELEVERING"
+	Set ORDNr=$P($G(^KTO($$$LevHalux,TOENr,1)),"\",7)
+	Quit:'ORDNr "GEEN ORDER IN TOELEVERING"
+	
+	Quit ..ControleViaOrder(ORDNr)
+]]></Implementation>
+</Method>
+
+<Method name="ControleViaOrder">
+<FormalSpec>ORDNr:%String</FormalSpec>
+<ReturnType>%String</ReturnType>
+<Implementation><![CDATA[
+	Set KLNr=$P(^KO1(ORDNr,"F"),"\")
+	Quit:'..ControleerVerzendwijze(KLNr,ORDNr) "FOUTIEVE VERZENDWIJZE"
+	Quit:'..ControleerKredietWaardig(KLNr) "ONVOLDOENDE KREDIET"
+	
+	Quit ..ControleerLijnen(KLNr,ORDNr)
+]]></Implementation>
+</Method>
+
+<Method name="ControleerVerzendwijze">
+<FormalSpec>KLNr:%String,ORDNr:%String</FormalSpec>
+<ReturnType>%String</ReturnType>
+<Implementation><![CDATA[
+	Set Hoofding=$G(^KOD(KLNr,"F",ORDNr,1))
+	Set Verzendwijzen=$P(Hoofding,"\",7)
+	; Alleen die klanten die ELKE dag met DI1 wordt geselecteerd
+	; dus "DI1;3" en "DI1;2`DI1;4" gelden niet
+	Quit Verzendwijzen=..#GewensteVerzendwijze
+]]></Implementation>
+</Method>
+
+<Method name="ControleerKredietWaardig">
+<FormalSpec>KLNr:%String</FormalSpec>
+<Implementation><![CDATA[
+	/// Controle of er vervallen facturen zijn
+	Set KredietWaardig=$$WAARDIG^KREDIET(KLNr,"D")
+	Quit $P(KredietWaardig,"\")
+]]></Implementation>
+</Method>
+
+<Method name="ControleerLijnen">
+<FormalSpec>KLNr:%String,ORDNr:%String</FormalSpec>
+<Implementation><![CDATA[
+	Set Hoofding=$G(^KOD(KLNr,"F",ORDNr,1))
+	Set OLNr=$O(^KOD(KLNr,"F",ORDNr,99)) 
+	Set SomVanAantal=0
+	Set FoutCode=""
+	Set MaximaleLeverdag=$S($P(Hoofding,"\",28):$H+99,1:$$CALCDATE^vhLib.DataTypes($H,"A",..#AantalWerkDagen)) ; Indien ASAP ingesteld dan 99 dagen
+	Set MemGenTyp=""
+	While (OLNr'="") && (FoutCode="")
+	{
+		Set Lijn=$G(^KOD(KLNr,"F",ORDNr,OLNr))
+		If $P($P(Lijn,"\",17),"#")'="KF11" ; geen tekstlijn
+		{
+			Set:$P($P(Lijn,"\",17),"#")'="KF0" FoutCode="Geen product lijn"
+
+			Set Datum=$P(Lijn,"\",25)
+			Set:Datum>MaximaleLeverdag FoutCode="Later leveren "_Datum
+
+			Set SomVanAantal=SomVanAantal+$P(Lijn,"\",3)
+			Set:SomVanAantal>..#MaxAantalLades FoutCode="Groot aantal "_SomVanAantal	
+
+			Set PRNr=$P(Lijn,"\",2)
+			Set GenTyp=$P($$GENTYP^HAD(PRNr),"\",1,2)
+			Set GenTyp=$S(GenTyp="":"*",1:GenTyp)
+			Set:$P(GenTyp,"\")'?1(1"TBX",1"LBX",1"TAO") FoutCode="GenType geen lade "_GenTyp
+			
+			Set:(MemGenTyp'="")&(MemGenTyp'=GenTyp) FoutCode="Verschillend GenType "_MemGenTyp_"="_GenTyp
+			Set MemGenTyp=GenTyp
+			
+			;w ORDNr," ",OLNr," ",PRNr," ",$P(^KPR(PRNr,0),"\")," ",$$EXTDATE^vhLib.DataTypes(Datum)," ",SomVanAantal," ",GenTyp,!
+		}
+		Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) 
+	}
+	Quit FoutCode
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>