Index: DOM/PM/Maatwerk/Syncs/DotNet/MaatwerkCalculator/impl/Halffabs.cls.xml
===================================================================
diff -u
--- DOM/PM/Maatwerk/Syncs/DotNet/MaatwerkCalculator/impl/Halffabs.cls.xml	(revision 0)
+++ DOM/PM/Maatwerk/Syncs/DotNet/MaatwerkCalculator/impl/Halffabs.cls.xml	(revision 62556)
@@ -0,0 +1,188 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="DOM.PM.Maatwerk.Syncs.DotNet.MaatwerkCalculator.impl.Halffabs">
+<Super>TECH.RegisteredObject</Super>
+
+<Property name="Connectie">
+<Type>%SQLGatewayConnection</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="Logger">
+<Type>vhLib.Logger</Type>
+<Private>1</Private>
+</Property>
+
+<Method name="%OnNew">
+<ReturnType>%Library.Status</ReturnType>
+<Implementation><![CDATA[
+	Set ..Connectie = ##class(%SQLGatewayConnection).%New()
+	Set ..Logger = ##class(vhLib.Logger).%New("DOTNET sync")
+ 	Set sc = ..Connectie.GetConnection("DOTNET_TMP")
+	Do ##class(TECH.Exceptions.StatusException).ThrowIndienNietOK(sc)
+	Quit $$$OK
+]]></Implementation>
+</Method>
+
+<Method name="SyncHalffabs">
+<FormalSpec>Halffabs:%ListOfObjects</FormalSpec>
+<Implementation><![CDATA[
+	// We veronderstellen dat alle halffabs tot eenzelfde kenmerkenset behoren
+	// Daaruit volgt dat de TypeCode en de Rol van alle halffabs uit de lijst
+	// hetzelfde zijn.
+	
+	Do ..Logger.Debug("DotnetSync [HalffabSyncer]", "Start sync")
+	
+	#dim UnId As %String
+	#dim Count As %Integer = 0
+	#dim Rolstukje As %String
+	#dim TypeCode As %String
+	
+	Set It = ##class(TECH.ListIterator).%New(Halffabs)
+	While (It.HasNext()) {
+		#dim Halffab As DOM.PM.Maatwerk.Calc.HF.Halffab = It.Next()
+		
+		Set Count = Count + 1
+		If (Count = 1) {
+			Set UnId = Halffab.GemaaktVoorKenmerkenSetID
+			#dim Klassenaam As %String = Halffab.%ClassName(1)
+			Set Rolstukje = ##class(TECH.StringUtils).GetLastPart(Klassenaam, ".")
+			Set TypeCode = $Piece(Klassenaam, ".", 7)
+		} Else {
+			If (Halffab.GemaaktVoorKenmerkenSetID '! UnId) {
+				Do ..Logger.Error("DotnetSync [HalffabSyncer]", "Halffab UnId wijkt af:" _ Halffab.GemaaktVoorKenmerkenSetID)
+				Throw ##class(TECH.Exceptions.InvalidInputException).%New("Halffabsyncer: alle halffabs moeten tot dezelfde kenmerkenset behoren")
+			}
+		}
+		Do ..Logger.Debug("DotnetSync [HalffabSyncer]", "Schrijf halffab UnId=" _ Halffab.GemaaktVoorKenmerkenSetID _ ": " _ Halffab.GeefOmschrijvingVoorDocs())
+		Do ..SchrijfHalffab(Halffab, Klassenaam, Rolstukje, TypeCode)
+	}
+	Do ..CommitNieuweVersie(UnId, Rolstukje, TypeCode)
+	Do ..Logger.Debug("DotnetSync [HalffabSyncer]", "Eind sync")
+]]></Implementation>
+</Method>
+
+<Method name="SchrijfHalffab">
+<FormalSpec>Halffab:DOM.PM.Maatwerk.Calc.HF.Halffab,Klassenaam:%String,Rolstukje:%String,TypeCode:%String</FormalSpec>
+<Implementation><![CDATA[
+	#dim PropertyNaam, Waarde As %String
+	Set Klasse = ##class(%Dictionary.CompiledClass).%OpenId(Klassenaam)
+	
+	// Eerste ronde: properties van de basisklasse
+	#dim IntoStuk As %String = "INSERT INTO " _ ..GeefBasistabelNaam() _ " (ProductID,MyDiscriminator,Versie"
+	#dim ValuesStuk As %String = "VALUES ('" _ Halffab.ProductID _ "','" _ TypeCode _ "_" _ Rolstukje _ "'," _ 1
+	Set PropertiesIterator = ##class(TECH.ListIterator).%New(Klasse.Properties)
+	while (PropertiesIterator.HasNext()) {
+		#dim Property As %Dictionary.CompiledProperty = PropertiesIterator.Next()
+		Set PropertyNaam = Property.Name
+		Continue:((PropertyNaam = "KlasseName") || (PropertyNaam = "ProductID"))
+		If (Property.Origin = "DOM.PM.Maatwerk.Calc.HF.Halffab") {
+			Set PropertyNaam = Property.Name
+			Set Waarde = $zobjproperty(Halffab, PropertyNaam)
+			If (Waarde '= "") {
+				Set IntoStuk = IntoStuk _ "," _ PropertyNaam
+				Set ValuesStuk = ValuesStuk _ ",'" _ Waarde _ "'"
+			}
+		}
+	}
+	Set IntoStuk = IntoStuk _ ") "
+	Set ValuesStuk = ValuesStuk _ "); "
+	
+	#dim Statement As %String = IntoStuk _ ValuesStuk
+	
+	// Tweede ronde: properties van de afgeleide klasse
+	// We gebruiken SCOPE_IDENTITY() voor de foreign key, dit is de autogenerated ID
+	// van de eerste INSERT.  De scope is hier de batch van queries
+	// (2 inserts gescheiden door ;).
+	Set IntoStuk = "INSERT INTO " _ ..GeefRoltabelNaam(Rolstukje, TypeCode) _ " (Id"
+	Set ValuesStuk = "VALUES (SCOPE_IDENTITY()"
+	
+	Set PropertiesIterator = ##class(TECH.ListIterator).%New(Klasse.Properties)
+	while (PropertiesIterator.HasNext()) {
+		Set Property = PropertiesIterator.Next()
+		If (Property.Origin = Klassenaam) {
+			Set PropertyNaam = Property.Name
+			Set Waarde = $zobjproperty(Halffab, PropertyNaam)
+			If (Waarde '= "") {
+				Set IntoStuk = IntoStuk _ ", " _ PropertyNaam
+				Set ValuesStuk = ValuesStuk _ ", '" _ Waarde _ "'"
+			}
+		}
+	}
+	Set IntoStuk = IntoStuk _ ") "
+	Set ValuesStuk = ValuesStuk _ ")"
+	
+	Set Statement = Statement _ IntoStuk _ ValuesStuk
+
+	Do ..VoeruitSql(Statement)
+]]></Implementation>
+</Method>
+
+<Method name="CommitNieuweVersie">
+<FormalSpec>UnId:%String,Rolstukje:%String,TypeCode:%String</FormalSpec>
+<Implementation><![CDATA[
+	// Swap de nieuwe voor de oude.
+	//   1) DELETE de oude op basis van UnId en Versie (in beide db's)
+	//   2) UPDATE versie aan van 1 naar 0 op basis van UnId en Versie = 1
+	// Beide stappen moeten atomair gebeuren, zodat gebruikers van de halffabs ofwel
+	// alle oude records nog zien, ofwel alle nieuwe, maar nooit de toestand zien
+	// zoals die is tussen de delete en de update.
+	// Stap 1 valt uiteen in 2 deletes want er zit blijkbaar geen cascaded delete
+	// in Entity Framework tussen het record van de basisklasse en het record van de
+	// afgeleide klasse.  Zie o.a. 
+	// https://stackoverflow.com/questions/8599617/problems-using-tpt-table-per-type-in-ef-4-2-and-deletion-of-parent-objects
+	#dim Statement As %String
+	
+	Set Statement = "BEGIN TRAN;"
+	// 1) Verwijderen van de oude versie.  We doen hier 2 deletes omdat Entity Framework
+	// voor Table Per Type geen cascaded deletes configureert van het record voor de
+	// basisklasse naar het record van de afgeleide klasse.
+	Set Statement = Statement _ "DELETE s FROM " _ ..GeefRoltabelNaam(Rolstukje, TypeCode) _ " s "_
+		"INNER JOIN " _ ..GeefBasistabelNaam() _ " b on s.Id = b.Id " _
+		"WHERE b.Versie=0 AND b.GemaaktVoorKenmerkenSetID='" _ UnId _ "'; "
+	Set Statement = Statement _ "DELETE FROM " _ ..GeefBasistabelNaam() _
+		" WHERE Versie=0 AND GemaaktVoorKenmerkenSetID='" _ UnId _ "';"
+	// 2) Update de versie
+	Set Statement = Statement _ "UPDATE " _ ..GeefBasistabelNaam()_
+		" set Versie=0 WHERE Versie=1 AND GemaaktVoorKenmerkenSetID='" _ UnId _ "'"
+	Set Statement = Statement _ "; COMMIT TRAN"
+
+	Do ..VoeruitSql(Statement)
+]]></Implementation>
+</Method>
+
+<Method name="GeefBasistabelNaam">
+<Private>1</Private>
+<ReturnType>%String</ReturnType>
+<Implementation><![CDATA[	Quit "dbo.Halffabs"
+]]></Implementation>
+</Method>
+
+<Method name="GeefRoltabelNaam">
+<FormalSpec>Rolstukje:%String,TypeCode:%String</FormalSpec>
+<Private>1</Private>
+<ReturnType>%String</ReturnType>
+<Implementation><![CDATA[
+	// Voorlopig
+	//Quit "dbo.DOM_PM_Maatwerk_Calc_HF_Framework_" _ TypeCode _ "_" _ Rolstukje
+	Quit "dbo." _ TypeCode _ "_" _ Rolstukje
+]]></Implementation>
+</Method>
+
+<Method name="VoeruitSql">
+<FormalSpec>Statement:%String</FormalSpec>
+<ReturnType>%ResultSet</ReturnType>
+<Implementation><![CDATA[
+	Do ..Logger.Debug("DotnetSync [HalffabSyncer]", "SQL: " _ Statement)
+	Set res = ##class(TECH.ResultSet).%New("%DynamicQueryGW:SQLGW")
+    Set sc = res.Prepare(Statement,,..Connectie)
+	Do ##class(TECH.Exceptions.StatusException).ThrowIndienNietOK(sc)
+    Set sc = res.Execute()
+	Do ##class(TECH.Exceptions.StatusException).ThrowIndienNietOK(sc)
+	Quit res
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>
Index: vhDeploy/D20201019xInitHalffabSyncEvent.cls.xml
===================================================================
diff -u
--- vhDeploy/D20201019xInitHalffabSyncEvent.cls.xml	(revision 0)
+++ vhDeploy/D20201019xInitHalffabSyncEvent.cls.xml	(revision 62556)
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="vhDeploy.D20201019xInitHalffabSyncEvent">
+<Super>vhDeploy.Deploy</Super>
+
+<Parameter name="Omschrijving">
+<Type>%String</Type>
+<Default>Init halffabsync event</Default>
+</Parameter>
+
+<Method name="ExecCode">
+<ClassMethod>1</ClassMethod>
+<Implementation><![CDATA[	Do ##class(DOM.PM.Maatwerk.Syncs.DotNet.MaatwerkCalculator.impl.Halffab.EventListener).InitSubscriptions()
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>
Index: DOM/PM/Maatwerk/Syncs/DotNet/MaatwerkCalculator/impl/Halffab/EventListener.cls.xml
===================================================================
diff -u
--- DOM/PM/Maatwerk/Syncs/DotNet/MaatwerkCalculator/impl/Halffab/EventListener.cls.xml	(revision 0)
+++ DOM/PM/Maatwerk/Syncs/DotNet/MaatwerkCalculator/impl/Halffab/EventListener.cls.xml	(revision 62556)
@@ -0,0 +1,27 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="DOM.PM.Maatwerk.Syncs.DotNet.MaatwerkCalculator.impl.Halffab.EventListener">
+<ClassType/>
+<ProcedureBlock>1</ProcedureBlock>
+<Super>TECH.RegisteredObject</Super>
+
+<Method name="SyncHalffabsEventListener">
+<ClassMethod>1</ClassMethod>
+<FormalSpec>Event:TECH.Events.HalffabsGemaaktEvent</FormalSpec>
+<Implementation><![CDATA[
+	Set Syncer = ##class(DOM.PM.Maatwerk.Syncs.DotNet.MaatwerkCalculator.impl.Halffabs).%New()
+	Do Syncer.SyncHalffabs(Event.Data.Halffabs)
+]]></Implementation>
+</Method>
+
+<Method name="InitSubscriptions">
+<ClassMethod>1</ClassMethod>
+<Implementation><![CDATA[
+	Set ModifiedSubscription = ##class(TECH.PubSub.EventSubscription).%New("HalffabsGemaaktEvent","DOM.PM.Maatwerk.Syncs.DotNet.MaatwerkCalculator.impl.Halffab.EventListener","SyncHalffabsEventListener")
+	Do ModifiedSubscription.Save()
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>