Index: APPS/Halux/PPS/MatService/MatUitvoeringInfoBepaler.cls.xml
===================================================================
diff -u
--- APPS/Halux/PPS/MatService/MatUitvoeringInfoBepaler.cls.xml	(revision 0)
+++ APPS/Halux/PPS/MatService/MatUitvoeringInfoBepaler.cls.xml	(revision 66701)
@@ -0,0 +1,174 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="APPS.Halux.PPS.MatService.MatUitvoeringInfoBepaler">
+<Super>TECH.RegisteredObject</Super>
+
+<Property name="ProductieSequentieRepository">
+<Type>APPS.Halux.common.ProductieSequentieRepository</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="ActiviteitGroepRepository">
+<Type>APPS.Halux.PPS.Activiteit.ActiviteitGroepRepository</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="ActivititeitRepository">
+<Type>APPS.Halux.PPS.Activiteit.impl.ActiviteitRepository</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="DocsV1">
+<Type>BL.PPS.TBX.DocsV1</Type>
+<Private>1</Private>
+</Property>
+
+<Method name="%OnNew">
+<FormalSpec>ProductieSequentieRepository:APPS.Halux.common.ProductieSequentieRepository="",ActiviteitGroepRepository:APPS.Halux.PPS.Activiteit.ActiviteitGroepRepository="",ActivititeitRepository:APPS.Halux.PPS.Activiteit.impl.ActiviteitRepository="",DocsV1:BL.PPS.TBX.DocsV1=""</FormalSpec>
+<Private>1</Private>
+<ProcedureBlock>1</ProcedureBlock>
+<ReturnType>%Status</ReturnType>
+<ServerOnly>1</ServerOnly>
+<Implementation><![CDATA[
+	Set ..ProductieSequentieRepository = $$$Inject(ProductieSequentieRepository, ##class(APPS.Halux.common.impl.ProductieSequentieRepository).%New())
+	Set ..ActiviteitGroepRepository = $$$Inject(ActiviteitGroepRepository, ##class(APPS.Halux.PPS.Activiteit.ActiviteitGroepRepository).%New())
+	Set ..ActivititeitRepository = $$$Inject(ActivititeitRepository, ##class(APPS.Halux.PPS.Activiteit.impl.ActiviteitRepository).%New())
+	Set ..DocsV1 = $$$Inject(DocsV1, ##class(BL.PPS.TBX.DocsV1).%New())
+	
+	Quit $$$OK
+]]></Implementation>
+</Method>
+
+<Method name="GeefMatUitvoeringIterator">
+<FormalSpec>BatchId:%Integer,Categorie:APPS.Halux.common.enu.Categorie=""</FormalSpec>
+<ReturnType>TECH.ListIterator</ReturnType>
+<Implementation><![CDATA[
+	Set UitvoeringInfoLijstPerInformatieID = ##class(%ArrayOfObjects).%New()
+
+	If (..IsCategorieOndersteund(Categorie)) {
+		If (Categorie = ##class(APPS.Halux.common.enu.Categorie).Tandembox()) {	
+			Do ..DocsV1.Init(BatchId)		
+		
+			#dim SequentieData As TECH.ResultSet = ..ProductieSequentieRepository.GeefSequentieDataVolgensSequenceVoorBatch(BatchId)
+			While (SequentieData.Next()) {
+				#dim InformatieId As %String = SequentieData.Data("ID")
+				#dim SequentieItem As DS.PPS.TBX.Queue = ..ProductieSequentieRepository.GeefSequentieItem(InformatieId)
+			
+				If (($$$Not(SequentieItem.Status = "PB") && ..DocsV1.MatChk(SequentieItem))) {
+					#dim UitvoeringInfo As APPS.Halux.PPS.Activiteit.impl.common.dto.MattenUitvoeringInfo = ..DocsV1.MatOneUitvoeringInfo(SequentieItem)
+				
+					If $IsObject(UitvoeringInfo) {
+						Do ..VoegToeAanUitvoeringInfoLijstPerInformatieID(UitvoeringInfoLijstPerInformatieID, InformatieId, UitvoeringInfo)
+					}
+				}
+			}		
+		} Else {
+			Set WerklijstItemsUitvoerder = ##class(APPS.Halux.PPS.Activiteit.impl.WerklijstItemsUitvoerder).%New()
+			Set ActieUitvoerder = ##class(APPS.Halux.PPS.impl.AansturingActieVoorActiviteit).%New()
+	
+			#dim ActiviteitGroepNaam As %String = ..GeefActiviteitGroep(Categorie).Naam
+			#dim ActiviteitGroepId = ..GeefActiviteitGroepId(Categorie, ActiviteitGroepNaam)
+	
+			Set GekoppeldeIKMattenActiviteitCode = ##class(APPS.Halux.PPS.Activiteit.impl.GekoppeldeIK.Matten).%New().#Code
+			#dim ActiviteitId = ..GeefActiviteitId(Categorie, ActiviteitGroepId, GekoppeldeIKMattenActiviteitCode)
+	
+			Set ActieUitvoerder.ActiviteitGroepID = ActiviteitGroepId
+			Set ActieUitvoerder.ActiviteitID = ActiviteitId
+	
+			#dim WerklijstItemIdLijst As %ListOfDataTypes = ActieUitvoerder.GeefWerklijstItemIDLijst(BatchId, ActieUitvoerder.GeefReworkFlag())
+			Set UitvoeringInfoLijstPerInformatieID = WerklijstItemsUitvoerder.GeefUitvoeringInfoLijstPerInformatieID(WerklijstItemIdLijst)
+		}
+	} Else {
+		Set Exception = ##class(TECH.Exceptions.InvalidInputException).%New("MatService is niet geïmplementeerd voor Categorie '" _ Categorie _ "'.")
+		Do ##class(TECH.ExceptionHandler).Throw(Exception)
+	}
+		
+	Quit ##class(TECH.ListIterator).%New(UitvoeringInfoLijstPerInformatieID)
+]]></Implementation>
+</Method>
+
+<Method name="IsCategorieOndersteund">
+<FormalSpec>Categorie:APPS.Halux.common.enu.Categorie</FormalSpec>
+<Private>1</Private>
+<ReturnType>%Boolean</ReturnType>
+<Implementation><![CDATA[
+	#dim IsOndersteund As %Boolean = $$$False
+	
+	If ($$$Not(Categorie = "") && ((Categorie = ##class(APPS.Halux.common.enu.Categorie).Tandembox()) || (Categorie = ##class(APPS.Halux.common.enu.Categorie).Legrabox()) || (Categorie = ##class(APPS.Halux.common.enu.Categorie).TAORbox()) || (Categorie = ##class(APPS.Halux.common.enu.Categorie).Merivobox()))) {
+		Set IsOndersteund = $$$True
+	}
+	
+	Quit IsOndersteund
+]]></Implementation>
+</Method>
+
+<Method name="VoegToeAanUitvoeringInfoLijstPerInformatieID">
+<FormalSpec>UitvoeringInfoLijstArray:%ArrayOfObjects,InformatieID:%String,UitvoeringInfo:APPS.Halux.PPS.dto.UitvoeringInfo</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	#dim Lijst As APPS.Halux.PPS.dto.UitvoeringInfoLijst 
+	
+	If $$$Not(UitvoeringInfoLijstArray.IsDefined(InformatieID)) {
+		Do UitvoeringInfoLijstArray.SetAt(##class(APPS.Halux.PPS.dto.UitvoeringInfoLijst).%New(),InformatieID)
+	} 	
+	Set Lijst = UitvoeringInfoLijstArray.GetAt(InformatieID)
+	Do Lijst.Insert(UitvoeringInfo)
+	
+	Quit
+]]></Implementation>
+</Method>
+
+<Method name="GeefActiviteitGroep">
+<FormalSpec>Categorie:APPS.Halux.common.enu.Categorie</FormalSpec>
+<Private>1</Private>
+<ReturnType>APPS.Halux.PPS.Activiteit.ActiviteitGroep</ReturnType>
+<Implementation><![CDATA[
+	#dim ActiviteitGroep As APPS.Halux.PPS.Activiteit.ActiviteitGroep = ""
+	
+	If (Categorie = ##class(APPS.Halux.common.enu.Categorie).Legrabox()) {
+		Set ActiviteitGroep =  ##class(APPS.Halux.PPS.Activiteit.impl.LBX.Groep.LBXVoormontage).%New()
+	} ElseIf (Categorie = ##class(APPS.Halux.common.enu.Categorie).Merivobox()) {
+		Set ActiviteitGroep = ##class(APPS.Halux.PPS.Activiteit.impl.MVX.Groep.MVXVoormontage).%New()
+	} ElseIf (Categorie = ##class(APPS.Halux.common.enu.Categorie).TAORbox()) {
+		Set ActiviteitGroep = ##class(APPS.Halux.PPS.Activiteit.impl.TAOR.Groep.TAORVoormontage).%New()
+	} Else {
+		Set Exception = ##class(TECH.Exceptions.InvalidInputException).%New("MatService is niet geïmplementeerd voor Categorie '" _ Categorie _ "'.")
+		Do ##class(TECH.ExceptionHandler).Throw(Exception)
+	}
+	
+	Quit ActiviteitGroep
+]]></Implementation>
+</Method>
+
+<Method name="GeefActiviteitGroepId">
+<FormalSpec>Categorie:APPS.Halux.common.enu.Categorie,ActiviteitGroepNaam:%String</FormalSpec>
+<Private>1</Private>
+<ReturnType>%Integer</ReturnType>
+<Implementation><![CDATA[
+	#dim ActiviteitGroepIterator As TECH.Iterator = ..ActiviteitGroepRepository.ZoekViaCategorieEnNaam(Categorie, ActiviteitGroepNaam)
+
+	If ($$$Not(ActiviteitGroepIterator.HasNext())) {
+		Do ##class(TECH.ExceptionHandler).Throw(##class(TECH.Exceptions.InvalidInputException).%New("Geen ActiviteitGroep gevonden voor ActiviteitCode '" _ ActiviteitGroepNaam_"'. Categorie: '"_Categorie_"'."))
+	}
+	
+	#dim ActiviteitGroep As APPS.Halux.PPS.Activiteit.ActiviteitGroep = ActiviteitGroepIterator.Next()
+
+	If (ActiviteitGroepIterator.HasNext()) {
+		Do ##class(TECH.ExceptionHandler).Throw(##class(TECH.Exceptions.InvalidInputException).%New("ActiviteitGroep '" _ ActiviteitGroepNaam _ "' niet eenduidig. Categorie: '"_Categorie_"'."))
+	}	
+		
+	Quit ActiviteitGroep.GeefID()
+]]></Implementation>
+</Method>
+
+<Method name="GeefActiviteitId">
+<FormalSpec>Categorie:APPS.Halux.common.enu.Categorie,ActiviteitGroepId:%Integer,ActiviteitCode:%String</FormalSpec>
+<Private>1</Private>
+<ReturnType>%Integer</ReturnType>
+<Implementation><![CDATA[	Quit ..ActivititeitRepository.GeefActiviteitIDVoorCode(ActiviteitCode, ActiviteitGroepId, Categorie)
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>
Index: vhUnitTest/APPS/Halux/PPS/MatService/MatUitvoeringInfoBepaler/GeefMatUitvoeringIterator/Test.cls.xml
===================================================================
diff -u
--- vhUnitTest/APPS/Halux/PPS/MatService/MatUitvoeringInfoBepaler/GeefMatUitvoeringIterator/Test.cls.xml	(revision 0)
+++ vhUnitTest/APPS/Halux/PPS/MatService/MatUitvoeringInfoBepaler/GeefMatUitvoeringIterator/Test.cls.xml	(revision 66701)
@@ -0,0 +1,75 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="vhUnitTest.APPS.Halux.PPS.MatService.MatUitvoeringInfoBepaler.GeefMatUitvoeringIterator.Test">
+<Super>vhUnitTest.TestCase</Super>
+
+<Method name="Test: Lege categorie =&gt; Geeft InvalidInputException">
+<Implementation><![CDATA[
+	Set MatUitvoeringInfoBepaler = ##class(APPS.Halux.PPS.MatService.MatUitvoeringInfoBepaler).%New()
+	
+	#dim Substring = ##class(TECH.ListUtils).CreateListOfDataTypes("MatService is niet geïmplementeerd voor Categorie ''")
+	Do ..ZetVerwachteExceptie(##class(Tools.Test.VerwachteExceptie).%New("TECH.Exceptions.InvalidInputException", Substring))
+
+	Do MatUitvoeringInfoBepaler.GeefMatUitvoeringIterator()
+]]></Implementation>
+</Method>
+
+<Method name="Test: Geen enkele ActiviteitGroep gevonden =&gt; Geeft InvalidInputException">
+<Implementation><![CDATA[
+	#dim Categorie As APPS.Halux.common.enu.Categorie = ##class(APPS.Halux.common.enu.Categorie).Merivobox()
+	#dim ActiviteitGroepNaam As %String = "MVX voormontage"
+	
+	#dim ActiviteitGroepLijst As %ListOfObjects = ##class(%ListOfObjects).%New()	
+	#dim ActiviteitGroepIterator As TECH.Iterator = ##class(TECH.ListIterator).%New(ActiviteitGroepLijst)	
+	Set ActiviteitGroepRepositoryMock = ##class(vhTest.Mock.APPS.Halux.PPS.Activiteit.ActiviteitGroepRepository).%New()
+	Do ActiviteitGroepRepositoryMock.VerwachtMethodCall("ZoekViaCategorieEnNaam", Categorie, ActiviteitGroepNaam).DanReturn(ActiviteitGroepIterator)
+	
+	#dim Substring = ##class(TECH.ListUtils).CreateListOfDataTypes("Geen ActiviteitGroep gevonden voor ActiviteitCode '"_ActiviteitGroepNaam_"'. Categorie: '"_Categorie_"'.")
+	Do ..ZetVerwachteExceptie(##class(Tools.Test.VerwachteExceptie).%New("TECH.Exceptions.InvalidInputException", Substring))
+	
+	Set MatUitvoeringInfoBepaler = ##class(APPS.Halux.PPS.MatService.MatUitvoeringInfoBepaler).%New(, ActiviteitGroepRepositoryMock)
+		
+	Do MatUitvoeringInfoBepaler.GeefMatUitvoeringIterator("", Categorie)
+	Do ActiviteitGroepRepositoryMock.Verifieer()
+]]></Implementation>
+</Method>
+
+<Method name="Test: Meerdere ActiviteitGroepen gevonden =&gt; Geeft InvalidInputException">
+<Implementation><![CDATA[
+	#dim Categorie As APPS.Halux.common.enu.Categorie = ##class(APPS.Halux.common.enu.Categorie).Merivobox()
+	#dim ActiviteitGroepNaam As %String = "MVX voormontage"
+	
+	#dim ActiviteitGroepLijst As %ListOfObjects = ..MaakActiviteitGroepLijst()
+	#dim UTActiviteitGroep2 As APPS.Halux.PPS.Activiteit.ActiviteitGroep = ##class(APPS.Halux.PPS.Activiteit.ActiviteitGroep).%New("UTCategorie2", "UTNaam2")
+	Do ActiviteitGroepLijst.Insert(UTActiviteitGroep2)
+	
+	#dim ActiviteitGroepIterator As TECH.Iterator = ##class(TECH.ListIterator).%New(ActiviteitGroepLijst)	
+	Set ActiviteitGroepRepositoryMock = ##class(vhTest.Mock.APPS.Halux.PPS.Activiteit.ActiviteitGroepRepository).%New()
+	Do ActiviteitGroepRepositoryMock.VerwachtMethodCall("ZoekViaCategorieEnNaam", Categorie, ActiviteitGroepNaam).DanReturn(ActiviteitGroepIterator)
+	
+	#dim Substring = ##class(TECH.ListUtils).CreateListOfDataTypes("ActiviteitGroep '"_ActiviteitGroepNaam_"' niet eenduidig. Categorie: '"_Categorie_"'")
+	Do ..ZetVerwachteExceptie(##class(Tools.Test.VerwachteExceptie).%New("TECH.Exceptions.InvalidInputException", Substring))
+	
+	Set MatUitvoeringInfoBepaler = ##class(APPS.Halux.PPS.MatService.MatUitvoeringInfoBepaler).%New(, ActiviteitGroepRepositoryMock)
+
+	Do MatUitvoeringInfoBepaler.GeefMatUitvoeringIterator("", Categorie)
+	Do ActiviteitGroepRepositoryMock.Verifieer()
+]]></Implementation>
+</Method>
+
+<Method name="MaakActiviteitGroepLijst">
+<Private>1</Private>
+<ReturnType>%ListOfObjects</ReturnType>
+<Implementation><![CDATA[
+	#dim ActiviteitGroepLijst As %ListOfObjects = ##class(%ListOfObjects).%New()
+	
+	#dim UTActiviteitGroep As APPS.Halux.PPS.Activiteit.ActiviteitGroep = ##class(APPS.Halux.PPS.Activiteit.ActiviteitGroep).%New("UTCategorie", "UTNaam")
+	Do ActiviteitGroepLijst.Insert(UTActiviteitGroep)
+	
+	Quit ActiviteitGroepLijst
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>