Index: BL/Prod/ImageLinkImport/BlumImagesVoorAdminImporteerder.cls.xml
===================================================================
diff -u
--- BL/Prod/ImageLinkImport/BlumImagesVoorAdminImporteerder.cls.xml	(revision 0)
+++ BL/Prod/ImageLinkImport/BlumImagesVoorAdminImporteerder.cls.xml	(revision 68089)
@@ -0,0 +1,210 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<Export generator="Cache" version="24">
+<Class name="BL.Prod.ImageLinkImport.BlumImagesVoorAdminImporteerder">
+<Super>TECH.RegisteredObject</Super>
+
+<Property name="FileUtils">
+<Type>TECH.File.impl.FileUtils</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="ImageLinkImportUtil">
+<Type>BL.Prod.ImageLinkImport</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="ProductAPI">
+<Type>DOM.PM.ProductAPI</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="StatsVerwerking">
+<Type>TECH.FrequentieTabel</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="Logger">
+<Type>vhLib.Logger</Type>
+<Private>1</Private>
+</Property>
+
+<Property name="FileReader">
+<Type>TECH.FileReader</Type>
+<Private>1</Private>
+</Property>
+
+<Method name="%OnNew">
+<Private>1</Private>
+<ProcedureBlock>1</ProcedureBlock>
+<ReturnType>%Status</ReturnType>
+<ServerOnly>1</ServerOnly>
+<Implementation><![CDATA[
+	Set ..FileUtils = ##class(TECH.File.impl.FileUtils).%New()
+	Set ..ImageLinkImportUtil = ##class(BL.Prod.ImageLinkImport).%New()
+	Set ..ProductAPI = ##class(DOM.PM.impl.ProductAPI).%New()
+
+	Set ..StatsVerwerking = ##class(TECH.FrequentieTabel).Instance()
+	Set ..Logger = ##class(vhLib.Logger).%New("BlumImagesVoorAdminImporteerder")
+	
+	Quit $$$OK
+]]></Implementation>
+</Method>
+
+<Method name="ImportImagesVoorBlumProducten">
+<Description>
+Oproepen via :
+   Do ##class(BL.Prod.ImageLinkImport.BlumImagesVoorAdminImporteerder).%New().ImportImagesVoorBlumProducten()</Description>
+<FormalSpec>BestandVolledigeNaam:%String="",CsvDelimiter:%String=";"</FormalSpec>
+<Implementation><![CDATA[
+	If ($$$Trim(BestandVolledigeNaam) = "") {
+		Set BestandVolledigeNaam = "\\notes01\shared\W V\Images\import_AX_blum_MVX_2022-06-03.csv"
+		;Set BestandVolledigeNaam = "E:\CacheExport\2010v2\ADMIN1\W V\Images\import_AX_blum_MVX_2022-06-03_kort.csv"
+		;Set BestandVolledigeNaam = "\\notes01\shared\W V\Images\import_AX_blum_MVX_2022-06-03_kort.csv"
+	}
+	
+	Do ..Logger.Info("ImportImages","Start importing from file '"_BestandVolledigeNaam_"'.")
+	Do ..InitialiseStats()
+	Do ..InitialiseFileReader(BestandVolledigeNaam,CsvDelimiter)
+	Do ..ImportVanBestand()
+	Do ..Logger.Info("ImportImages","Finished importing from file '"_BestandVolledigeNaam_"'. Stats :"_$$$CRLF_..StatsVerwerking.ToString())
+]]></Implementation>
+</Method>
+
+<Method name="InitialiseStats">
+<Private>1</Private>
+<Implementation><![CDATA[
+	Do ..StatsVerwerking.ResetItems()
+	Do ..StatsVerwerking.Reset("Gelukt")
+]]></Implementation>
+</Method>
+
+<Method name="InitialiseFileReader">
+<FormalSpec>BestandVolledigeNaam:%String,CsvDelimiter:%String=";"</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	Set ..FileReader = ##class(TECH.FileReader).%New(BestandVolledigeNaam)
+	Do ..FileReader.SetDelimiter(CsvDelimiter)
+	Do ..FileReader.SetHeaderRow(1)
+	Do ..FileReader.SetFirstDataRow(2)
+]]></Implementation>
+</Method>
+
+<Method name="ImportVanBestand">
+<Private>1</Private>
+<Implementation><![CDATA[
+	While ..FileReader.Next() {
+		#dim mdDataRow As TECH.MultiDim 
+		Merge mdDataRow = ..FileReader.Data
+		
+		#dim ProductIdentnummer As %String = mdDataRow("ProductNummer")
+		#dim ImageFileName As %String = mdDataRow("Locatie")
+		#dim ImageType As %String = $G(mdDataRow("Type"))   ; Deze (laatste) kolom wordt nog wel doorgegeven, maar wordt verder in het script niet gebruikt. Misschien iets van vroeger !? 
+		
+		Try {
+			Do ..VerwerkProductImage(ProductIdentnummer,ImageFileName,ImageType)
+			Do ..StatsVerwerking.Verhoog("Gelukt")
+		}
+		Catch {
+			#dim Exception As TECH.Exceptions.Exception = ##class(TECH.ExceptionHandler).Catch()
+			Do ..StatsVerwerking.Verhoog("Gefaald")
+			Do ..Logger.Warning("VerwerkProductImage","Fout bij verwerken van een rij uit de lijst : '"_ProductIdentnummer_"' en '"_ImageFileName_"'.")
+			Do ..Logger.LogExceptie(Exception)
+		}
+	}
+]]></Implementation>
+</Method>
+
+<Method name="VerwerkProductImage">
+<FormalSpec>ProductIdentnummer:%String,ImageFileName:%String,ImageType:%String=""</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	#dim ProductId As %String = ..ProductAPI.GeefProductIdVoorIdentNummer(ProductIdentnummer)
+	
+	#dim ObjType As %String =  ##class(BL.Prod.ImageLinkImport).#ObjType
+	#dim Oorsprong As %String = ""   ; Leeg is oké? 
+	
+	Do ..VerwijderOudeImagLinks(ObjType, ProductId, Oorsprong)
+	
+	Do ..VoegToeProductImageLinks(ObjType, ProductId, Oorsprong, ImageFileName)
+	
+	Do ..Logger.Info("VerwerkProductImage","Image-Link(s) aangemaakt voor product "_ProductIdentnummer_" ("_ProductId_") op basis van file '"_ImageFileName_"'.")
+]]></Implementation>
+</Method>
+
+<Method name="VerwijderOudeImagLinks">
+<FormalSpec>ObjType:%String,ObjRef:%String,Oorsprong:%String</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[	Do ..ImageLinkImportUtil.OpkuisVorigeImages(ObjType, ObjRef, Oorsprong)
+]]></Implementation>
+</Method>
+
+<Method name="VoegToeProductImageLinks">
+<FormalSpec>ObjType:%String,ObjRef:%String,Oorsprong:%String,ImageFileName:%String</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	#dim FunctieType As %String = "PB"   ; a.k.a. "Toepassing" 
+	#dim ImageGroep As %String = "P"
+	#dim ImageSize As %String = ""
+	#dim Taal As %String = ""
+	#dim VisueelType As %String
+	
+	#dim ImageLink As Res.ImageLink = ##class(Res.ImageLink).Create(ObjType, ObjRef, ImageGroep, FunctieType, Taal)
+	Set ImageLink.Oorsprong = Oorsprong
+	;Set ImageLink.AspectRatio = ""
+	;Set ImageLink.ScaleFactor = ""
+	
+	#dim WebImageFileName As %String = ImageFileName
+	Set VisueelType = "W"   ; Web 
+	Do ..AddLink(ImageLink, VisueelType, WebImageFileName, ImageSize, )
+	
+	#dim ThumbnailImageFileName As %String = ##class(TECH.StringUtils).Replace(ImageFileName, "\W\", "\T\")
+	If ..FileUtils.FileExists(ThumbnailImageFileName) {
+		Set VisueelType = "T"   ; Thumbnail
+		Do ..AddLink(ImageLink, VisueelType, ThumbnailImageFileName, ImageSize, $$$False)
+	}
+	
+	/*
+	Set VisueelType = "P"   ; Printed
+	#dim IsVectorieel As %Boolean = $$$UCase($Extract(ImageFileName,$L(ImageFileName)-2,$L(ImageFileName)))="SVG"
+	If IsVectorieel {
+		Set VisueelType = "V"   ; Vectorieel
+	}
+	Do ..AddLink(ImageLink, VisueelType, ImageFileName, ImageSize, )
+	*/
+	
+	#dim SaveStatus As %Status = ImageLink.%Save()
+	Do ##class(TECH.Exceptions.StatusException).ThrowIndienNietOK(SaveStatus, "Het bewaren van ImageLink voor Product ID '"_ObjRef_"' en image '"_ImageFileName_"' is niet gelukt.")
+]]></Implementation>
+</Method>
+
+<Method name="AddLink">
+<FormalSpec>ImageLink:Res.ImageLink,VisueelType:%String,BestandVolledigeNaam:%String,ImageSize:%String="",IsBestandValidatieNodig:%Boolean=1</FormalSpec>
+<Private>1</Private>
+<Implementation><![CDATA[
+	If IsBestandValidatieNodig {
+		#dim BestandBestaat As %Boolean = ..FileUtils.FileExists(BestandVolledigeNaam)
+		If $$$Not(BestandBestaat) {
+			Do ##class(TECH.Exceptions.GeneralErrorException).Throw("Import ImagesVoorBlumProducten : Bestand '"_BestandVolledigeNaam_"' bestaat niet. Er wordt geen imageLink gekoppeld aan product '"_"..ProductId"_"'.")
+		}
+	}
+
+	#dim BestandNaam As %String = ##class(TECH.File).GeefBestandsnaam(BestandVolledigeNaam, )
+	#dim BestandNaamZonderExtensie As %String = ##class(TECH.File).GeefBestandsnaam(BestandVolledigeNaam, $$$False)
+	#dim BestandExtensie As %String = ##class(TECH.File).GeefExtensie(BestandVolledigeNaam)
+	#dim BestandLocatie As %String = ##class(TECH.File).GetDirectory(BestandVolledigeNaam)
+	
+	#dim ImageSubdir As %String = $$$UCase(##class(TECH.File).NormalizeDirectory(BestandLocatie))
+	If ImageSubdir [ "NOTES01\IMAGES\" {
+		Set ImageSubdir = $Piece(ImageSubdir, "NOTES01\IMAGES\", 2)
+	}
+	If $E(ImageSubdir,*)="\" {
+		Set ImageSubdir = $E(ImageSubdir, 1, *-1)
+	}
+	
+	Do ImageLink.AddLink(VisueelType, ImageSubdir, BestandNaamZonderExtensie, , BestandExtensie, ImageSize)
+]]></Implementation>
+</Method>
+</Class>
+
+
+</Export>